test2.inc

物业管理和办公自动化系统

<%
'************************************************************************************************
' 文件名: list.inc
' Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司

' 创建人: 周秋舫
' 日　期:   2002-05-08
' 修改历史:
'   ****年**月**日 ****** 修改内容:**************************************************
' 描　述:
' 版　本:
'************************************************************************************************


'************************************************************************************************
' 函数名　: TableHeader
' 输　入　: (无) 
' 输　出　: TableHeader函数名作为返回值，类型为字符串
' 功能描述: 表格头，确定表格的宽度等属性，描绘表头各字段
' 调用模块: TableHeaderField(sFileName, sField, sFieldName, sFormParams, sSorting, sSorted)
' 作　者　: 周秋舫
' 日　期　: 2002-05-08
' 版　本　: 
'************************************************************************************************
Function TableHeader()
	TableHeader = _
		"<table cellspacing=0 cellpadding=0 class=tablelist width=700px align=center>" & _
		"<tr><td class=tblTitle colspan=9>个人名片列表</td></tr>" & _
		"<tr>" & _
		"<td class=tdHead>" & TableHeaderField(sFileName, "name", "姓名", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead>" & TableHeaderField(sFileName, "company_name", "公司名称", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead>" & TableHeaderField(sFileName, "position_id", "职务", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead>" & TableHeaderField(sFileName, "phone", "单位电话", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead>" & TableHeaderField(sFileName, "fax", "传真", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead>" & TableHeaderField(sFileName, "email", "电子信箱", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead>属性</td>" & _
		"<td class=tdHead>修改</td>" & _
		"<td class=tdHead>删除</td>" & _
		"</tr>"
End Function

'************************************************************************************************
' 函数名　: TableTailer
' 输　入　: (无) 
' 输　出　: TableTailer函数名作为返回值，类型为字符串
' 功能描述: 表格尾
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-05-08
' 版　本　: 
'************************************************************************************************
Function TableTailer()
	TableTailer = "</table>"
End Function

'************************************************************************************************
' 函数名　: TableRecords
' 输　入　: sSQL
' 　　　　  sSQL             ---- SQL查询语句
' 　　　　  iCols            ---- 列数，共有多少列
' 　　　　  iCurrentPage     ---- 当前所处的页码
' 　　　　  iTotalPages      ---- 总页数
' 　　　　  iRecordsPerPage  ---- 每页显示的记录数
' 　　　　  iTotalRecords    ---- 总的记录数
' 　　　　  sFileName			---- 分页链接文件名
' 　　　　  sFormParams		---- 分页链接传递的参数
' 　　　　  sSortParams		---- 分页链接传递的排序参数
' 输　出　: TableRecords函数名作为返回值，类型为字符串
' 功能描述: 数据库数据以表格形式显示出来
' 调用模块: Paginate函数分页
' 作　者　: 周秋舫
' 日　期　: 2002-05-08
' 版　本　: 
'************************************************************************************************

Function TableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams)
	Dim sTemp			: sTemp = ""

	' 分页所需的变量定义
	Dim iCounter		: iCounter = 0
	Dim iPrevPage, iNextPage

	'------------------------------------
	' 获取数据库连接
	'------------------------------------
	dim crs	: set crs = New CRecordset
	dim rs	: set rs = crs.open(dbLocal,sSQL)

	rs.Move (iCurrentPage - 1) * iRecordsPerPage	' 将记录定位到你翻到的页面的第一个记录

	if rs.EOF then
		sTemp = sTemp & "<tr><td class=tdlist colspan=" & iCols & " align=center style=""color:#cccccc"">&nbsp;&nbsp;（哎呀，什么也没找到！）</td></tr>"
	end if
	while not rs.EOF and iCounter < iRecordsPerPage
		m_serial		= crs.GetValue("serial")
		m_emp_serial	= crs.GetValue("emp_serial")
		m_name		= crs.GetValue("name")
		m_company_name	= crs.GetValue("company_name")
		m_position_id   = crs.GetValue("position_id")
		m_phone		= crs.GetValue("phone")
		m_fax	     = crs.GetValue("fax")
		m_email	     = crs.GetValue("email")

		m_desp	= DLookUp(dbLocal, "t_position", "position_desc", "pisition_id = " & m_position_id)

		' 公司名称缩写，如果长度超过8，则采用缩写形式
		m_company_name_bref = m_company_name
		if len(m_company_name) > 8 then m_company_name_bref = left(m_company_name, 6) & "...."

		' Email的缩写，如果长度超过10，则采用缩写形式
		m_email_bref = m_email
		if len(m_email) > 14 then m_email_bref = left(m_email, 10) & "...."

		sTemp = sTemp & "<tr>" & _
				"<form name=formList action=""list.asp"" method=""post"">" & _
				"<input type=hidden name=serial value=""" & m_serial & """>" & _
				"<td class=tdlist>&nbsp;" & m_name & "&nbsp;</td>" & _
				"<td class=tdlist title='" & m_company_name & "'>&nbsp;" & m_company_name_bref & "&nbsp;</td>" & _
				"<td class=tdlist align=center>&nbsp;" & m_desp & "&nbsp;</td>" & _
				"<td class=tdlist>&nbsp;" & m_phone & "&nbsp;</td>" & _
				"<td class=tdlist>&nbsp;" & m_fax & "&nbsp;</td>" & _
				"<td class=tdlist title='" & m_email & "'>&nbsp;" & m_email_bref & "&nbsp;</td>" & _
				"<td class=tdlist align=center><a href='property.asp?serial=" & m_serial & "'><img border=0 src='../images/property.gif'></a></td>"
		
		' 只能修改自己的名片
		if m_emp_serial = emp_serial then 
			sTemp = sTemp & "<td class=tdlist align=center>" & _
					"<a href='detail.asp?command=modify&serial=" & m_serial & "'><img border=0 src='../images/modify.gif'></a>" & _
					"</td>" & vbLF & _
					"<td class=tdlist align=center>" & _
					"<a style='cursor:hand' OnClick=""javascript:if(window.confirm('真的想删除名片『"& m_name & "』，你的确想清楚了？')) location.href='list.asp?command=delete&serial=" & m_serial & "'""><img border=0 src='../images/delete.gif'></a>" & _
					"</td>"
		else
			sTemp = sTemp & "<td class=tdlist align=center>-</td><td class=tdlist align=center>-</td>"
		end if
		sTemp = sTemp & "</form></tr>"
		iCounter = iCounter + 1
		rs.movenext
	wend
	rs.close

	' 首页、前页、后页、尾页等分页信息
	sTemp = sTemp & "<tr><td class=tdlist colspan=" & iCols & " align=right>" & _
				Paginate(sFileName, sFormParams, sSortParams, iCurrentPage, iTotalPages) & _
				"&nbsp;</td></tr>"
	TableRecords = sTemp
End Function
%>