taskhistory.inc

物业管理和办公自动化系统

<%
Function TaskHistoryTableHeader()
	dim sTaskSubject
	TaskHistoryTableHeader = _
		"<table width=600 cellspacing=0 cellpadding=1 border=0 background=""../images/bg/bnbg.gif"">" & _
		"<tr><td align=center style=""color:#FFFFFF;background-color:#0040a0;font-weight:600"">任务执行历史过程全跟踪</td></tr>" & _
		"</table>" & _
		"<table width=600 cellspacing=0 cellpadding=1 border=0 class=tablelist style=""table-layout:fixed"">" & _
		"<tr>" & _
		"	<td class=tdHead width=60>&nbsp;" & TableHeaderField(sFileName, "name", "人员", sFormParams, iSort, iSorted) & "</td>" & _
		"	<td class=tdHead width=110>&nbsp;" & TableHeaderField(sFileName, "record_time", "更新时间", sFormParams, iSort, iSorted) & "</td>" & _
		"	<td class=tdHead width=60>&nbsp;" & TableHeaderField(sFileName, "progress_percent", "进度", sFormParams, iSort, iSorted) & "</td>" & _
		"	<td class=tdHead width=""*"">&nbsp;" & TableHeaderField(sFileName, "memo", "备注说明", sFormParams, iSort, iSorted) & "</td>" & _
		"</tr>"
End Function

Function TaskHistoryTableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams)
	dim sTemp	: sTemp = ""	' 临时字符串变量
	dim j					' 临时循环变量

	'------------------------------------
	' 分页所需的变量定义
	'------------------------------------
	Dim iCounter		: iCounter = 1
	Dim iPrevPage, iNextPage
	
	'------------------------------------
	' 获取数据库连接
	'------------------------------------
	dim crs	: set crs = New CRecordset
	dim rs	: set rs = crs.open(dbLocal,sSQL)
	dim sRecordTime, iProgressPercent, sMemo, sEmpName
	
	' 如果未到记录尾，将记录定位到你翻到的页面的第一个记录，否则显示空行
	if Not rs.EOF then
		rs.Move (iCurrentPage - 1) * iRecordsPerPage
	end if

	'' ****************************************************************************************************
	'' 提取数据并显示开始
	'' ToHTML, Bref 函数定义在../include/datahandle.inc
	while not rs.EOF and iCounter <= iRecordsPerPage
		sEmpName = crs.GetValue("name")
		iProgressPercent	= crs.GetValue("Progress_Percent")
		sMemo					= crs.GetValue("memo")
		sRecordTime			= crs.GetValue("record_time")
		sRecordTime			= FormatDT(sRecordTime, "yyyy-mm-dd hh:mm")

		sTemp = sTemp & "<tr>" & _
			"<td class=tdlist align=center nowrap>&nbsp;" & sEmpName & "&nbsp;</td>" & _
			"<td class=tdlist align=left nowrap>&nbsp;" & sRecordTime & "&nbsp;</td>" & _
			"<td class=tdlist align=right nowrap>&nbsp;" & iProgressPercent & "%&nbsp;&nbsp;&nbsp;</td>" & _
			"<td class=tdlist title='" & sMemo & "' nowrap>&nbsp;<img src=""../images/bg/ar-g.gif"" width=8 height=8>&nbsp;" & ToHtml(Trim(sMemo)) & "&nbsp;</td>" & _
			"</tr>"
		iCounter = iCounter + 1
		rs.movenext
	wend
	'' 提取数据并显示结束
	'' ****************************************************************************************************
	crs.Close()

	' 这里填补空白行, '' WhiteRows函数定义在../include/recordlist.inc
	sTemp = sTemp & WhiteRows(iCols, iCounter, iRecordsPerPage)

	' 首页、前页、后页、尾页等分页信息
	sTemp = sTemp & "<tr><td class=tdlist colspan=" & iCols & " align=right>" & _
				Paginate(sFileName, sFormParams, sSortParams, iCurrentPage, iTotalPages) & _
				"&nbsp;</td></tr>"
	TaskHistoryTableRecords = sTemp
End Function

Function TaskHistoryTableTailer(iCols)
	TaskHistoryTableTailer = _
		"		</table>"
End Function

Function TableLink()
	TableLink = _
		"<table width=600 cellspacing=0 cellpadding=0 border=0 align=center>" & _
		"<tr height=10>" & _ 
		"	<td width=600><img src=""../images/bg/line.gif"" width=600 height=3></td>" & _
		"</tr>" & _
		"<tr height=20>" & _
		"	<td width=600>&nbsp;" & _
		"		<img src=""../images/goto.gif"">&nbsp;<a href=""taskdetail.asp?serial=" & pTaskSerial & """>任务信息</a>" & _
		"		&nbsp;&nbsp;&nbsp;" & _
		"		<img src=""../images/goto.gif"">&nbsp;<a href=""tasktodo.asp"">待办事宜</a></td>" & _
		"</tr>" & _
		"</table>"
End Function
%>