⭐ 欢迎来到虫虫下载站！ | 📦 资源下载 📁 资源专辑 ℹ️ 关于我们
⭐ 虫虫下载站
📤 上传资源

📄 plancompany.inc

📁 物业管理和办公自动化系统
💻 INC
📖 第 1 页 / 共 2 页
字号:
🔍
12 
'************************************************************************************************
' 函数名　: SeasonTableHeader()
' 输　入　: 
' 输　出　: 季度工作计划表的表头显示
' 功能描述: 
' 调用模块: plancompany.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-06-18
' 版　本　: 
'************************************************************************************************
Function SeasonTableHeader()
'-----------------------------------------------------------------------------
'季度工作计划表的表头
'------------------------------------------------------------------------------
	Response.Write TableTitle(iOf_year & "年第" & iOf_season & "季度" &"的季度工作计划表", 600, "", "#0040a0")
	SeasonTableHeader = _
		"<table cellspacing=0 cellpadding=0 width=600 align=center class=tablelist style=""table-layout:fixed"">" & _
		"<tr>" & _
		"<td class=tdHead width=50 align =center>"
	if GetEmpSerial = GetOfficer then
		SeasonTableHeader = SeasonTableHeader & "<img src=""../images/bg/ar-y.gif"" width=8 height=8>&nbsp;"
	end if
	SeasonTableHeader = SeasonTableHeader & "序号</td>" & _
		"<td class=tdHead width=180>&nbsp;" & TableHeaderField(sFileName, "content", "本季度计划完成的主要工作", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead width=160>&nbsp;" & TableHeaderField(sFileName, "target", "实施目标和措施", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead width=80	>&nbsp;" & TableHeaderField(sFileName, "progress", "完成进度", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead width=70 valign=middle >&nbsp;" & TableHeaderField(sFileName, "handler", "责任人", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead width=60>&nbsp;" & TableHeaderField(sFileName, "memo", "备注", sFormParams, iSort, iSorted) & "</td>" & _
		"</tr>"		
End Function

'************************************************************************************************
' 函数名　: TableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, 
'			sFileName, sFormParams, sSortParams)
' 输　入　: 查询语句，栏目数量，每页记录条数，总记录条数，当前页码，总页数，文件名，查询表单参数，排序参数
' 输　出　: 一张工作计划表的内容部分
' 功能描述: 
' 调用模块: plancompany.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-06-18
' 版　本　: 
'************************************************************************************************
Function TableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams)
	dim sTemp	: sTemp = ""	' 临时字符串变量
	dim j					' 临时循环变量

	'------------------------------------
	' 分页所需的变量定义
	'------------------------------------
	Dim iCounter		: iCounter = 1
	Dim iPrevPage, iNextPage
	
	'------------------------------------
	' 获取数据库连接
	'------------------------------------
	dim crs	: set crs = New CRecordset
	dim rs	: set rs = crs.open(dbLocal,sSQL)
	dim sContent, sTarget, sProgress, sHandler, sMemo, iSerial, iPlanSerial
	dim iTemp : iTemp = 0
	
	' 如果未到记录尾，将记录定位到你翻到的页面的第一个记录，否则显示空行
	if Not rs.EOF then
'		response.write iCurrentPage & "*" & iRecordsPerPage & "<br>" : response.end
		rs.Move (iCurrentPage - 1) * iRecordsPerPage
		iTemp = (iCurrentPage - 1) * iRecordsPerPage
	end if
	while not rs.EOF and iCounter <= iRecordsPerPage
		sContent			= crs.GetValue("content")
		sTarget 			= crs.GetValue("target")
		sProgress   		= crs.GetValue("progress")
		sHandler			= crs.GetValue("handler")
		sMemo				= crs.GetValue("memo")
		iSerial				= crs.GetValue("serial")
		iPlanSerial			= crs.GetValue("plan_serial")
		iTemp = iTemp + 1
	'根据当前用户的身份显示相应的内容，办公室主任在序号上有连接，以便于修改，而其它用户没有连接
	if GetEmpSerial = GetOfficer then
		sTemp = sTemp & "<tr>" & _
				"<td class=tdlist width=40 align=center style=""cursor:hand""><a href=plancompany.asp?formaction=updtype&serial=" & iserial & "&plan_serial=" & iPlanSerial & "&page=" & iCurrentPage &  "><img border=0 src=""../images/bg/ar-g.gif"" width=8 height=8>&nbsp;" & iTemp & "</td>" 
	else
		sTemp = sTemp & "<tr>" & _
				"<td class=tdlist align=center>" & iTemp & "</td>" 
	end if
		sTemp = sTemp & _
				"<td class=tdlist nowrap title="""& Tohtml(sContent) & """ >&nbsp;" & ToHTML(sContent) & "&nbsp;</td>" & _
				"<td class=tdlist nowrap title="""& Tohtml(sTarget) & """ >&nbsp;" & ToHTML(sTarget) & "&nbsp;</td>" & _
				"<td class=tdlist nowrap title="""& Tohtml(sProgress) & """ >&nbsp;" & ToHTML(sProgress) & "</td>" & _
				"<td class=tdlist nowrap title="""& Tohtml(sHandler) & """ >&nbsp;" & ToHTML(sHandler)& "&nbsp;</td>" & _
				"<td class=tdlist nowrap title="""& Tohtml(sMemo) & """ >&nbsp;" & ToHTML(sMemo) & "&nbsp;</td>" & _	
				"</tr>"
		iCounter = iCounter + 1			
		rs.movenext
	wend
	crs.Close()

	' 填补空白行
	sTemp = sTemp & WhiteRows(iCols, iCounter, iRecordsPerPage)

	' 首页、前页、后页、尾页等分页信息
	sTemp = sTemp & "<tr><td class=tdlist colspan=" & iCols & " align=right>" & _
				Paginate(sFileName, sFormParams, sSortParams, iCurrentPage, iTotalPages) & _
				"&nbsp;</td></tr>"
	TableRecords = sTemp&"</table>"
End Function

'************************************************************************************************
' 函数名　: UpdatePlan()
' 输　入　: 
' 输　出　: 更新计划表的内容
' 功能描述: 用于新添、更新、删除、发布工作计划表
' 调用模块: plancompany.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-06-18
' 版　本　: 
'************************************************************************************************
Sub UpdatePlan()
	dim sSQL, iSerial, iType, iOf_year, iOf_month, iOf_season, sAction, sError
	dim sContent, sTarget, sProgress, sHandler, sMemo, iEmpserial, iPage
	iPage = GetParam("page")
	iType = GetParam("type")
	iOf_year = GetParam("of_year")
	iOf_month = GetParam("of_month")
	iOf_season = GetParam("of_season")
	sAction = GetParam("formAction")
	iSerial = GetParam("serial")
	sTarget = GetParam("target")
	sContent = GetParam("content")
	sProgress = GetParam("progress")
	sHandler = GetParam("handler")
	sMemo = GetParam("memo")
	iEmpSerial = GetEmpSerial

	sAction = LCase(sAction)
	select case sAction
	case "addtype"
		'---------------------------------------------------------------------------------
		'新添工作计划
		'---------------------------------------------------------------------------------
		'先判断该类型的工作计划表在T_Plan中是否已经存在，
		'如果存在，则取出serial值，然后在T_Plan_Detail中添加计划内容，plan_serial = serial
		'如果不存在，则先在T_Plan中添加一条新纪录，然后取该记录的serial,在T_Plan_Detail中添加计划内容，plan_serial = serial
		'----------------------------------------------------------------------------------------------------------
		'********************************************************************************************************
		' 根据查询的计划类型不同，构造分页的SQL语句
		'********************************************************************************************************
		select case iType 
		case 1'月度公司计划查询
			iSerial = DLookUp(dbLocal, "T_Plan", "serial", "type = " & ToSQL(iType,"Number") &  "and of_year = " & ToSQL(iOf_year, "Number") & "and of_month = " & ToSQL(iOf_month, "Number") & "and scope = 3" )
		case 2'季度公司计划查询
			iSerial = DLookUp(dbLocal, "T_Plan", "serial", "type = " & ToSQL(iType,"Number") &  "and of_year = " & ToSQL(iOf_year, "Number") & "and of_season = " & ToSQL(iOf_season, "Number") &  "and scope = 3" )
		case 3'年度公司计划查询
			iSerial = DLookUp(dbLocal, "T_Plan", "serial", "type = " & ToSQL(iType,"Number") &  "and of_year = " & ToSQL(iOf_year, "Number") &  "and scope = 3" )
		end select

		if iSerial = "" then'如果在T_Plan中没有找到相应的工作计划表，则先加T_Plan,后加T_Plan_Detail
			select case iType
			case 1'添加月度工作计划表
				sSQL = "insert into T_Plan(type, of_year, of_month, person, scope, release) " & _
				" values(" & ToSQL(iType,"Number") & ", " & ToSQL(iOf_year,"Number") & "," & ToSQL(iOf_month,"Number") & "," & ToSQL(iEmpSerial,"Number") & ", 3, 0 "  &")"
			case 2'添加季度工作计划表
				sSQL = "insert into T_Plan(type, of_year, of_season, person, scope, release) " & _
				" values(" & ToSQL(iType,"Number") & ", " & ToSQL(iOf_year,"Number") & "," & ToSQL(iOf_season,"Number") & "," & ToSQL(iEmpSerial,"Number") & ", 3, 0 " &")"
			case 3'添加年度工作计划表
				sSQL = "insert into T_Plan(type, of_year, person, scope, release) " & _
				" values(" & ToSQL(iType,"Number") & ", " & ToSQL(iOf_year,"Number") & ","  & ToSQL(iEmpSerial,"Number") & ",3,0 " &")"
			end select
			sError  = ExecuteSQL(dbLocal, sSQL)
			if sError <> "" then
				Response.Write "<script language=""javascript"">alert('对不起，新增计划表失败！')</script>"
			else'如果T_Plan添加成功，再添加T_Plan_Detail
				dim crs, rs
				sSQL = "select max(serial) as m_serial from T_Plan "
				set crs = New CRecordset
				set rs = crs.open(dbLocal,sSQL)
				iSerial = crs.GetValue("m_serial")
				crs.Close()
				sSQL = "insert into T_Plan_Detail(plan_serial, content, target, progress, handler, memo)" & _
				"values("& ToSQL(iSerial,"Number") & "," & ToSQL(sContent,"Text") & "," & _
				ToSQL(sTarget,"Text") & "," & ToSQL(sProgress,"Text") & "," & ToSQL(sHandler,"Text") & _
				"," & ToSQL(sMemo,"Text") & ")"  
				sError  = ExecuteSQL(dbLocal, sSQL)
				if sError <> "" then
					Response.Write "<script language=""javascript"">alert('对不起，新增工作计划失败！')</script>"
				end if
			end if

		else'如果在T_Plan中已经存在相应的工作计划表，则直接在T_Plan_Detail中添加计划内容
			sSQL = "insert into T_Plan_Detail(plan_serial, content, target, progress, handler, memo)" & _
			"values("& ToSQL(iSerial,"Number") & "," & ToSQL(sContent,"Text") & "," & _
			ToSQL(sTarget,"Text") & "," & ToSQL(sProgress,"Text") & "," & ToSQL(sHandler,"Text") & _
			"," & ToSQL(sMemo,"Text") & ")"  
			sError  = ExecuteSQL(dbLocal, sSQL)
			if sError <> "" then
				Response.Write "<script language=""javascript"">alert('对不起，新增工作计划失败！')</script>"
			end if
		end if
	case "updtype"
	'-----------------------------------------------------------------------------------------------------
	'更新工作计划
	'------------------------------------------------------------------------------------------------------
		sSQL = "update T_Plan_Detail" & _
		" set content = " & ToSQL(sContent, "Text") & ", target = " & ToSQL(sTarget,"Text") & _
		" , progress = " & ToSQL(sProgress,"Text") & ", handler = "& ToSQL(sHandler,"Text") & _
		", memo = "&ToSQL(sMemo,"Text") & " where serial = " & ToSQL(iSerial,"Number")
		sError  = ExecuteSQL(dbLocal, sSQL)
		if sError <> "" then
			Response.Write "<script language=""javascript"">alert('对不起，更新工作计划失败！')</script>"
		end if
	case "deltype"
	'-----------------------------------------------------------------------------------------------------
	'删除工作计划
	'------------------------------------------------------------------------------------------------------
		sSQL = "delete from T_Plan_Detail where serial = " & ToSQL(iSerial,"Number")
		sError  = ExecuteSQL(dbLocal, sSQL)
		if sError <> "" then
			Response.Write "<script language=""javascript"">alert('对不起，删除工作计划失败！')</script>"
		end if
	case "reltype"
	'------------------------------------------------------------------------------------------
	'发布工作计划表
	'------------------------------------------------------------------------------------------
		'---------------------------------------------------------------------------------
		'先判断该类型的工作计划表在T_Plan中是否已经存在，
		'如果存在，则取出serial值，然后更新T_Plan中该记录的release值，改为1。
		'如果不存在，则要求先填写工作计划表，然后发表
		'----------------------------------------------------------------------------------------------------------
		'********************************************************************************************************
		' 根据查询的计划类型不同，构造分页的SQL语句
		'********************************************************************************************************
		select case iType 
		case 1'月度公司计划查询
			iSerial = DLookUp(dbLocal, "T_Plan", "serial", "type = " & ToSQL(iType,"Number") &  "and of_year = " & ToSQL(iOf_year, "Number") & "and of_month = " & ToSQL(iOf_month, "Number") & "and scope = 3" )
		case 2'季度公司计划查询
			iSerial = DLookUp(dbLocal, "T_Plan", "serial", "type = " & ToSQL(iType,"Number") &  "and of_year = " & ToSQL(iOf_year, "Number") & "and of_season = " & ToSQL(iOf_season, "Number") &  "and scope = 3" )
		case 3'年度公司计划查询
			iSerial = DLookUp(dbLocal, "T_Plan", "serial", "type = " & ToSQL(iType,"Number") &  "and of_year = " & ToSQL(iOf_year, "Number") & "and scope = 3" )
		end select
		if iSerial = "" then 
			Response.Write "<script language=""javascript"">alert('对不起，请先填写工作计划内容，然后再发布！')</script>"
		else 
			sSQL = "update T_Plan set release = 1 where serial = " & ToSQL(iSerial,"Number")
			sError  = ExecuteSQL(dbLocal, sSQL)
			if sError <> "" then
				Response.Write "<script language=""javascript"">alert('对不起，发布工作计划失败！')</script>"
			end if
		end if
	case "cancel"
	'-----------------------------------------------------------------------
	'取消操作
	'--------------------------------------------------------------------------
		response.write "<script language=vbscript>window.navigate(""plancompany.asp?type="&_
		iType&"&of_year="&iOf_year&"&of_month="&iOf_month&"&of_season="&iOf_season&"&page="&iPage&"&"")</script>"
	end select
End Sub

'************************************************************************************************
' 函数名　: TableLink()
' 输　入　: 
' 输　出　: 显示提供相应的链接的表
' 功能描述: 
' 调用模块: plancompany.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-06-18
' 版　本　: 
'************************************************************************************************
Function TableLink()
	TableLink = _
		"<table width=600 cellspacing=0 cellpadding=0 border=0 align=center>" & _
		"<tr height=10>" & _ 
		"	<td width=600><img src=""../images/bg/line.gif"" width=600 height=3></td>" & _
		"</tr>" & _
		"<tr height=20>" & _
		"	<td width=600>&nbsp;" & _
		"		<img src=""../images/goto.gif"" width=11 height=11>&nbsp;<a href=""plancompany.asp?"&sFormParams&"page="&iCurrentPage&""">公司工作计划登记</a>" & _
		"		&nbsp;&nbsp;&nbsp;" & _
		"</tr>" & _
		"</table>"
End Function
%>
12

⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -