datahandle.inc

物业管理和办公自动化系统

<%
'************************************************************************************************
' 文件名: datahandle.inc
' Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司

' 　创建人 : 周秋舫
' 　日　期 : 2002-05-08
' 修改历史 :
'   ****年**月**日 ****** 修改内容:**************************************************
' 功能描述 : 用于数据处理的常用函数
'		GetParam(ParamName)	: 获取名称ParamName的参数的值
'		ToHTML(str)			: 将str转换为HTML编码后返回
'		ToURL(str)				: 将str转换为URL编码后返回
'		ToSQL(sql)				: 变换SQL语句
'		FormatDT(dt,format)		: 将日期转换成格式字符串	
'		Bref(str, length)			: 将字符串转换成形如 “ *****... ” 的缩写形式
'		GetCheckBoxValue		:
' 　版　本 :
'************************************************************************************************


'************************************************************************************************
' 函数名　: GetParam
' 输　入　: ParamName ---- 字符串类型的任意值
' 输　出　: GetParam函数名作为返回值，类型为字符串
' 功能描述: 获取页面传递的参数，先从URL中取，找不到的话再从Form中取特定的参数，找不到返回empty
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-05-09
' 版　本　: 
'************************************************************************************************
Function GetParam(ParamName)
	Dim Param
	  
	if Request.QueryString(ParamName).Count > 0 then 
		Param = Request.QueryString(ParamName)
	elseif Request.Form(ParamName).Count > 0 then
		Param = Request.Form(ParamName)
	else 
		Param = ""
	end if
	if Param = "" then
		GetParam = Empty
	else
		GetParam = Param
	end if
End Function


'************************************************************************************************
' 函数名　: ToHTML
' 输　入　: sValue ---- 字符串类型的任意值
' 输　出　: ToHTML函数名作为返回值，类型为HTML编码后的字符串
' 功能描述: 将输入参数值转换为HTML编码后返回
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-05-09
' 版　本　: 
'************************************************************************************************
Function ToHTML(sValue)
  if IsNull(sValue) then 
    ToHTML = ""
  else
    ToHTML = Server.HTMLEncode(sValue)
  end if
End Function

'************************************************************************************************
' 函数名　: ToURL
' 输　入　: sValue ---- 字符串类型的任意值
' 输　出　: ToURL函数名作为返回值，类型为URL编码后的字符串
' 功能描述: 将输入参数值转换为URL编码后返回
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-05-09
' 版　本　: 
'************************************************************************************************
Function ToURL(sValue)
  if IsNull(sValue) then sValue = ""
  ToURL = Server.URLEncode(sValue)
End Function

'************************************************************************************************
' 函数名　: ToSQL
' 输　入　: value ---- 字符串类型的任意值
' 　　　　  sType ---- 类型
' 输　出　: ToSQL函数名作为返回值，类型为字符串
' 功能描述: 主要用于变换SQL语句，对于整型值，将逗号改为点；对于非整型值，先将单引号变为两个单引号，然后再在首尾加单引号
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-05-09
' 版　本　: 
'************************************************************************************************
Function ToSQL(Value, sType)
	Dim Param : Param = Value
	if Param = "" then
		ToSQL = "Null"
	else
		if sType = "Number" then
			ToSQL = replace(CDbl(Param), ",", ".")
		else
			ToSQL = "'" & Replace(Param, "'", "''") & "'"
		end if
	end if
End Function

'************************************************************************************************
' 函数名　: FormatDT
' 输　入　: dt		---- 日期时间，类型为日期或可转换成日期的字符串
' 　　　　  format	---- 转换格式，类型为字符串
' 输　出　: FormatDT函数名作为返回值，类型为字符串
' 功能描述: 将日期转换成格式字符串
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-05-29
' 版　本　: 
'************************************************************************************************
Function FormatDT(dt, format)
	if Not IsDate(dt) then
		FormatDT = ""
		exit function
	end if
	dim y, m, mm, d, dd, h, mi
	dt = CDate(dt)							' dt:    先将参数转换成日期
	y = Year(dt)							' y:     取出年份
	m = Month(dt)							' m:    取出月份
	if m < 10 then mm = "0" & m else mm = m		' mm: 双位月份
	d = Day(dt)							' d: 	  取出日期
	if d < 10 then dd = "0" & d else dd = d			' dd:   双位日期
	h = Hour(dt)							' h:     时
	if h < 10 then h = "0" & h
	mi = Minute(dt)							' mi:   分
	if mi < 10 then mi = "0" & mi
	Select Case format
	case "yyyy-mm-dd hh:mm"
		FormatDT = y & "-" & mm & "-" & dd & " " & h & ":" & mi
	case "yyyy-mm-dd"
		FormatDT = y & "-" & mm & "-" & dd
	case "yyyy年mm月dd日"
		FormatDT = y & "年" & mm & "月" & dd & "日"
	case "m月d日 hh:mm"
		FormatDT = m & "月" & d & "日 " & h & ":"& mi
	case "m月d日"
		FormatDT = m & "月" & d & "日 " 
	case "hh:mm"
		FormatDT =  h & ":"& mi
	case "m/d hh:mm"
		FormatDT = m & "/" & d & " " & h & ":"& mi
	case else
		'' yyyy-mm-dd
		FormatDT = y & "-" & mm & "-" & dd
	End Select
End Function

'************************************************************************************************
' 函数名　: Bref
' 输　入　: s		---- 要转换的字符串
' 　　　　  format	---- 转换后子串的最大长度
' 输　出　: Bref函数名作为返回值，类型为字符串
' 功能描述: 将给定子串转换成形如 “ ****.... ” 的字符串
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-05-29
' 版　本　: 
'************************************************************************************************
Function Bref(s, l)
	if len(s) > l then
		Bref = left(s, l - 2) & "..."
	else
		Bref = s
	end if
End Function

'************************************************************************************************
' Obtain Checkbox value depending on field type
' 这个函数是从codechange中copy过来的，好像我们也没用到过CheckBox，就先留着吧
'************************************************************************************************
function GetCheckBoxValue(sVal, CheckedValue, UnCheckedValue, sType)
	if isempty(sVal) then
		if UnCheckedValue = "" then
			getCheckBoxValue = "Null"
		else
			if sType = "Number" then
				getCheckBoxValue = UnCheckedValue
			else
				getCheckBoxValue = "'" & Replace(UnCheckedValue, "'", "''") & "'"
			end if
		end if
	else
		if CheckedValue = "" then
			getCheckBoxValue = "Null"
		else
			if sType = "Number" then
				getCheckBoxValue = CheckedValue
			else
				getCheckBoxValue = "'" & Replace(CheckedValue, "'", "''") & "'"
			end if
		end if
	end if
end function
%>