savetodb.asp

物业管理和办公自动化系统

<%
'************************************************************************************************
' 文件名: getfile.asp
' Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司

' 　创建人 : 周秋舫
' 　日　期 : 2002-08-15
' 修改历史 :
'   ****年**月**日 ****** 修改内容:**************************************************
' 功能描述 : 上载文件到数据库
' 　版　本 :
'************************************************************************************************
option explicit
Response.CacheControl = "no-cache"
Response.AddHeader "Pragma", "no-cache"
Response.Expires = -1
%>

<!-- #include file="../include/config.inc" -->
<!-- #include file="../include/common.inc" -->
<!-- #include file="../include/debug.inc" -->
<!-- #include file="../include/db.inc" -->
<!-- #include file="../include/date.inc" -->
<!-- #include file="../include/datahandle.inc" -->
<!-- #include file="../include/recordlist.inc" -->
<!-- #include file="../include/security.inc" -->
<!-- #include file="../include/message.inc" -->

<!-- #include file="file.inc" -->
<!-- #include file="upload.inc"--> 

<% 
'' 获取本人的序列号
dim iEmpSerial	: iEmpSerial = GetEmpSerial

Response.Buffer = TRUE 
Response.Clear 



'' ******************************************************************************************************
'' 获取上传文件及其它各种数据
'' -----------------------------------------------------------------------------------------------------------------------------------------------
dim byteCount		: byteCount = Request.TotalBytes 
dim RequestBin		: RequestBin = Request.BinaryRead(byteCount) 
dim UploadRequest	: set UploadRequest = CreateObject("Scripting.Dictionary") 
BuildUploadRequest RequestBin 
dim FileNameNew	: FileNameNew = UploadRequest.Item("filename_new").Item("Value")
dim FileFolder			: FileFolder = UploadRequest.Item("folder").Item("Value")
dim FileOpenTo		: FileOpenTo = UploadRequest.Item("opentoEmpSerial").Item("Value")

dim contentType		: contentType = UploadRequest.Item("blob").Item("ContentType")
dim FilePathName	: FilePathName = UploadRequest.Item("blob").Item("FileName")
dim FileName			: FileName = Right(FilePathName,Len(FilePathName)-InstrRev(FilePathName,"\"))
dim FileExtension

if InStr(FileName, ".") = 0 then
	FileExtension = ""
else
	FileExtension = Right(FileName,Len(FileName)-InstrRev(FileName,"."))
end if

dim FileContent		: FileContent = UploadRequest.Item("blob").Item("Value")
dim FileSize			: FileSize = LenB(FileContent)

if FileFolder = "" then FileFolder = null
if FileOpenTo = "" then FileOpenTo = null

'' 是否重命名了
if FileNameNew <> "" then FileName = FileNameNew & "." & FileExtension


'' ******************************************************************************************************
'' 上传数据库
'' -----------------------------------------------------------------------------------------------------------------------------------------------
dim oCn	: set oCn = New CDBConnection
oCn.Connect(dbLocal)
dim cn		: set cn = oCn.m_DBConn
dim objRst
set objRst = server.createobject("adodb.recordset")
objrst.Open "t_files", cn, 1,3,2
objrst.addnew
objrst.fields("emp_serial") = iEmpSerial
objrst.fields("filename")	=	FileName
objrst.fields("filetype") = FileExtension						'' 文件类型，即文件后缀名
objrst.fields("contenttype")	=	contentType				'' 如：image/gif
objrst.fields("content").appendchunk filecontent 
objrst.fields("filesize") = filesize
objrst.fields("upload_time") = now
objrst.fields("folder") = FileFolder
objrst.fields("opento") = FileOpenTo
objrst.update 

'' 获取刚刚上传的文件的标识
dim iFileSerial	: iFileSerial = objrst.fields("serial")
objrst.close
set objrst=nothing 
oCn.Disconnect()


'' 通知文件共享者文件给共享的信息
dim sMsgType, iParentMsgId, sMsgSubject, sMsgContent, sMsgSender, sMsgReceiver
if FileOpenTo <> "" then
	sMsgType = MSG_COMMON
	iParentMsgId = ""
	sMsgSubject = "新的共享文件：《" & FileName & "》"
	sMsgContent = GetUserName & "给您共享了文件：《" & FileName & "》"
	sMsgSender = iEmpSerial
	sMsgReceiver = FileOpenTo
	call CommonSendMsg(sMsgType, iParentMsgId, sMsgSubject, sMsgContent, sMsgSender, sMsgReceiver)
end if

'' 转向刚刚上传的文件，显示该文件的属性
Response.Redirect "file_p.asp?serial=" & iFileSerial & "&"
'' ******************************************************************************************************
%>