file_e.inc

物业管理和办公自动化系统

<%
Function FormFileUpdate()
	dim sSQL, crs, rs
	dim sFileName, sFileType, sContentType, sUploadTime, sFileSize, sFileFolder, sOpenTo, sFileOwner
	dim sActionLink, sTemp

	'' ************************************************************************************
	'' 只有我自己的文件，我才有权限进行属性编辑或删除
	sSQL = "select * from t_files" & _
		" where serial = " & pFileSerial & _
		" and (emp_serial = " & iEmpSerial & " or PATINDEX('%," & iEmpSerial & ",%', ','+replace(opento,' ','')+',') > 0)"
	set crs = New CRecordset
	set rs = crs.Open(dbLocal, sSQL)

	if rs.EOF then
		crs.Close()
		Response.Clear()
		Server.Transfer("../common/error.asp")
		Response.end
	end if

	'' ************************************************************************************
	'' 获取数据
	sFileOwner	= crs.GetValue("emp_serial")
	sFileName	= crs.GetValue("filename")
	sFileType	= crs.GetValue("filetype")
	sContentType		= crs.GetValue("contenttype")
	sUploadTime		= crs.GetValue("upload_time")
	sFileSize	= crs.GetValue("filesize")
	sFileFolder	= crs.GetValue("folder")
	sOpenTo	= crs.GetValue("opento")

	if sFileFolder = "" then sFileFolder = "<span style=""color:gray"">(根目录)</span>"

	FormFileUpdate = _
		"<form method=post name=""FormUpdateFile"" action=""file_e.asp"">" & vbLF & _
		"<input type=""hidden"" name=""serial"" value=""" & pFileSerial & """>" & vbLF & _
		"<input type=""hidden"" name=""filename"" value=""" & sFileName & """>" & vbLF & _
		"<input type=""hidden"" name=""filetype"" value=""" & sFileType & """>" & vbLF & _
		"<input type=""hidden"" name=""original_opentoEmpSerial"" value=""" & sOpenTo & """ size=75>" & vbLF & _
		"<input type=""hidden"" name=""opentoEmpSerial"" value=""" & sOpenTo & """ size=75>" & vbLF & _
		"<table border=0 cellspacing=1 cellpadding=5 bgcolor=silver width=""100%"" style=""border:1px solid navy;table-layout:fixed"">" & vbLF & _
		"<tr style=""display:none""><td width=70>这一行仅用于控制表格宽度</td><td width=""*""></td></tr>" & vbLF & _
		"<tr bgcolor=navy><td colspan=2 style=""font-weight:600;color:white"" align=center>文 件 属 性</td></tr>" & vbLF & _
		"<tr bgcolor=white><td nowrap align=center>文件名称：</td><td nowrap class=tdLink onclick=""window.open('showfile.asp?serial=" & pFileSerial & "&');""><span>" & sFileName & "</span></td></tr>" & vbLF & _
		"<tr bgcolor=white><td nowrap align=center>文件类型：</td><td nowrap class=tdValue>" & TransFileType(sFileType) & "</td></tr>" & vbLF & _
		"<tr bgcolor=white><td nowrap align=center>文件大小：</td><td nowrap class=tdValue>" & sFileSize & " 字节</td></tr>" & vbLF & _
		"<tr bgcolor=white><td nowrap align=center>内容类型：</td><td nowrap class=tdValue>" & sContentType & "</td></tr>" & vbLF & _
		"<tr bgcolor=white><td nowrap align=center>上载时间：</td><td nowrap class=tdValue>" & sUploadTime & "</td></tr>" & vbLF & _
		"<tr bgcolor=white><td nowrap align=center>重 命 名：</td>" & vbLF & _
				"<td nowrap class=tdValue><input name=""filename_new"" size=80 maxlength=64></td></tr>" & vbLF & _
		"<tr bgcolor=white><td nowrap align=center>所在目录：</td>" & _
				"<td nowrap class=tdValue>" & vbLF & _
				"<select name=""folder"" style=""width:491px"">" & vbLF & _
				"<option value="""">／( 根目录 )</option>" & vbLF & _
				selectOptions(dbLocal, "t_filefolder", "folder_id", "folder_name", sFileFolder, "emp_serial=" & iEmpSerial & " order by folder_name") & vbLF & _
				"</select></td></tr>" & vbLF & _
		"<tr bgcolor=white><td nowrap align=center>文件共享：</td>" & _
				"<td nowrap ondblclick=""TransSlctEmp();"">" & vbLF & _
				"<input type=""text"" name=""opentoEmpName"" value=""" & TransEmpSerial(dbLocal, sOpenTo) & """ size=80 readonly>" & vbLF & _
				"<img border=0 src=""../images/openswin.gif"" onclick=""TransSlctEmp();""></td></tr>" & vbLF & _
		"<tr bgcolor=white height=40><td colspan=2 align=center>" & vbLF & _
				"<input type=""image"" style=""border-width:0"" src=""../images/button/update.gif"">" & vbLF & _
				"<img border=0 height=0 width=30>" & vbLF & _
				"<img border=0 src=""../images/button/delete.gif"" style=""cursor:hand"" onclick=""DeleteFile(" & pFileSerial & ");"">" & vbLF & _
				"<img border=0 height=0 width=30>" & vbLF & _
				"<img border=0 src=""../images/button/cancel.gif"" style=""cursor:hand"" onclick=""location.href='file_p.asp?serial=" & pFileSerial & "&';"">" & vbLF & _
				"</td></tr>" & vbLF & _
		"</table>" & vbLF & _
		"<!-- 这一段用于翻译人名 -->" & vbLF & _
		"<select id=""slctEmplist"" multiple size=10 style=""display:none"">" & vbLF & _
		selectOptions(dbLocal,"t_employee", "serial", "name", "", "co_id=" & GetCoId & " and isdummy=0 and dismissed=0") & vbLF & _
		"</select>" & vbLF
End Function

Sub UpdateFile()
	dim sSQL
	dim sOriginalOpenTo, sOpenTo, sFileName, sFileType, sFileNameNew, sFileFolder
	sFileName		= GetParam("filename")
	sFileType		= GetParam("filetype")
	sFileNameNew= GetParam("filename_new")
	sFileFolder		= GetParam("folder")
	sOriginalOpenTo = GetParam("original_opentoEmpSerial")		'' 文件原来共享的人员
	sOpenTo		= GetParam("opentoEmpSerial")							'' 修改后共享的人员

	if IsEmpty(sFileNameNew) then sFileNameNew = ""
	'' 如果有重命名文件，则新的文件名则为用户新提交的文件名称和后缀名的组合，否则文件名保持不变
	if Trim(sFileNameNew) <> "" then
		sFileName = sFileNameNew & "." & sFileType
	end if
		
	sSQL = "update t_files" & _
				" set filename = " & ToSQL(sFileName,"Text") & _
				", folder = " & ToSQL(sFileFolder, "Text") & _
				", opento = " & ToSQL(sOpenTo, "Text") & _
				" where serial = " & ToSQL(pFileSerial, "Number")
	call ExecuteSQL(dbLocal, sSQL)


	'' 通知文件新增的共享者文件被共享的信息，并且通知哪些原来是共享者现在不是共享者的人文件共享权被取消了
	'' 具体做法就是比较原来的共享者和现在的共享者之间的差别，找到新的共享者列表和取消共享者的列表
	dim j, sArray, sEmpTemp
	dim sMsgType, iParentMsgId, sMsgSubject, sMsgContent, sMsgSender, sMsgReceiver
	sMsgType = MSG_COMMON
	iParentMsgId = ""
	sMsgSender = iEmpSerial
	sOriginalOpenTo = Replace(sOriginalOpenTo, " ", "")	'' 去掉所有的空格
	sOpenTo = Replace(sOpenTo, " ", "")							'' 去掉所有的空格
	if sOriginalOpenTo = sOpenTo then								'' 共享情况没有发生变化
		'' do nothing
	elseif sOriginalOpenTo = "" then									'' 原来没有共享，现在共享了
		'' send msg to sOpenTo that the file is shared to them
		sMsgSubject = "新的共享文件：《" & sFileName & "》"
		sMsgContent = GetUserName & "给您共享了文件：《" & sFileName & "》"
		sMsgReceiver = sOpenTo
		call CommonSendMsg(sMsgType, iParentMsgId, sMsgSubject, sMsgContent, sMsgSender, sMsgReceiver)
	elseif sOpenTo = "" then												'' 原来共享了，现在不共享了
		'' send msg to sOriginalOpenTo the the file is not shared any longer
		sMsgSubject = "文件不再共享：《" & sFileName & "》"
		sMsgContent = GetUserName & "取消了您对文件：《" & sFileName & "》的访问权限"
		sMsgReceiver = sOriginalOpenTo
		call CommonSendMsg(sMsgType, iParentMsgId, sMsgSubject, sMsgContent, sMsgSender, sMsgReceiver)
	else
		'' compare sOriginalOpenTo and sOpenTo, find those people whose access right is changed
		'' 新增的共享者：分析sOpenTo中的每个人，检查在sOriginalOpenTo中有没有，如没有，则为新增的
		sMsgReceiver = ""
		sArray = Split(sOpenTo, ",")					'' 成员之间以逗号分隔
		for j = LBound(sArray) to UBound(sArray)
			sEmpTemp = sArray(j)
			if InStr(sOriginalOpenTo, sEmpTemp) = 0 then
				if sMsgReceiver <> "" then sMsgReceiver = sMsgReceiver & ","
				sMsgReceiver = sMsgReceiver & sEmpTemp
			end if
		next
		if sMsgReceiver <> "" then
			sMsgSubject = "新的共享文件：《" & sFileName & "》"
			sMsgContent = GetUserName & "给您共享了文件：《" & sFileName & "》"
			call CommonSendMsg(sMsgType, iParentMsgId, sMsgSubject, sMsgContent, sMsgSender, sMsgReceiver)
		end if

		'' 被取消的共享者：分析sOriginalOpenTo中的每个人，检查在sOpenTo中是否出现，如没有，则表示被取消了
		sMsgReceiver = ""
		sArray = Split(sOriginalOpenTo, ",")
		for j = LBound(sArray) to UBound(sArray)
			sEmpTemp = sArray(j)
			if InStr(sOpenTo, sEmpTemp) = 0 then
				if sMsgReceiver <> "" then sMsgReceiver = sMsgReceiver & ","
				sMsgReceiver = sMsgReceiver & sEmpTemp
			end if
		next
		if sMsgReceiver <> "" then
			sMsgSubject = "文件不再共享：《" & sFileName & "》"
			sMsgContent = GetUserName & "取消了您对文件：《" & sFileName & "》的访问权限"
			call CommonSendMsg(sMsgType, iParentMsgId, sMsgSubject, sMsgContent, sMsgSender, sMsgReceiver)
		end if
	end if
	
	Response.Redirect "file_p.asp?serial=" & pFileSerial & "&"
End Sub


Function TableLink()
	TableLink = _
		"<br><table width=600 cellspacing=0 cellpadding=0 border=0 align=center>" & vbLF & _
		"<tr height=10>" & vbLF & _ 
		"	<td width=600><img src=""../images/bg/line.gif"" width=600 height=3></td>" & vbLF & _
		"</tr>" & vbLF & _
		"<tr height=20>" & vbLF & _
		"	<td width=600>&nbsp;" & vbLF & _
			"<img src=""../images/goto.gif"">&nbsp;<a href=""file_l.asp"">文件列表</a>" & vbLF & _
			"&nbsp;&nbsp;&nbsp;&nbsp;" & vbLF & _
			"<img src=""../images/goto.gif"">&nbsp;<a href=""getfile.asp"">上传文件</a>" & vbLF & _
			"&nbsp;&nbsp;&nbsp;&nbsp;" & vbLF & _
			"<img src=""../images/goto.gif"">&nbsp;<a href=""folder.asp"">文件统计及文件夹管理</a>" & vbLF & _
			"&nbsp;&nbsp;&nbsp;&nbsp;" & vbLF & _
			"<img src=""../images/goto.gif"">&nbsp;<a href=""#"" onclick=""window.open('folder_a.asp','','height=124,width=350,left=200,top=200');"">新建文件夹</a></td>" & vbLF & _
		"</tr>" & vbLF & _
		"</table>" & vbLF
End Function

%>