newroutinemeeting.inc

物业管理和办公自动化系统

<%
'************************************************************************************************
' 函数名　: FormMeetingTable(iMeetingSerial)
' 输　入　: iMeetingSerial:会议序列号，如果是新申请会议，那么iMeetingSerial=0，表示一张空的表
' 输　出　: 一张新增、修改、删除例会的表单
' 功能描述: 根据例会序列号，把相应的例会信息显示出来
' 调用模块: newroutinemeeting.inc
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-24
' 版　本　: 
'************************************************************************************************
Function FormMeetingTable(iMeetingSerial)
	'------------------------------------
	' 根据会议的MeetingSerial,画出相应的会议申请表，显示原来的会议信息，供修改
	'------------------------------------
	dim sSQL, iExecuter, sMeetingName, sTask, iDepartment, sMeetingRoom, sPresider, dStart_time
	dim sAttendee, iProposer, rt, rm, sError, iMeetingday, iFrequence, iRemindbeforedays
	dim sTemp, sTempButtons
	dim crs, rs
	sSQL = "select * from T_Routinemeeting where meeting_serial = "& iMeetingSerial
	set crs = New CRecordset
	set rs = crs.open(dbLocal,sSQL)
'	response.write ssql
'	response.end
	if not rs.eof then 
		sMeetingName = crs.GetValue("meeting_name")
		sTask = crs.GetValue("task")
		sMeetingRoom = crs.GetValue("meeting_room")
		sPresider = crs.GetValue("presider")
		dStart_time = crs.GetValue("meeting_time")
		iDepartment = crs.GetValue("node_id")
		sAttendee = crs.GetValue("attendee")
		iFrequence = crs.GetValue("frequence")
		iRemindbeforedays = crs.GetValue("remindbeforedays")
		iMeetingday = crs.GetValue("meeting_day")
		sTempButtons=_
		"		<img border=0 src=""../images/button/update.gif"" style=""cursor:hand"" name=btnSubmit>" & _
		"		<img border=0 src=""../images/button/delete.gif"" style=""cursor:hand"" name=btnDelete>" & _
		"		<img border=0 src=""../images/button/reset.gif"" style=""cursor:hand"" name=btnReset>" 
	else
		sMeetingName = ""
		sTask = ""
		sMeetingRoom = ""
		sPresider = ""
		dStart_time = "13:30"
		iDepartment = 0
		iFrequence = 1
		iRemindbeforedays = 1
		iMeetingday = 1
		sAttendee = ""
		sTempButtons=_
		"		<img border=0 src=""../images/button/submit.gif"" style=""cursor:hand"" name=btnSubmit>" & _
		"		<img border=0 src=""../images/button/clear.gif"" style=""cursor:hand"" name=btnCancel>"
	end if

	FormMeetingtable=_
		TableTitle("例会信息表", 600, "", "#0040a0") & _
		"<table cellspacing=0 cellpadding=0 width=600 align=center border=0 >" & _
		"<form name=""frmnewroutinemeeting"" method=post action=""newroutinemeeting.asp"">"  
		FormMeetingTable = FormMeetingTable & _
		"<tr height=30>" & _
		"	<td width=115 align=right>例会名称：</td>" & _
		"	<td width=485 colspan=3><input name=""mtName""  value=""" & sMeetingName & """ size=64  type=""text"" maxlength=128></td>"&_
		"</tr>" & _
		"<tr height=30>" & _
		"	<td width=115 align=right>例会类型：</td>"&_
		"	<td width=485 colspan=3><select name=""frequence"" style=""width:394px"">" & _
		"			<option value=1>每周召开一次</option>" & _
		"		</select>" & _
		"		<script language=""javascript"">document.all.frequence.selectedIndex=" & (iFrequence - 1)& "</script>" & _
		"	</td>" & _
		"<tr height = 1><td colspan=2>&nbsp;</td></tr>"&_
		"<tr height=30>" & _
		"	<td width=115 align=right>会议内容：</td>" & _
		"	<td width=485 colspan=4><textarea class=""FlatCtrl"" name=""mtTask"" rows=10 cols=62>"&sTask&"</textarea></td>"&_
		"</tr>" & _
		"<tr height=30>" & _
		"	<td width=115 align=right>召开部门：</td>" & _
		"	<td width=170><select name=department style=""WIDTH:170px"">" & OwnerDepartmentSelectOptions(iDepartment) & "</select></td>" & _
		"	<td width=80 align=right>召开地点：</td>" & _
		"	<td width=235><input name=""meeting_room"" value="""& sMeetingRoom &""" type=""text"" size=21 maxlength=25 >"& _
		"	</td>" & _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td width=115 align=right>主持人：</td>" & _
		"	<td width=170><input name=presider value=""" & sPresider & """ type=""text"" size=21 maxlength=10 >"& _
		"	<td width=80 align=right>召开日：</td>" & _
		"   <td width=235><select  name = ""meeting_day""style=""WIDTH:140px"">"&_
		"	  <option value = 1>星期一</option> "&_
		"	  <option value = 2>星期二</option> "&_
		"	  <option value = 3>星期三</option> "&_
		"	  <option value = 4>星期四</option> "&_
		"	  <option value = 5>星期五</option> "&_
		"	  <option value = 6>星期六</option> "&_
		"	  <option value = 7>星期日</option> "&_
		"	  </select>"&_
		"		<script language=""javascript"">document.all.meeting_day.selectedIndex=" & (iMeetingday-1)& "</script>" & _
		"	</td>" & _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td width=115 align=right>召开时间：</td>" & _
		"	<td width=170><input name=""start_time"" type=""text"" size=21 maxlength=19 value="""& dStart_time &""">" &"</td>"& _
		"	<td width=80 align=right>通知时间：</td>" & _
		"   <td width=235><select name = ""remindbeforedays"" style=""WIDTH:140px"">"&_
		"	  <option value = 1>提前一天</option> "&_
		"	  <option value = 2>提前二天</option> "&_
		"	  <option value = 3>提前三天</option> "&_
		"	  <option value = 4>提前四天</option> "&_
		"	  <option value = 5>提前五天</option> "&_
		"	  <option value = 6>提前六天</option> "&_
		"	  <option value = 7>提前七天</option> "&_
		"	  </select>"&_
		"		<script language=""javascript"">document.all.remindbeforedays.selectedIndex=" & (iRemindbeforedays-1)& "</script>" & _
		"	</td>" & _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td width=115 align=right>参会人员：</td>" & _
		"	<td width=170><select style=""width:140px"" multiple size=6 name=employee>" & GetRemainlist(sAttendee) & "</select>"& _
		"	<td width=80 align=left	><input type=button name=AddAtt value=""--->"" onclick=""JavaScript:MoveOptions(document.all.frmnewroutinemeeting.employee,document.all.frmnewroutinemeeting.attendee)""> <br>" & _
		"		<br><input type=button name=DelAtt value=""<---"" onclick=""JavaScript:MoveOptions(document.all.frmnewroutinemeeting.attendee,document.all.frmnewroutinemeeting.employee)""> </td>" & _
		"	<td width=235><select style=""width:140px""multiple size=6 name=attendee>"& GetAttendeelist(sAttendee) &"</select></td>"& _
		"</tr>" & _
		"<tr height=50>" & _
		"	<td colspan=4 align=center>" & sTempButtons & _
		"	</td>" & _
		"</tr>" & _
		"<tr height=30>" & _
		"   <input type=hidden name=rt>" & _
		"   <input type=hidden name=rm>" & _
		"   <input type=hidden name=formaction>" & _
		"   <input type=hidden name=meetingserial value="""&iMeetingSerial&""">" & _
		"</tr>" & _
		"</form>" & _
		"</table>" 
End Function

'************************************************************************************************
' 函数名　: TableLink()
' 输　入　: 
' 输　出　: 
' 功能描述: 	会议申请表页面上到其他页面的连接
' 调用模块: newroutinemeeting.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-11
' 版　本　: 
'************************************************************************************************
Function TableLink()
	TableLink = _
		"<table width=600 cellspacing=0 cellpadding=0 border=0 align=center>" & _
		"<tr height=30>" & _ 
		"	<td width=600><img src=""../images/bg/line.gif"" width=600 height=3></td>" & _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td width=600>&nbsp;" & _
		"		<img src=""../images/goto.gif"" width=11 height=11>&nbsp;<a href=""newroutinemeeting.asp"">新增例会</a>" & _
		"		&nbsp;&nbsp;&nbsp;" & _
		"		<img src=""../images/goto.gif"" width=11 height=11>&nbsp;<a href=""list_routinemeeting.asp"">例会列表</a>" & _
		"		&nbsp;&nbsp;&nbsp;" & _
		"		<img src=""../images/goto.gif"" width=11 height=11>&nbsp;<a href=""list_renewroutinemeeting.asp"">修改会议申请表</a></td>" & _
		"</tr>" & _
		"</table>"
End Function

'************************************************************************************************
' 函数名　: UpdateMeeting()
' 输　入　: 
' 输　出　: 
' 功能描述: 	新增或者更新会议的数据处理，根据meetingserial的值，采取不同的操作:
'			iMeetingserial=0：新的会议申请
'			iMeetingserial<>0 :重新会议申请
' 调用模块: newroutinemeeting.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-11
' 版　本　: 
'************************************************************************************************
Sub UpdateMeeting()
'	定义变量
	dim sSQL, crs, rs, sError, sMeeting_Name,  sTask, iDepartment, sMeeting_room, sPresider, dStart_time
	dim sAttendee, iCreator,  sFormaction
	dim iRemindbeforedays, iMeetingday, sRemind_time, sRemind_method, iFrequence
'   获取表单的数据 
	iCreator = GetEmpSerial
	sFormaction = GetParam("formaction")
	sMeeting_Name = GetParam("mtName")
	sTask   = GetParam("mtTask")
	iDepartment = GetParam("department")
	sMeeting_room = GetParam("meeting_room")
	iMeetingday = GetParam("meeting_day")
	sPresider = GetParam("presider")
	dStart_time = GetParam("start_time")
	sAttendee = GetParam("attendee")
	iRemindbeforedays = GetParam("remindbeforedays")
	sRemind_time = GetParam("rt")
	sRemind_method = GetParam("rm")
	iFrequence = GetParam("frequence")
'response.write "iMeetingSerial="&iMeetingSerial
'response.end
	select case sFormaction
	case "add"
		if iMeetingserial = 0 then
			'定义新增例会的sSQL语句
			sSQL = "insert into T_RoutineMeeting(meeting_name,node_id,frequence,meeting_day,meeting_time,meeting_room,presider,"&_
				"attendee,remindbeforedays,task,creator,remind_method,remind_time) values("&ToSQL(sMeeting_Name,"text")&_
				","&ToSQL(iDepartment,"Number")& "," & ToSQL(iFrequence,"number")&","&ToSQL(iMeetingday,"number")&","&_
				ToSQL(dStart_time,"text")& "," & ToSQL(sMeeting_room,"text") & "," & ToSQL(sPresider,"text") &_
				"," & ToSQL(sAttendee,"text") & "," & ToSQL(iRemindbeforedays,"number")& "," & ToSQL(sTask,"text") & _
				"," & ToSQL(iCreator,"Number") & "," & ToSQL(sRemind_method,"text")&","&ToSQL(sRemind_time,"text")&")"
			'执行新增例会
			sError = ExecuteSQL(dbLocal, sSQL)
			if sError <> "" then
				response.write "<script language=""javascript"">alert('对不起，添加例会失败！')</script>"
			else
				response.write "<script language=""javascript"">alert('例会添加成功！')</script>"
			end if
			response.write "<script language=vbscript>window.navigate(""newroutinemeeting.asp"")</script>"
		else
			sSQL = "select * from T_RoutineMeeting where meeting_serial = "& iMeetingSerial 
			set crs = New CRecordset
			set rs = crs.open(dbLocal,sSQL)
			if not rs.eof then 
				'定义更新例会的sSQL语句
				sSQL = "update T_RoutineMeeting set meeting_name = "& ToSQL(sMeeting_Name,"text") & ", task = " & ToSQL(sTask,"text") &_
				", node_id = " & ToSQL(iDepartment,"Number") & ", meeting_room = " & ToSQL(sMeeting_room,"text") & ", presider = "&_
				ToSQL(sPresider,"text") & ", meeting_time = " & ToSQL(dStart_time,"text") & ", attendee = " &_
				ToSQL(sAttendee,"text") & ", frequence = " & ToSQL(iFrequence,"Number") & ", meeting_day = " &_
				ToSQL(iMeetingday,"text") & ", remindbeforedays = " & ToSQL(iRemindbeforedays,"number") &_
				", remind_method = "&  ToSQL(sRemind_method,"text") & ", remind_time = " &ToSQL(sRemind_time,"text") &_
				"where meeting_serial=" & iMeetingSerial 
				'执行会议申请的更新
				sError = ExecuteSQL(dbLocal, sSQL)
				if sError <> "" then
					response.write "<script language=""javascript"">alert('对不起，例会修改失败！')</script>"
				else
					response.write "<script language=""javascript"">alert('例会修改成功！')</script>"
				end if
				response.write "<script language=vbscript>window.navigate(""list_routinemeeting.asp"")</script>"
			else
				response.write "<script language=""javascript"">alert('对不起，不存在该例会！')</script>"
				response.write "<script language = vbscript>window.navigate(""list_routinemeeting.asp"")</script>"
			end if
		end if
	case "del"
		sSQL = "delete from T_RoutineMeeting where meeting_serial = "&iMeetingSerial
		sError = ExecuteSQL(dbLocal, sSQL)
		if sError <> "" then
			response.write "<script language=""javascript"">alert('对不起，例会删除失败！')</script>"
		else
			response.write "<script language=""javascript"">alert('例会删除成功！')</script>"
		end if
		response.write "<script language=vbscript>window.navigate(""list_routinemeeting.asp"")</script>"
	end select
End Sub

%>