cardlist.asp

物业管理和办公自动化系统

<%
'#############################################################################################
'#
'#	文件名	 : cardlist.asp
'#	Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司
'#
'#	创建人	 : BinZha
'#  日　期	 : 2002-07-19
'#
'#	修改历史  : ****年**月**日 ****** 修改内容:**********************************************
'#
'#	功能描述	 : 低值易耗品卡片
'#  版  　本	 :
'#
'#############################################################################################

'----------------------------------------------------------
' 服务器端设置
'----------------------------------------------------------
option explicit
Response.CacheControl = "no-cache"
Response.AddHeader "Pragma", "no-cache"
Response.Expires = -1
%>

<!-- #include file="../include/config.inc" -->
<!-- #include file="../include/common.inc" -->
<!-- #include file="../include/debug.inc" -->
<!-- #include file="../include/db.inc" -->
<!-- #include file="../include/date.inc" -->
<!-- #include file="../include/datahandle.inc" -->
<!-- #include file="../include/recordlist.inc" -->
<!-- #include file="../include/security.inc" -->
<!-- #include file="../include/message.inc" -->
<!-- #include file="../common/commonpage.inc" -->
<!-- #include file="cardlist.inc" -->

<%
call CheckSecurity()
'********************************************************************************************************
' 服务器端代码
dim sSQL, sWhere, sOrderby
Dim sFileName			: sFileName			= "cardlist.asp"
Dim iCardID				: iCardID			= GetParam("id")
Dim iEmpSerial			: iEmpSerial		= GetEmpSerial
Dim sEmpName			: sEmpName			= GetUserName
Dim iTotalRecords		: iTotalRecords		= 0			' 分页
Dim iRecordsPerPage		: iRecordsPerPage	= 10
Dim iTotalPages			: iTotalPages		= 0
Dim iCols				: iCols				= 6
Dim iCurrentPage		: iCurrentPage		= GetParam("Page")
Dim iSort				: iSort				= GetParam("Sorting")
Dim iSorted				: iSorted			= GetParam("Sorted")
Dim sSortParams			: sSortParams		= ""
Dim sFormParams			: sFormParams		= ""
Dim sDirection			: sDirection		= ""
Dim sAction				: sAction			= GetParam("action")
Dim sFormAction			: sFormAction		= GetParam("FormAction")
Dim sPart				: sPart				= GetParam("part")
dim sHeader

'********************************************************************************************************
' 如果是提交，则调用函数AddCard()或UpdateCard()更新数据库
if UCase(Request.ServerVariables("REQUEST_METHOD") = "POST") then
	select case sFormAction
		case "addcard"
			call AddCard()
		case "updatecard"
			call UpdateCard()
		case "deletecard"
			call DeleteCard()
		case "passcard"
			call PassCard()
		case "backcard"
			call BackCard()
	end select
end if

'-----------------------------------------------------------------------------------------------------'
' 查询参数，组，是否公开，姓名关键字，单位名称关键字
'-----------------------------------------------------------------------------------------------------
dim pName				: pName				= GetParam("cardname")
dim pDepartment			: pDepartment		= GetParam("depart")
dim pUserName			: pUserName			= GetParam("user_name")
dim pApplyDate1			: pApplyDate1		= GetParam("apply_date1")
dim pApplyDate2			: pApplyDate2		= GetParam("apply_date2")

sFormParams = "cardname=" & pName & "&depart=" & pDepartment & "&user_name=" & pUserName & "&apply_date1=" & pApplyDate1 & "&apply_date2=" & pApplyDate2 & "&" 

'********************************************************************************************************
' 构造分页的SQL语句
'--------------------------------------------------------------------------------------------------------
sSQL = "select ID,Serial,Name,Department,UserName,ApplyDate,Status from T_Expendable" 
sWhere = " where signer = '" & sEmpName & "'" 
sHeader = "我的低值易耗品卡片列表"
if IsOfficer() then 
	select case sPart
		case "passed"
			sWhere = " where status = '已经发放'" 
			sHeader = "已经发放的低值易耗品卡片列表"
		case "forpass"
			sWhere = " where status = '等待审批'" 
			sHeader = "等待审批的低值易耗品卡片列表"
	end select
end if

sOrderby = " order by ID desc"

'********************************************************************************************************

'********************************************************************************************************
' 查询条件限制
'--------------------------------------------------------------------------------------------------------
if Not IsEmpty(pName) then sWhere = sWhere & " and Name like " & ToSQL("%" & pName & "%","Text")
if Not IsEmpty(pDepartment) then sWhere = sWhere & " and Department like " & ToSQL("%" & pDepartment & "%","Text")
if Not IsEmpty(pUserName) then sWhere = sWhere & " and UserName like " & ToSQL("%" & pUserName & "%","Text")
if Not IsEmpty(pApplyDate1) then sWhere = sWhere & " and ApplyDate >= " & ToSQL(pApplyDate1,"Text")
if Not IsEmpty(pApplyDate2) then sWhere = sWhere & " and ApplyDate <= " & ToSQL(pApplyDate2,"Text")

'********************************************************************************************************
' 分页SQL语句构造完毕，调用PrepareListData进行分页前的准备
'--------------------------------------------------------------------------------------------------------
dim arrayFields(5), sDelimiter
sDelimiter	=	"*"
arrayFields(0)	=	"Serial"
arrayFields(1)	=	"Name"
arrayFields(2)	=	"Department"
arrayFields(3)	=	"UserName"
arrayFields(4)	=	"ApplyDate"
arrayFields(5)	=	"Status"

call PrepareListData(sSQL & sWhere & sOrderby, Join(arrayFields, sDelimiter), sDelimiter)
%>

<html>
<head>
<title>上海信息大楼 Shanghai Information Tower</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link rel="stylesheet" href="../common/common.css" type="text/css">
<!-- 日历 begin -->
<IFRAME style="display:none;position:absolute;width:148;height:194;z-index=100" ID="CalFrame" MarginHeight=0 MarginWidth=0 noresize frameborder=0 scrolling=no src="../common/cal/calendar.htm"></IFRAME>
<script language="javascript" src="../common/cal/calendar.js"></script>
<script for=document event="onclick()">
<!--
document.all.CalFrame.style.display="none";
//-->
</script>
<!-- 日历 end -->

<script language="VBScript">
Sub btnSearch_OnClick()
	document.all.frmSearch.submit()
End Sub
</script>
</head>
<script language="javascript" src="cardlist.js"></script>
</head>

<body bgcolor="#FFFFFF" leftmargin="0" topmargin="0" marginwidth="0" marginheight="0" background="../images/bg/bg0.jpg">
<br>

<%
Response.Write OuterTableHeader
Response.Write HeaderWithMenu
Response.Write InnerTableHeader
'********************************************************************************************************
' 主体从这里开始
'-------------------------------------------------------------------------------------------------------------------------------------------------

'********************************************************************************************************
' 从这里开始显示通讯录详细信息
'-------------------------------------------------------------------------------------------------------------------------------------------------
if IsEmpty(sFormAction) and IsEmpty(sAction) then Response.Write TableSearch

Response.Write FormDetail()

Response.Write TableLink()
'-------------------------------------------------------------------------------------------------------------------------------------------------
' 主体到这里结束
'********************************************************************************************************
Response.Write InnerTableTailer
Response.Write Footer
Response.Write OuterTableTailer
%>

</body>
</html>