📄 emp_oa.asp

📁 物业管理和办公自动化系统
💻 ASP
字号:
<%
'************************************************************************************************
' 文件名: emp_oa.asp
' Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司
'
' 　创建人 : 周秋舫
' 　日　期 : 2002-05-13
' 修改历史 :
'   ****年**月**日 ****** 修改内容:**************************************************
' 功能描述 : 员工登记前先确定OA用户名
' 　版　本 :
'*******************************************************************************
option explicit
Response.CacheControl = "no-cache"
Response.AddHeader "Pragma", "no-cache"
Response.Expires = -1
%>

<!-- #include file="../include/config.inc" -->
<!-- #include file="../include/common.inc" -->
<!-- #include file="../include/debug.inc" -->
<!-- #include file="../include/db.inc" -->
<!-- #include file="../include/date.inc" -->
<!-- #include file="../include/datahandle.inc" -->
<!-- #include file="../include/recordlist.inc" -->
<!-- #include file="../include/security.inc" -->

<!-- #include file="../common/commonpage.inc" -->
<!-- #include file="emp_oa.inc" -->

<%
call CheckSecurity()

'' 如果不是人事管理员，则无权进入本页
if Not IsAdministrator then
'if Not IsHrAdmin then
	Response.Clear
	Response.Redirect "../common/error.asp?error=只有系统管理员新增用户后才能进行人事信息管理！"
	Response.end
end if


'' 检查是否有角色，如果没有角色，则提醒需系统管理员新增角色
dim iCountRoles	 : iCountRoles = DLookUp(dbLocal, "t_role", "count(*)", "")
''response.write "目前系统中有角色：" & iCountRoles & "个<br>"
if iCountRoles = 0 then
	Response.Clear()
	Response.Redirect("../common/error.asp?error=目前系统中无角色可选，请系统管理员新增角色！")
	Response.end
end if

'*******************************************************************************
' 服务器端代码
dim sName		: sName = GetParam("name")
dim sAccountId	: sAccountId = GetParam("account_id")
dim role				: role = GetParam("role")
dim pStep			: pStep = GetParam("step")

if IsEmpty(pStep) then pStep = 1
'response.write GetParam("role") & "<br>"

dim co_id	: co_id = 1					'' 业主员工
dim isdummy : isdummy = 0		'' 非虚拟员工
dim dismissed	: dismissed = 0	'' 在职员工

dim sTitle, sTip


if pStep = 1 then
	sTip = "注意：用户名只能由字母、数字和下划线组成，且必须以字母打头"
elseif pStep = 2 then
	'' 检查是否存在相同的用户名，如果有，则退回到第一步；如果没有，则进入第二步
	dim sSQL, iRows
	iRows = DLookUp(dbLocal, "t_account", "count(*)", "account_id = " & ToSQL(sAccountId,"Text"))
	if iRows > 0 then
		pStep = 1
		sTip = "对不起，用户名 " & sAccountId & " 已经存在，请选择其它的用户名！"
	else
		pStep = 2
		sTip = "请确认以下信息，如果正确，请按下一步，否则按上一步"
	end if
elseif pStep = 3 then	'' 新增用户
	AddEmp()
end if
%>

<html>
<head>
<title>上海信息大楼 Shanghai Information Tower</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link rel="stylesheet" href="../common/common.css" type="text/css">

<style>
input {color:blue}
</style>

<script language="javascript">
function CheckInput()
{
	// 检查用户姓名
	var sName = frmAddEmp.name.value;
	if (sName == "")
	{
		alert("对不起，请输入员工姓名！");
		frmAddEmp.name.focus();
		return false;
	}

	// 检查用户名
	var sAccountId = frmAddEmp.account_id.value;
	if (sAccountId == "")
	{
		alert("对不起，请输入用户名！");
		frmAddEmp.account_id.focus();
		return false;
	}
	else
	{
		// 检查用户名是否合法，用户名只能由字母、数字和下划线组成，且第一位必须为字母
		var re = new RegExp("^[a-z][a-z0-9_]*$","ig");
		var str = sAccountId;
		if (str.match(re) == null)
		{
			alert("对不起，用户名只能由字母、数字和下划线组成，且必须以字母打头！");
			frmAddEmp.account_id.focus();
			return false;
		}
	}
//	var sRole = frmAddEmp.role.value;
//	alert(sRole);
//	return false;
}
</script>

</head>

<body bgcolor="#FFFFFF" leftmargin="0" topmargin="0" marginwidth="0" marginheight="0" background="../images/bg/bg0.jpg">
<br>

<%
Response.Write OuterTableHeader
Response.Write HeaderWithMenu
Response.Write InnerTableHeader
'*******************************************************************************
' 主体从这里开始
'-------------------------------------------------------------------------------

if pStep = 1 then
	Response.Write FirstForm()
elseif pStep = 2 then
	Response.Write SecondForm()
end if

Response.Write TableLink
'-------------------------------------------------------------------------------
' 主体到这里结束
'*******************************************************************************
Response.Write InnerTableTailer
Response.Write Footer
Response.Write OuterTableTailer
%>


</body>
</html>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -