taskdetail.inc

物业管理和办公自动化系统

<%
Function TaskInfo()
	dim sSQL, crs, rs
	dim sSubject, sContent, sDoFrom, sDoEnd, sExecutor, sUrgency, sCreateDate
	dim sRemindMethod, sRemindTime

	sSQL = "select t1.subject, t1.content, t1.dofrom, t1.doend, t1.executor, t2.urgency_desc, t1.create_date, t1.remind_method, t1.remind_time" & _
			" from t_task t1, t_urgency t2" & _
			" where t1.urgency = t2.urgency_id" & _
			" and task_serial = " & ToSQL(iTaskSerial, "Number")

	'' response.write sSQL : response.end
	set crs = New CRecordset
	set rs = crs.Open(dbLocal, sSQL)


	'' 居然找不到通讯录信息的记录，那肯定是个莫名的错误
	if rs.EOF then
		Response.Clear
		Server.Transfer("../common/error.asp")
		Response.end
	end if

	'' 获取任务信息的各种数据
	sSubject	= crs.GetValue("subject")
	sContent	= crs.GetValue("content")
	sDoFrom	= crs.GetValue("dofrom")
	sDoEnd		= crs.GetValue("doend")
	sExecutor	= crs.GetValue("executor")
	sUrgency	= crs.GetValue("urgency_desc")
	sCreateDate		= crs.GetValue("create_date")
	sRemindMethod	= crs.GetValue("remind_method")
	sRemindTime		= crs. GetValue("remind_time")
	crs.Close()

	'' 数据显示前的处理
	sDoFrom = FormatDT(sDoFrom, "yyyy-mm-dd hh:mm")
	sDoEnd = FormatDT(sDoEnd, "yyyy-mm-dd hh:mm")
	sCreateDate = FormatDT(sCreateDate, "yyyy-mm-dd hh:mm")
	sExecutor = TransEmpSerial(dbLocal, sExecutor)

	if sRemindMethod = "" then
			sRemindMethod = "从不提醒"
			sRemindTime = ""
	else
			sRemindMethod = TransRemindMethod(sRemindMethod)
			if sRemindTime <> "" then sRemindTime = FormatDT(sRemindTime, "yyyy-mm-dd hh:mm")
	end if

	'' TableTitle函数定义在../common/commonpage.inc
	TaskInfo = _
		"<table cellspacing=1 cellpadding=3 width=600 height=390 border=0 align=center bgcolor=silver style=""table-layout:fixed"">" & vbLF & _
		"<tr style=""display:none"">" & vbLF & _
		"		<td width=80 nowrap>这一行进用于控制表格宽度</td>" & vbLF & _
		"		<td width=200>&nbsp;</td>" & vbLF & _
		"		<td width=80 nowrap>这一行进用于控制表格宽度</td>" & vbLF & _
		"		<td width=200>&nbsp;</td></tr>" & vbLF & _
		"<tr height=20 style=""color:white;font-weight:600"">" & vbLF & _
		"		<td background=""../images/bg/bnbg.gif"" align=center colspan=4>任 务 详 细 信 息</td></tr>" & vbLF & _
		"<tr bgcolor=white height=30>" & vbLF & _
		"		<td align=center>任务名称</td>" & vbLF & _
		"		<td colspan=3 class=tdvalue>" & sSubject & "</td></tr>" & vbLF & _
		"<tr bgcolor=white>" & vbLF & _
		"		<td align=center>具体内容</td>" & vbLF & _
		"		<td colspan=3 class=tdvalue style=""word-wrap:break-word;width:510"" valign=top>" & vbLF & _
				"<pre>" & sContent & "</pre>" & vbLF & _
				"<span onclick=""javascript:window.open('task_e.asp?serial=" & iTaskSerial & "','','width=518,height=360,left=100,top=100')"" style=""color:blue;cursor:hand"">&gt;&gt;&nbsp;点击这里修改任务具体内容</span>" & vbLF & _
				"</td></tr>" & vbLF & _
		"<tr bgcolor=white height=30>" & vbLF & _
		"		<td align=center>开始时间</td><td class=tdvalue>" & sDoFrom & "</td>" & vbLF & _
		"		<td align=center>完成期限</td><td class=tdvalue>" & sDoEnd & "</td></tr>" & vbLF & _
		"<tr bgcolor=white height=30>" & vbLF & _
		"		<td align=center>紧急程度</td><td class=tdvalue>" & sUrgency & "</td>" & vbLF & _
		"		<td align=center>创建时间</td><td class=tdvalue>" & sCreateDate & "</td></tr>" & vbLF & _
		"<tr bgcolor=white height=30>" & vbLF & _
		"		<td align=center>相关人员</td>" & vbLF & _
		"		<td colspan=3 class=tdvalue>" & sExecutor & "</td></tr>" & vbLF & _
		"<tr bgcolor=white height=30>" & vbLF & _
		"		<td align=center>提醒方式</td>" & vbLF & _
		"		<td colspan=3 class=tdvalue>" & sRemindMethod & "</td>" & vbLF & _
		"<tr bgcolor=white>" & vbLF & _
		"		<td align=center>完成情况</td>" & vbLF & _
		"		<td colspan=3>" & TaskExeInfo & _
				"&nbsp;<a href=""taskhistory.asp?serial=" & iTaskSerial & """ style=""color:blue"">&gt;&gt;&nbsp;点击这里察看任务执行过程</a>" & _
				"</td></tr>" & vbLF & _
		"<tr bgcolor=white height=30>" & vbLF & _
		"	<td colspan=4 align=center><span style=""color:blue;cursor:hand"" onclick=""DeleteTask(" & iTaskSerial & ");""><img border=0 src=""../images/delete.gif"" align=absmiddle>&nbsp;删除本项任务</span>" & vbLF & _
				"</td></tr>" & vbLF & _
		"</table>" & vbLF

End Function

Function TaskExeInfo()
	dim sSQL, crs, rs 
	dim iPTSerial, sEmpName, sProgressPercent, sFinishTime, sMemo
	dim sTemp	 : sTemp = ""

	sSQL = "select t1.serial, t2.name, isnull(t1.progress_percent,0) as progress_percent, t1.finish_time, t1.memo" & _
				" from t_personaltask t1" & _
				" left join t_employee t2 on t2.serial = t1.emp_serial" & _
				" where task_serial = " & iTaskSerial

	set crs = New CRecordset
	set rs = crs.Open(dbLocal, sSQL)

	while not rs.EOF
			iPTSerial = crs.GetValue("serial")
			sEmpName = crs.GetValue("name")
			sProgressPercent = crs.GetValue("progress_percent")
			sFinishTime = crs.GetValue("finish_time")
			sMemo = crs.GetValue("memo")

			if sFinishTime <> "" then
					sFinishTime = FormatDT(sFinishTime, "yyyy-mm-dd hh:mm")
					sFinishTime = "最后一次更新时间 " & sFinishTime
			end if
			sTemp = sTemp & _
					"<tr bgcolor=white height=20>" & vbLF & _
					"		<td nowrap><img border=0 src=""../images/executor.gif"">" & sEmpName & "</a></td>" & vbLF & _
					"		<td nowrap class=tdvalue>完成 " & sProgressPercent & "%</td>" & vbLF & _
					"		<td nowrap class=tdvalue>" & sFinishTime & "&nbsp;</td>" & vbLF & _
					"</tr>" & vbLF & _
					"<tr bgcolor=white>" & vbLF & _
					"		<td class=tdvalue>&nbsp;</td>" & vbLF & _
					"		<td class=tdvalue colspan=2 style=""color:gray""><pre>" & ToHTML(sMemo) & "</pre></td>" & vbLF & _
					"</tr>"
			rs.movenext
	wend
	crs.Close()

	TaskExeInfo = sTemp
	if sTemp <> "" then
		TaskExeInfo = _
			"<table cellspacing=1 cellpadding=3 width=520 border=0 align=center bgcolor=white style=""table-layout:fixed"">" & vbLF & _
			"<tr style=""display:none""><td width=68></td><td width=80></td><td width=""*""></td></tr>" & vbLF & _
				sTemp & _
			"</table>" & vbLF
	end if
End Function

Function TableLink()
	TableLink = _
		"<table width=600 cellspacing=0 cellpadding=0 border=0 align=center>" & vbLF & _
		"<tr height=10>" & vbLF & _ 
		"	<td width=600><img src=""../images/bg/line.gif"" width=600 height=3></td>" & vbLF & _
		"</tr>" & vbLF & _
		"<tr height=20>" & _
		"	<td width=600>&nbsp;" & vbLF & _
		"		<img src=""../images/goto.gif"">&nbsp;<a href=""task_a.asp"">安排新任务</a>" & _
		"		&nbsp;&nbsp;&nbsp;" & vbLF & _
		"		<img src=""../images/goto.gif"">&nbsp;<a href=""tasktodo.asp"">待办事宜</a></td>" & vbLF & _
		"</tr>" & _
		"</table>"
End Function
%>