file_p.inc

物业管理和办公自动化系统

<%
Function FileInfor()
	dim sSQL, crs, rs
	dim sFileName, sFileType, sContentType, sUploadTime, sFileSize, sFileFolder, sOpenTo, sFileOwner
	dim sActionLink, sTemp

	sSQL = "select t1.filename, t1.filetype, t1.contenttype, t1.upload_time, t1.filesize, t2.folder_name, t1.emp_serial, t1.opento" & _
		" from t_files t1 left join t_filefolder t2 on t2.folder_id = t1.folder" & _
		" where t1.serial = " & pFileSerial & _
		" and (t1.emp_serial = " & iEmpSerial & " or PATINDEX('%," & iEmpSerial & ",%', ','+replace(t1.opento,' ','')+',') > 0)"

	'		'' 我今天要参加的会议
	'' attendee清除任何位置的空格，然后在首尾各加一个逗号分隔符","（因为attendee是以逗号分隔个参会人员的），最后与操作员自己的序列号进行匹配
	'sql2 = "	select count(*) from t_meetingprepare" & _
	'		" where start_time >= " & ToSQL(date,"Text") & _
	'		" and PATINDEX('%," & iEmpSerial & ",%', ',' + replace(attendee,' ','') + ',') > 0"

	set crs = New CRecordset
	set rs = crs.Open(dbLocal, sSQL)

	if rs.EOF then
		crs.Close()
		Response.Clear()
		Response.Redirect("../common/error.asp?error=找不到文件。<br>可能情况是该文件已经被删除。")
		Response.end
	end if

	'' 获取数据
	sFileOwner	= crs.GetValue("emp_serial")
	sFileName	= crs.GetValue("filename")
	sFileType	= crs.GetValue("filetype")
	sContentType		= crs.GetValue("contenttype")
	sUploadTime		= crs.GetValue("upload_time")
	sFileSize	= crs.GetValue("filesize")
	sFileFolder	= crs.GetValue("folder_name")
	sOpenTo	= crs.GetValue("opento")
	if sOpenTo <> "" then
		sOpenTo = TransEmpSerial(dbLocal, sOpenTo)
	else
		sOpenTo = "<span style=""color:gray"">(不共享)</span>"
	end if

	if sFileFolder = "" then sFileFolder = "<span style=""color:gray"">(根目录)</span>"
	sFileType = TransFileType(sFileType)
	
	sActionLink = ""
	if CStr(sFileOwner) = CStr(iEmpSerial) then
		'' 这是我自己的文件，因此我有权限进行修改和删除
		sActionLink = "<tr bgcolor=white height=40>" & vbLF & _
				"<td align=center colspan=2>" & _
				"<a style=""color:blue"" href=""file_e.asp?serial=" & pFileSerial& "&""><img border=0 src=""../images/edit.gif"">&nbsp;编辑文件属性</a>" & _
				"<img border=0 height=0 width=40>" & _
				"<a style=""color:blue;cursor:hand"" onclick=""DeleteFile(" & pFileSerial & ");""><img border=0 src=""../images/trash.gif"">&nbsp;删除文件</a>" & _
				"</td>" & vbLF & _
				"</tr>" & vbLF
	end if

	FileInfor = _
		"<table border=0 cellspacing=1 cellpadding=5 bgcolor=silver width=""100%"" style=""border:1px solid navy;table-layout:fixed"">" & vbLF & _
		"<tr style=""display:none""><td width=70>这一行仅用于控制表格宽度</td><td width=""*""></td></tr>" & vbLF & _
		"<tr bgcolor=navy><td colspan=2 style=""font-weight:600;color:white"" align=center>文 件 属 性</td></tr>" & vbLF & _
		"<tr bgcolor=white><td nowrap align=center>文件名称：</td><td nowrap>" & _
				"<a target=_blank style=""color:blue;cursor:hand"" href=""showfile.asp?serial=" & pFileSerial & "&"");"" title=""点击这里打开文件""><img border=0 src=""images/content.gif"">&nbsp;" & sFileName & "</a></td></tr>" & vbLF & _
		"<tr bgcolor=white><td nowrap align=center title=""点击这里下载文件"">文件下载：</td><td nowrap><a style=""color:blue;"" href=""downfile.asp?serial=" & pFileSerial & "&""><img border=0 src=""images/download.gif"">&nbsp;点击这里下载文件</a></td></tr>" & vbLF & _
		"<tr bgcolor=white><td nowrap align=center>文件类型：</td><td nowrap class=tdValue>" & sFileType & "</td></tr>" & vbLF & _
		"<tr bgcolor=white><td nowrap align=center>文件大小：</td><td nowrap class=tdValue>" & TransFileSize(sFileSize) & " ( " & FormatNumber(sFileSize,0) & " 字节 )" & "</td></tr>" & vbLF & _
		"<tr bgcolor=white><td nowrap align=center>内容类型：</td><td nowrap class=tdValue>" & sContentType & "</td></tr>" & vbLF & _
		"<tr bgcolor=white><td nowrap align=center>上载时间：</td><td nowrap class=tdValue>" & sUploadTime & "</td></tr>" & vbLF & _
		"<tr bgcolor=white><td nowrap align=center>所在目录：</td><td nowrap class=tdValue>" & sFileFolder & "</td></tr>" & vbLF & _
		"<tr bgcolor=white><td nowrap align=center>共 享 给：</td><td class=tdValue>" & sOpenTo & "</td></tr>" & vbLF & _
		sActionLink & vbLF & _
		"</table>" & vbLF
End Function


Function TableLink()
	TableLink = _
		"<br><table width=600 cellspacing=0 cellpadding=0 border=0 align=center>" & vbLF & _
		"<tr height=10>" & vbLF & _ 
		"	<td width=600><img src=""../images/bg/line.gif"" width=600 height=3></td>" & vbLF & _
		"</tr>" & vbLF & _
		"<tr height=20>" & vbLF & _
		"	<td width=600>&nbsp;" & vbLF & _
			"<img src=""../images/goto.gif"">&nbsp;<a href=""file_l.asp"">文件列表</a>" & vbLF & _
			"&nbsp;&nbsp;&nbsp;&nbsp;" & vbLF & _
			"<img src=""../images/goto.gif"">&nbsp;<a href=""getfile.asp"">上传文件</a></td>" & vbLF & _
		"</tr>" & vbLF & _
		"</table>" & vbLF
End Function

%>