categoryedit.inc

物业管理和办公自动化系统

<%
'#############################################################################################
'#
'#	文件名	 : categoryedit.inc
'#
'#
'#	创建人	 : 姚晓辉
'# 　	日　期	 : 2002-05-13
'#
'#	修改历史  : ****年**月**日 ****** 修改内容:**********************************************
'#
'#	功能描述	 : 图书类别管理函数文件
'# 　	版  　本	 :
'#	
'#	Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司
'#
'#############################################################################################

Function ListTableHeader()
	ListTableHeader = _
		"<table cellspacing=0 cellpadding=0 width=300 align=center class=tablelist>" & vbLF & _
		"<tr><td colspan=" & iCols & " bgcolor=""#0040a0"" align=center style=""color:white;font-weight:600"" height=20 >类别列表</td></tr>" & vbLF & _
		"<tr><td class=tdHead width=300>&nbsp;<img src=""../images/bg/happy.gif"" width=8 height=8>&nbsp;" & TableHeaderField(sFileName, "description", "类别名称", sFormParams, iSort, iSorted) & "</td>" & vbLF & _
		"</tr>" & vbLF
End Function

Function ListTableTailer()
	ListTableTailer = "</table>" & vbLF
End Function

Function ListTableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams)
	dim sTemp	: sTemp = ""	' 临时字符串变量
	dim j					' 临时循环变量

	'------------------------------------
	' 分页所需的变量定义
	'------------------------------------
	Dim iCounter		: iCounter = 1
	Dim iPrevPage, iNextPage
	
	'------------------------------------
	' 获取数据库连接
	'------------------------------------
	dim crs	: set crs = New CRecordset
	dim rs	: set rs = crs.open(dbLocal,sSQL)
	dim iTitleId, sTitleDescription
	dim sColor	

	' 如果未到记录尾，将记录定位到你翻到的页面的第一个记录，否则显示空行
	if Not rs.EOF then	
		rs.Move (iCurrentPage - 1) * iRecordsPerPage
	end if
	while not rs.EOF and iCounter <= iRecordsPerPage
		iTitleId				= crs.GetValue("id")
		sTitleDescription	= crs.GetValue("description")

		if CStr(iTitleId) = CStr(pTitleId) then		'' 如果是选中的纪录，显示不同的颜色，这里指定红色
				sColor = "red"
		else
				sColor = "black"
		end if
		sTemp = sTemp & "<tr bgcolor=white>" & vbLF & _
				"<td class=tdlist title=""" & sTitleDescription & """ style=""cursor:hand;color:" & sColor & """ onclick=""javascript:location.href='categoryedit.asp?id=" & iTitleId & "';"">&nbsp;<img src=""../images/bg/ar-g.gif"" width=8 height=8>&nbsp;" & Bref(sTitleDescription,18) & "&nbsp;</td>" & vbLF & _
				"</tr>" & vbLF
		iCounter = iCounter + 1
		rs.movenext
	wend
	crs.Close()

	' 填补空白行
	sTemp = sTemp & WhiteRows(iCols, iCounter, iRecordsPerPage)

	' 首页、前页、后页、尾页等分页信息
	sTemp = sTemp & "<tr bgcolor=white><td class=tdlist colspan=" & iCols & " align=right>" & vbLF & _
				Paginate(sFileName, sFormParams, sSortParams, iCurrentPage, iTotalPages) & vbLF & _
				"&nbsp;</td></tr>" & vbLF

	ListTableRecords = sTemp
End Function


Function FormTable()
	dim sTitle, sActionLinks
	if IsEmpty(pTitleId) then
		sTitle = "新增类别"			'' 显示新增、取消的链接
		sActionLinks = _
				"<tr bgcolor=white height=30>" & vbLF & _
				"	<td colspan=8 align=center>" & vbLF & _
				"		<img border=0 src=""../images/button/add.gif"" onclick=""btnAdd_OnClick()"" style=""cursor:hand"">" & vbLF & _
				"		&nbsp;&nbsp;&nbsp;&nbsp;" & vbLF & _
				"		<img border=0 src=""../images/button/clear.gif"" onclick=""btnClear_OnClick()"" style=""cursor:hand"">" & vbLF & _
				"	</td>" & vbLF & _
				"</tr>" & vbLF
	else
		sTitle = "重命名类别"			'' 显示修改、删除、取消的链接
		sActionLinks = _
				"<tr bgcolor=white height=30>" & vbLF & _
				"	<td colspan=8 align=center>" & vbLF & _
				"		<img border=0 src=""../images/button/update.gif"" onclick=""btnUpdate_OnClick()"" style=""cursor:hand"">" & vbLF & _
				"		&nbsp;&nbsp;&nbsp;&nbsp;" & vbLF & _
				"		<img border=0 src=""../images/button/delete.gif"" onclick=""btnDelete_OnClick()"" style=""cursor:hand"">" & vbLF & _
				"		&nbsp;&nbsp;&nbsp;&nbsp;" & vbLF & _
				"		<img border=0 src=""../images/button/cancel.gif"" onclick=""btnCancel_OnClick()"" style=""cursor:hand"">" & vbLF & _
				"	</td>" & vbLF & _
				"</tr>" & vbLF
	end if

	FormTable = _
		"<table cellspacing=1 cellpadding=0 bgcolor=white border=0 width=300 height=""100%"" background=""../images/bg/bg001.gif"">" & vbLF & _
		"<form method=post name=frmMgr action=""categoryedit.asp"">" & vbLF & _
		"<input type=""hidden"" name=""FormAction"">" & vbLF & _
		"<input type=""hidden"" name=""id"" value=""" & pTitleId & """>" & vbLF & _
		"<tr height=20>" & vbLF & _
		"		<td colspan=2 background=""../images/bg/bnbg.gif"" style=""color:white;font-weight:600"" align=center>" & sTitle & "</td></tr>" & vbLF & _
		"<tr height=20><td></td></tr>" & vbLF & _
		"<tr bgcolor=""#FFFFFF"" height=60>" & vbLF & _
		"		<td width=80 align=right>类别名称：</td>" & _
		"		<td><input type=""text"" name=""description"" value=""" & sTitleDesp & """ size=31 maxlength=10></td></tr>" & vbLF & _
		sActionLinks & vbLF & _
		"<tr height=166><td></td></tr>" & vbLF & _
		"</form>" & _
		"</table>" & vbLF & _
		""
End Function

Function TableLink()
	TableLink = _
		"<table width=600 cellspacing=0 cellpadding=0 border=0 align=center>" & _
		"<tr height=10>" & _ 
		"	<td width=600><img src=""../images/bg/line.gif"" width=600 height=3></td>" & _
		"</tr>" & _
		"<tr height=20>" & _
		"	<td width=600>&nbsp;" & _
		"		<img src=""../images/goto.gif"">&nbsp;<a href=""book_in1.asp"">新书登记</a>" & _
		"		&nbsp;" & _
		"		<img src=""../images/goto.gif"">&nbsp;<a href=""book_q.asp"">图书查询</a>" & _
		"		&nbsp;" & _
		"		<img src=""../images/goto.gif"">&nbsp;<a href=""ok.asp"">ok</a></td>" & _
		"</tr>" & _
		"</table>"
End Function


sub AddTitle()
	dim sSQL, iRows
	sTitleDesp = Trim(GetParam("description"))

	'' 类别名称不能为空
	if sTitleDesp = "" then
		Response.Write _
				"<script language=""javascript"">" & vbLF & _
				"		alert(""抱歉，请输入类别名称"");" & vbLF & _
				"</script>" & vbLF
		exit sub
	end if

	'' 检查是否存在重复的类别名称
	iRows = DLookUp(dbLocal, "t_library_books_category", "count(*)", "title =" & ToSQL(sTitleDesp, "Text"))
	if iRows > 0 then
		Response.Write _
				"<script language=""javascript"">" & vbLF & _
				"		alert(""抱歉，已经存在名称为“" & sTitleDesp & "”的类别，不能重复！"");" & vbLF & _
				"</script>" & vbLF
		exit sub
	end if
	sSQL = "insert into t_library_books_category(title) values(" & ToSQL(sTitleDesp, "Text") & ")"
	call ExecuteSQL(dbLocal, sSQL)
	pTitleId = empty		'' 重新置成新增状态
	sTitleDesp = ""
end sub

sub UpdateTitle()
	dim sSQL, iRows
	sTitleDesp = Trim(GetParam("description"))

	'' 类别名称不能为空
	if sTitleDesp = "" then
		Response.Write _
				"<script language=""javascript"">" & vbLF & _
				"		alert(""对不起，请输入类别名称"");" & vbLF & _
				"</script>" & vbLF
		exit sub
	end if

	'' 检查是否存在重复的类别名称
	iRows = DLookUp(dbLocal, "t_library_books_category", "count(*)", "title=" & ToSQL(sTitleDesp, "Text") & " and category_id<>" & ToSQL(pTitleId,"Number"))
	if iRows > 0 then
		Response.Write _
				"<script language=""javascript"">" & vbLF & _
				"		alert(""对不起，类别名称不能重复！"");" & vbLF & _
				"</script>" & vbLF
		exit sub
	end if
	sSQL = "update t_library_books_category set title = " & ToSQL(sTitleDesp, "Text") & " where category_id = " & ToSQL(pTitleId, "Number")
	call ExecuteSQL(dbLocal, sSQL)
	pTitleId = empty
	sTitleDesp = ""
end sub

sub DeleteTitle()
	sTitleDesp = Trim(GetParam("description"))
	dim sSQL, iRows

	'' 检查是否存在重复的类别名称
	iRows = DLookUp(dbLocal, "t_library", "count(*)", "category_id =" & ToSQL(pTitleId, "Number"))
	if iRows > 0 then
		Response.Write _
				"<script language=""javascript"">" & vbLF & _
				"		alert(""对不起，系统中有" & iRows & "本类别为“" & sTitleDesp & "”的书籍，该类别不能删除！"");" & vbLF & _
				"</script>" & vbLF
		exit sub
	end if
	sSQL = "delete from t_library_books_category where category_id = " & ToSQL(pTitleId, "Number")
	call ExecuteSQL(dbLocal, sSQL)
	pTitleId = empty		'' 重新置成新增状态
	sTitleDesp = ""
end sub
%>