diaryquery.inc

物业管理和办公自动化系统

<%
'************************************************************************************************
' 函数名　: TableSearch()
' 输　入　: 
' 输　出　: 一个用于查询工作日志的表单
' 功能描述: 
' 调用模块: diaryquery.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-06-06
' 版　本　: 
'************************************************************************************************
Function TableSearch()
	'' 任务分类，0为所有任务，1为普通任务，2为会议相关的任务，3为审批相关的任务
	'' 任务完成状况，0全部，1所有已完成任务，2所有未完成任务，3所有正常的未完成任务，4所有过时的未完成任务
	'' 开始日期的日历，DrawCal函数定义在../common/commonpage.inc
	'' 结束日期的日历
	TableSearch = _
		TableTitle("设置查询条件", 600, "", "") & _
		"<table cellspacing=0 cellpadding=0 width=600 align=center border=0>" & _
		"<form name=""frmSearchNote"" method=post action=""diaryquery.asp"">"  & _
		"<tr height=20>" & _
		"	<td width=200>" & DrawCal("开始日期", pDay1, "day1", "dateimg1") & "	</td>" & _	
		"	<td width=200>" & DrawCal("结束日期", pDay2, "day2", "dateimg2") & "</td>" & _
		"	<td width=200><span id=btnSearch style=""cursor:hand"" title=""设置查询条件，然后点击查询按钮进行查询""><img border=0 src=""../images/search.gif"" style=""vertical-align:middle"">查询</span></td></tr>" & _
		"<tr height=10><td colspan=3 width=600>&nbsp;</td></tr>" & _
		"</form>" & _
		"</table>"
End Function

'************************************************************************************************
' 函数名　: TableHeader()
' 输　入　: 
' 输　出　: 一个用于显示个人工作日志的表头
' 功能描述: 根据fromaction参数的值，给出相应的表单
' 调用模块: diaryquery.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-06-06
' 版　本　: 
'************************************************************************************************
Function TableHeader()
	Response.Write TableTitle("您在" & pDay1 & "～" & pDay2 & "的工作日志", 600, "", "#0040a0")
	TableHeader = _
		"<table cellspacing=0 cellpadding=0 width=600 align=center class=tablelist style=""table-layout:fixed"">" & _
		"<tr>" & _
		"<td class=tdHead width=100>&nbsp;<img src=""../images/bg/ar-y.gif"" width=8 height=8>&nbsp;" & TableHeaderField(sFileName, "record_time", "日期", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead width=200>&nbsp;" & TableHeaderField(sFileName, "subject", "名称", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead width=230>&nbsp;" & TableHeaderField(sFileName, "content", "内容", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead width=70>&nbsp;" & TableHeaderField(sFileName, "emp_serial", "记录人", sFormParams, iSort, iSorted) & "</td>" & _
		"</tr>"
End Function

'************************************************************************************************
' 函数名　: TableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages,
'          sFileName, sFormParams, sSortParams)
' 输　入　: 查询语句，栏目数量，每页记录条数，总记录条数，当前页码，总页数，文件名，查询表单参数，排序参数
' 输　出　: 显示个人工作日志内容
' 功能描述: 根据输入参数，显示相应的结果
' 调用模块: diaryquery.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-06-06
' 版　本　: 
'************************************************************************************************
Function TableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams)
	dim sTemp	: sTemp = ""	' 临时字符串变量
	dim j					' 临时循环变量

	'------------------------------------
	' 分页所需的变量定义
	'------------------------------------
	Dim iCounter		: iCounter = 1
	Dim iPrevPage, iNextPage
	
	'------------------------------------
	' 获取数据库连接
	'------------------------------------
	dim crs	: set crs = New CRecordset
	dim rs	: set rs = crs.open(dbLocal,sSQL)
	dim sTime, sNotename, sNotecontent, sNoteperson, iSerial
	
	' 如果未到记录尾，将记录定位到你翻到的页面的第一个记录，否则显示空行
	if Not rs.EOF then	
		rs.Move (iCurrentPage - 1) * iRecordsPerPage
	end if
	while not rs.EOF and iCounter <= iRecordsPerPage
		sTime				= crs.GetValue("record_time")
		sNotename			= crs.GetValue("subject")
		sNotecontent		= crs.GetValue("content")
		sNoteperson			= crs.GetValue("emp_serial")
		iSerial				= crs.GetValue("serial")
		sTemp = sTemp & "<tr>" & _
				"<td class=tdlist   style=""cursor:hand""><a href=""diarydetail.asp?formaction=updtype&day1="&pday1&"&day2="&pday2&"&page="&iCurrentPage&"&serial=" & iserial & """><img border=0 src=""../images/bg/ar-g.gif"" width=8 height=8> &nbsp;" & sTime & "&nbsp;</td>" & _
				"<td class=tdlist  nowrap align=left title=""" & ToHtml(sNotename) & """>&nbsp;" & ToHTML(sNotename) & "&nbsp;</td>" & _
				"<td class=tdlist nowrap align=left  title=""" & Tohtml(sNotecontent) & """>" & ToHtml(sNotecontent) & "</a>&nbsp;</td>" & _
				"<td class=tdlist nowrap align=left title=""" & TransEmpSerial(dbLocal,sNoteperson) & """>&nbsp;" & TransEmpSerial(dbLocal,sNoteperson) & "&nbsp;</td>" & _
				"</tr>"
		iCounter = iCounter + 1
		rs.movenext
	wend
	crs.Close()

	' 填补空白行
	sTemp = sTemp & WhiteRows(iCols, iCounter, iRecordsPerPage)

	' 首页、前页、后页、尾页等分页信息
	sTemp = sTemp & "<tr><td class=tdlist colspan=" & iCols & " align=right>" & _
				Paginate(sFileName, sFormParams, sSortParams, iCurrentPage, iTotalPages) & _
				"&nbsp;</td></tr>"
	TableRecords = sTemp
End Function


'************************************************************************************************
' 函数名　: TableLink()
' 输　入　: 
' 输　出　: 页面下方提供的链接
' 功能描述: 
' 调用模块: diaryquery.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-06-06
' 版　本　: 
'************************************************************************************************
Function TableLink()
	TableLink = _
		"<table width=600 cellspacing=0 cellpadding=0 border=0 align=center>" & _
		"<tr height=10>" & _ 
		"	<td width=600><img src=""../images/bg/line.gif"" width=600 height=3></td>" & _
		"</tr>" & _
		"<tr height=20>" & _
		"	<td width=600>&nbsp;" & _
		"		<img src=""../images/goto.gif"" width=11 height=11>&nbsp;<a href=""diarydetail.asp"">登记工作日志</a>" & _
		"		&nbsp;&nbsp;&nbsp;" & _
		"</tr>" & _
		"</table>"
End Function
%>