emp.inc

物业管理和办公自动化系统

<%
'************************************************************************************************
' 文件名: emp.inc
' Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司

' 　创建人 : 周秋舫
' 　日　期 : 2002-06-03
' 修改历史 :
'   ****年**月**日 ****** 修改内容:**************************************************
' 功能描述 : 跟员工信息有关的函数
'	TransEmpSerial(sEmpSerialList)		: 将员工序列号列表(以逗号分隔)转化成员工姓名列表(以逗号分隔)
'	EmpOwnerSelectOptions(iDefault)	: 业主员工姓名的<option></option>对
'
' 　版　本 :
'************************************************************************************************

Function TransEmpId(db, sEmpId)
	on error resume next
	TransEmpId = DLookUp(dbLocal, "t_employee", "name", "serial = (select emp_serial from t_account where account_id = " & ToSQL(sEmpId, "Text") & ")")
	on error goto 0
End Function

'************************************************************************************************
' 函数名　: TransEmpSerial(db, sEmpSerialList)
' 输　入　: db			: 指明连接到哪个数据库
'		sEmpSerialList	: 一组以逗号连接的员工序列号的字符串
' 输　出　: 一组以逗号连接的员工姓名
' 功能描述: 将一组以逗号连接的员工序列号转换成一组以逗号连接的员工姓名的字符串
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-05-09
' 版　本　: 
'************************************************************************************************
Function TransEmpSerial(db, sEmpSerialList)
	on error resume next
	dim crs, rs
	set crs = New CRecordset
	set rs = crs.Open(db, "proc_transEmpSerial " & ToSQL(sEmpSerialList,"Text"))
	TransEmpSerial = crs.GetValue("namelist")

	crs.Close()
	on error goto 0
End Function

Function EmpOwnerSelectOptions(iDefault)
	dim sWhere, sTemp
	sWhere = "co_id = 1 and isDummy = 0 and dismissed = 0"
	EmpOwnerSelectOptions = SelectOptions(dbLocal, "T_Employee", "serial", "name", iDefault, sWhere)
End Function

Function OwnerDepartmentSelectOptions(iDefault)
	dim sWhere, sTemp
	sWhere = "isgroup = 1 and co_id = 1"
	OwnerDepartmentSelectOptions = SelectOptions(dbLocal, "T_Node", "node_id", "node_name", iDefault, sWhere)
End Function

Function RoleSelectOptions(iDefault)
	dim sWhere, sTemp
	RoleSelectOptions = SelectOptions(dbLocal, "T_Role", "role_id", "role_desp", iDefault, sWhere)
End Function

'************************************************************************************************
' 函数名　: TransDepartment(db, iDepartment)
' 输　入　: db			: 指明连接到哪个数据库
'		iDepartment	: 一个部门的node_id
' 输　出　: 一个部门的名称
' 功能描述: 将一个部门的node_id转换成该部门的名称
' 调用模块: 
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-15
' 版　本　: 
'************************************************************************************************
Function TransDepartment(db, iDepartment)
'	on error resume next
	dim crs, rs, sSQL
	sSQL = "select * from T_Node where node_id = "&iDepartment
	set crs = New CRecordset
	set rs = crs.Open(db, sSQL)
	TransDepartment = crs.GetValue("node_name")
	crs.Close()
	on error goto 0
End Function

'************************************************************************************************
' 函数名　: TransRole(db, iRoleid)
' 输　入　: db: 指明连接到哪个数据库;iRoleid:角色id
' 输　出　: 一个角色的名称
' 功能描述: 将一个角色的roleid转换成该角色的名称
' 调用模块: 
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-31
' 版　本　: 
'************************************************************************************************
Function TransRole(db, iRoleid)
'	on error resume next
	dim crs, rs, sSQL
	sSQL = "select * from T_Role where role_id = "&iRoleid
	set crs = New CRecordset
	set rs = crs.Open(db, sSQL)
	TransRole = crs.GetValue("role_desp")
	crs.Close()
	on error goto 0
End Function

'************************************************************************************************
' 函数名　: TransRoletype(db, sRoletype)
' 输　入　: db: 指明连接到哪个数据库;sRoletype:角色类型（'a'或者'u'）
' 输　出　: 一个角色的类型的描述
' 功能描述: 将一个角色的类型转换成该类型的描述
' 调用模块: 
' 作　者　: 蔡晓燕
' 日　期　: 2002-08-01
' 版　本　: 
'************************************************************************************************
Function TransRoletype(db, sRoletype)
'	on error resume next
	select case sRoletype
	case "a"
		TransRoletype = "系统预定义"
	case "u"
		TransRoletype = "用户自定义"
	end select
	on error goto 0
End Function

'************************************************************************************************
' 函数名　: TransMeetingstatus(db, iMeetingstatus)
' 输　入　: db			: 指明连接到哪个数据库
'		iMeetingstatus	: 一个会议的状态
' 输　出　: 一个会议状态的描述
' 功能描述: 将一个会议状态的值转换成该状态的描述
' 调用模块: 
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-18
' 版　本　: 
'************************************************************************************************
Function TransMeetingstatus(db, iMeetingstatus)
'	on error resume next
	dim crs, rs, sSQL
	sSQL = "select * from T_MeetingStatus where meeting_status = "&iMeetingstatus
	set crs = New CRecordset
	set rs = crs.Open(db, sSQL)
	TransMeetingstatus = crs.GetValue("status_desp")
	crs.Close()
	on error goto 0
End Function

'************************************************************************************************
' 函数名　: TransMeetingDay(iMeetingday)
' 输　入　: iMeetingday	: 例会的召开日，为数字1-7，表示星期一到星期日
' 输　出　: 一个会议召开日的描述
' 功能描述: 将一个会议召开日的值转换成该召开日的描述
' 调用模块: 
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-25
' 版　本　: 
'************************************************************************************************
Function TransMeetingday(iMeetingday)
'	on error resume next
	select case iMeetingday
	case 1
		TransMeetingday = "星期一"
	case 2
		TransMeetingday = "星期二"
	case 3
		TransMeetingday = "星期三"
	case 4
		TransMeetingday = "星期四"
	case 5
		TransMeetingday = "星期五"
	case 6
		TransMeetingday = "星期六"
	case 7
		TransMeetingday = "星期日"
	end select
	on error goto 0
End Function

Function TransRoleStatus(iStatus)
'	on error resume next
	select case iStatus
	case 0
		TransRoleStatus = "正常"
	case 1
		TransRoleStatus = "锁定"
	end select
	on error goto 0
End Function

'************************************************************************************************
' 函数名　: EmpUnderlingsSelectOptions(iDefault)
' 输　入　: iDefault			: 指明缺省选中的员工的serial
' 输　出　: 一组员工姓名的下拉列表的选项
' 功能描述: 将当前用户所在部门的别的岗位（指和当前员工处于不同的岗位的）的员工的列表显示出来
' 调用模块: 
' 作　者　: 蔡晓燕
' 日　期　: 2002-06-14
' 版　本　: 
'************************************************************************************************
Function EmpUnderlingsSelectOptions(iDefault)
	dim sWhere, sTemp, iDepartmentId, iNodeId
	iDepartmentId = GetDepartmentId
	iNodeId = GetNodeId
	sWhere = "co_id = 1 and isDummy = 0 and dismissed = 0 and node_id in " & _
	"(select node_id from T_node where parent_node_id = "& iDepartmentId & ") and node_id <> "& _
	iNodeId
	EmpUnderlingsSelectOptions = SelectOptions(dbLocal, "T_Employee", "serial", "name", iDefault, sWhere)
End Function

'************************************************************************************************
' 函数名　: OwnerLevel2DepartmentSelectOptions(iDefault)
' 输　入　: iDefault			: 指明缺省选中的部门的serial
' 输　出　: 一组部门名称的下拉列表的选项
' 功能描述: 将信息世界公司（co_id=1）的二级（node_level = 2）部门的列表显示出来
' 调用模块: plandepartments.inc
' 作　者　: 蔡晓燕
' 日　期　: 2002-06-14
' 版　本　: 
'************************************************************************************************
Function OwnerLevel2DepartmentSelectOptions(iDefault)
	dim sWhere, sTemp
	sWhere = "isgroup = 1 and co_id = 1 and node_level = 2 "
	OwnerLevel2DepartmentSelectOptions = SelectOptions(dbLocal, "T_Node", "node_id", "node_name", iDefault, sWhere)
End Function

'************************************************************************************************
' 函数名　: RoutinemeetingSelectOptions(iDefault)
' 输　入　: iDefault			: 指明缺省选中的例会的serial
' 输　出　: 一组例会名称的下拉列表的选项
' 功能描述: 将例会表中的例会名称的列表显示出来
' 调用模块: routinemeeting.inc
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-28
' 版　本　: 
'************************************************************************************************
Function RoutinemeetingSelectOptions(iDefault)
	dim sWhere, sTemp
	sWhere = ""
	RoutinemeetingSelectOptions = SelectOptions(dbLocal, "T_Routinemeeting", "meeting_serial", "meeting_name", iDefault, sWhere)
End Function

'************************************************************************************************
' 函数名　: GetAttendeelist(sAttendee)
' 输　入　: sAttendee			: 一组员工empserial以逗号隔开的字符串，例如："52,53,55,60"
' 输　出　: 一组员工姓名的下拉列表的选项
' 功能描述: 将 co_id = getcoid 的员工中serial属于sAttendee的员工姓名列表显示出来
' 调用模块: applymeeting.inc
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-11
' 版　本　: 
'************************************************************************************************
function GetAttendeelist(sAttendee)
	dim strData, crs, rs, sSQL, iEmpSerial, sName, Res
	Res = ""
	sSQL = "SELECT * FROM T_employee WHERE co_id = 1 and isDummy = 0 and dismissed = 0"
	strData = sAttendee
	if ISNULL(strData) then
	else
		strData = replace(strData," ","")
		strData = ","+strData+","
		set crs = New CRecordset
		set rs = crs.open(dbLocal,sSQL)
		while not rs.eof
		iEmpSerial = crs.GetValue("serial")
		sName = crs.GetValue("name")
			 if Instr(strData, iEmpSerial) > 0 then 
				 Res = Res & vbTab & "<option value=""" & iEmpSerial &""">"& sName & "</option>" & VBLF
			 end if			  
			 rs.movenext
		wend
	end if
	GetAttendeelist = Res
end function

'************************************************************************************************
' 函数名　: GetRemainlist(sAttendee)
' 输　入　: sAttendee			: 一组员工empserial以逗号隔开的字符串，例如："52,53,55,60"
' 输　出　: 一组员工姓名的下拉列表的选项
' 功能描述: 将 co_id = getcoid 的员工中serial不属于sAttendee的员工姓名列表显示出来
' 调用模块: applymeeting.inc
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-11
' 版　本　: 
'************************************************************************************************
function GetRemainlist(sAttendee)
	dim strData, crs, rs, sSQL, iEmpSerial, sName, Res
	Res = ""
	sSQL = "SELECT * FROM T_employee WHERE co_id = 1 and isDummy = 0 and dismissed = 0"
	strData = sAttendee
	if ISNULL(strData) then
	else
		strData = replace(strData," ","")
		strData = ","+strData+","
		set crs = New CRecordset
		set rs = crs.open(dbLocal,sSQL)
		while not rs.eof
		iEmpSerial = crs.GetValue("serial")
		sName = crs.GetValue("name")
			 if Instr(strData, iEmpSerial) <= 0 then 
				 Res = Res & vbTab & "<option value=""" & iEmpSerial &""">"& sName & "</option>" & VBLF
			 end if			  
			 rs.movenext
		wend
	end if
	GetRemainlist = Res
end function

' ==================================================================
' 函数名称：Isattendee(sAttendee,sEmpserial)
' 函数功能：判断",sEmpserial,"是否包含在",sAttendee,"中
' 输入参数：sAttendee,sEmpserial都是字符串
' 返回值：  true/false,表示是/否包含。
' 调用模块: historymeeting.inc
' 作　者　: 蔡晓燕
' 日　期　: 2002-08-15
' 版　本　: 

' ==================================================================
function Isattendee(sAttendee,sEmpserial)
	Dim strAttendee, strEmpSerial
	if Isnull(sAttendee) or Isnull(sEmpserial) then
		response.write "参会人员或当前用户为null!"
'		response.end
		Isattendee = false
	else 
		strAttendee = replace(sAttendee," ","")
		strAttendee = ","&strAttendee &","
		strEmpSerial = ","&sEmpserial&","
		if Instr(strAttendee,strEmpSerial) > 0 then 
			Isattendee = true
		else 
			Isattendee = false
		end if
	end if
end function

%>