复件 typemgr.inc

物业管理和办公自动化系统

<%
Sub TypeMaintain()
	dim sTypeOld, sTypeNew, sAction, sSQL, sError
	sError = ""
	sAction = GetParam("formAction")
	sAction = LCase(sAction)
	select case sAction
	case "addtype"
		sTypeNew = GetParam("newtypename")
		sSQL = "insert into T_Rule_Types values(" & ToSQL(sTypeNew,"Text") & ")"
		sError = ExecuteSQL(dbLocal, sSQL)

	case "updtype"
		sTypeOld = GetParam("oldtypename")
		sTypeNew = GetParam("newtypename")
		sSQL = "update T_Rule_Types set type=" & ToSQL(sTypeNew, "Text") & " where Type =" & ToSQL(sTypeOld, "Text")
		sError = ExecuteSQL(dbLocal, sSQL)

	case "deltype"
		sTypeOld = GetParam("oldtypename")
		'------------------------------------
		' 判断一下如果该类别下面的制度存在，就不删除
		'------------------------------------
		dim crs	: set crs = New CRecordset
		dim s: s = "select count(*) c from t_rule_info where type=" & ToSQL(sTypeOld,"Text")
		
		dim rs	: set rs = crs.open(dbLocal,s)
		
		dim c : c = crs.GetValue("c")
		if c > 0 then
			sError = "del_error"
			crs.Close()
		else
			crs.Close()
			sSQL = "delete from T_Rule_Types where type = " & ToSQL(sTypeOld,"Text")
			sError = ExecuteSQL(dbLocal, sSQL)

		end if

	end select



	if sError <> "" then
		if sAction = "addtype" then
			Response.Write "<script language=""javascript"">alert('对不起，制度类别已存在，不能重复新增！')</script>"
			exit sub
		end if
		if sAction = "deltype" then
			Response.Write "<script language=""javascript"">alert('对不起，制度类别下存在制度，不能删除该类别！')</script>"
			exit sub
		end if
		Response.Write "<script language=""javascript"">alert('对不起，操作中发生错误，请查阅帮助文件！')</script>"
	end if
End Sub

Function TableAdd()
	'' 任务分类，0为所有任务，1为普通任务，2为会议相关的任务，3为审批相关的任务
	'' 任务完成状况，0全部，1所有已完成任务，2所有未完成任务，3所有正常的未完成任务，4所有过时的未完成任务
	'' 开始日期的日历
	'' 结束日期的日历
	Dim sTypeText,sFormName, sTemp
	sTypeText = GetParam("type")
	sTemp = "<td width=300><table width=300 cellspacing=0 cellpadding=0 border=0><tr><td width=300 align=center>"
	if IsEmpty(sTypeText) then
		sTypeText = ""
		sTemp = sTemp & _
			"<span id=btnAdd style=""cursor:hand"" title=""填写需新增的类别名称，点击新增按钮""><img border=0 src=""../images/button/add.gif"" style=""vertical-align:bottom""></span>" & _
			"&nbsp;" & _
			"<span id=btnClear style=""cursor:hand"" title=""清空""><img border=0 src=""../images/button/clear.gif"" style=""vertical-align:bottom""></span>"

	else
		sTemp = sTemp & _
			"<span id=btnMod style=""cursor:hand"" title=""修改类别名称，点击更新按钮""><img border=0 src=""../images/button/update.gif"" style=""vertical-align:bottom""></span>" & _
			"&nbsp;" & _
			"<span id=btnDel style=""cursor:hand"" title=""点击删除按钮删除类别名称""><img border=0 src=""../images/button/delete.gif"" style=""vertical-align:bottom""></span>" & _
			"&nbsp;" & _
			"<span id=btnRes style=""cursor:hand"" title=""重置""><img border=0 src=""../images/button/reset.gif"" style=""vertical-align:bottom""></span>" & _
			"&nbsp;" & _
			"<span id=btnCancel style=""cursor:hand"" title=""取消""><img border=0 src=""../images/button/cancel.gif"" style=""vertical-align:bottom""></span>"
	end if
	sTemp = sTemp & "</td></tr></table></td>"
	TableAdd = _
		TableTitle("填写需新增的类别信息", 300, "", "") & _
		"<table cellspacing=0 cellpadding=0 width=300 align=left border=0>" & _

		"<form name=frmTypeMgr method=post action=""typemgr.asp"">"  & _
		
		"<tr height=60 valign=bottom>" & _
		"	<td width=300 align=center colspan=3>" & _
		"		类别信息：<input type=text name=newtypename value='" & sTypeText & "' size=25 maxlength=25>" & _
		"		<input type=hidden name=oldtypename value='" & sTypeText & "' size=30>" & _
		"		<input type=hidden name=formAction>" & _
		"	</td>" & _
		"   </tr>" & _
		"<tr height=40 align=center>" & _
			sTemp & _
		"</tr>" & _
		"<tr height=10><td colspan=3 width=300>&nbsp;</td></tr>" & _
		"</form>" & _
		"</table>"
'		"   " & _
'		"	<td width=120 align=right><span id=btnAdd style=""cursor:hand"" title=""填写需新增的类别名称，点击新增按钮""><img border=0 src=""../images/button/add.gif"" style=""vertical-align:bottom""></span>&nbsp;</td>" & _
'		"	<td width=60 align=center><span id=btnMod style=""cursor:hand"" title=""修改类别名称，点击更新按钮""><img border=0 src=""../images/button/update.gif"" style=""vertical-align:bottom""></span>&nbsp;</td>" & _
'		"	<td width=120 align=left><span id=btnDel style=""cursor:hand"" title=""点击删除按钮删除类别名称""><img border=0 src=""../images/button/delete.gif"" style=""vertical-align:bottom""></span></td></tr>" & _

End Function

Function TableHeader()
	sFileName = "typemgr.asp"
	TableHeader = _
		TableTitle("系统现有的制度类别列表", 300, "", "#0040a0") & _
		"<table cellspacing=0 cellpadding=0 width=300 align=center class=tablelist>" & _
		"<tr>" & _
		"<td class=tdHead>&nbsp;" & TableHeaderField(sFileName, "type", "类别名称", sFormParams, iSort, iSorted) & "</td>" & _
		"</tr>"
End Function

Function TableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams)
	dim sTemp	: sTemp = ""		' 临时字符串变量
	dim j					' 临时循环变量

	'------------------------------------
	' 分页所需的变量定义
	'------------------------------------
	Dim iCounter		: iCounter = 1
	Dim iPrevPage, iNextPage
	
	'------------------------------------
	' 获取数据库连接
	'------------------------------------
	dim crs	: set crs = New CRecordset
	dim rs	: set rs = crs.open(dbLocal,sSQL)
	dim sRuleType
	
	' 如果未到记录尾，将记录定位到你翻到的页面的第一个记录，否则显示空行
	if Not rs.EOF then	
		rs.Move (iCurrentPage - 1) * iRecordsPerPage
	end if
	while not rs.EOF and iCounter <= iRecordsPerPage
		sRuleType			= crs.GetValue("type")

		sTemp = sTemp & "<tr>" & _
				"<td class=tdlist  title='" & sRuleType & "' style=""cursor:hand"" onclick=""javascript:location.href='../rulemgr/typemgr.asp?type=" & sRuleType & "';"">&nbsp;<img src=""../images/bg/ar-g.gif"" width=8 height=8>&nbsp;"  & sRuleType & "&nbsp;</td>" & _
				"</tr>"
		iCounter = iCounter + 1
		rs.movenext
	wend
	crs.Close()

	' 填补空白行
	sTemp = sTemp & WhiteRows(iCols, iCounter, iRecordsPerPage)

	' 首页、前页、后页、尾页等分页信息
	sTemp = sTemp & "<tr><td class=tdlist colspan=" & iCols & " align=right>" & _
				Paginate(sFileName, sFormParams, sSortParams, iCurrentPage, iTotalPages) & _
				"&nbsp;</td></tr>"
	TableRecords = sTemp
End Function


Function TableLink()
	TableLink = _
		"<table width=400 cellspacing=0 cellpadding=0 border=0 align=left>" & _
		"<tr height=10>" & _ 
		"	<td width=600><img src=""../images/bg/line.gif"" width=400 height=3></td>" & _
		"</tr>" & _
		"<tr height=20 align=left>" & _
		"	<td width=400 align=left>&nbsp;" & _
		"		<img src=""../images/goto.gif"" >&nbsp;<a href=""infomgr.asp"">制度管理</a>" & _
		"		&nbsp;&nbsp;&nbsp;" & _
		"		<img src=""../images/goto.gif"" >&nbsp;<a href=""searchmgr.asp"">制度查询管理</a>" & _
		"</tr>" & _
		"</table>"
End Function
%>