taskinfor.inc

物业管理和办公自动化系统

<!-- #include file="../include/emp.inc" -->
<%
Function TaskInfor(task_serial)
	dim iPTaskSerial
	dim sSQL, crs, rs
	dim sSubject, sContent, sCreateTime, sCreator, sDoFrom, sDoEnd, sExecutor, sUrgency

	'' 找到相应的TaskSerial，因为T_PersonalTask.Task_Serial不能为null，因此总能取到这个值
	sSQL = "select * from T_Task where task_serial = " & task_serial
	set crs = New CRecordset
	set rs = crs.Open(dbLocal, sSQL)

	'' 居然找不到任务基本信息的记录，那肯定是个莫名的错误
	if rs.EOF then
		Response.Redirect("../common/error.asp")
		Response.end
	end if

	'' 获取任务信息的各种数据
	sSubject		= crs.GetValue("subject")
	sContent		= crs.GetValue("content")
	sCreateTime	= crs.GetValue("create_date")
	sCreator		= crs.GetValue("creator")
	sDoFrom		= crs.GetValue("dofrom")
	sDoEnd		= crs.GetValue("doend")
	sExecutor		= crs.GetValue("executor")
	sUrgency		= crs.GetValue("urgency")
	crs.Close()

	sUrgency		= DLookUp(dbLocal, "T_Urgency", "urgency_desc", "urgency_id=" & sUrgency)
	sCreateTime	= FormatDT(sCreateTime, "yyyy-mm-dd hh:mm")

	'' TableTitle函数定义在../common/commonpage.inc
	TaskInfor = _
		TableTitle("任 务 详 细 信 息", 600, "", "") & vbLF & _
		"<table id=taskinfor style=""display:block"" cellspacing=0 cellpadding=0 width=600 border=0 align=center>" & vbLF & _
		"<tr height=5><td width=600 colspan=3></td></tr>" & vbLF & _
		"<tr height=25><td width=600 colspan=3>【任务名称】" & sSubject & "</td></tr>" & vbLF & _
		"<tr height=25><td width=150>【紧急程度】" & sUrgency & "</td>" & vbLF & _
		"	<td width=150>【任务创建者】" & TransEmpSerial(dbLocal, sCreator) & "</td>" & vbLF & _
		"	<td width=300>【任务创建时间】" & sCreateTime & "</td></tr>" & vbLF & _
		"<tr height=25>" & vbLF & _
		"	<td width=550 colspan=3 title=""" & TransEmpSerial(dbLocal, sExecutor) & """>【任务相关人员】" & TransEmpSerial(dbLocal, sExecutor) & "</td></tr>" & vbLF & _
		"<tr height=25><td width=600 colspan=3 style=""word-wrap:break-word;""><pre>【任务内容】" & sContent & "</pre></td></tr>" & vbLF & _
		"</table>" & vbLF
End Function
%>