tasktodo.inc

物业管理和办公自动化系统

<%
Function TableSearch()
	'' 任务分类，0为所有任务，1为普通任务，2为会议相关的任务，3为审批相关的任务
	'' 任务完成状况，0全部，1所有已完成任务，2所有未完成任务，3所有正常的未完成任务，4所有过时的未完成任务
	'' 开始日期的日历，DrawCal函数定义在../common/commonpage.inc
	'' 结束日期的日历
	TableSearch = _
		TableTitle("设置查询条件", 600, "", "") & _
		"<table cellspacing=0 cellpadding=0 width=600 align=center border=0>" & _
		"<form name=""frmSearchTask"" method=post action=""tasktodo.asp"">"  & _
		"<tr height=30>" & _
		"	<td width=170>" & DrawCal("开始日期", pDay1, "day1", "dateimg1") & "	</td>" & _	
		"	<td width=170>" & DrawCal("结束日期", pDay2, "day2", "dateimg2") & "</td>" & _
		"	<td width=170>时效状态：<select name=""task_status"" style=""width:86px"">" & _
		"			<option value=0>全部</option>" & _
		"			<option value=1>已完成</option>" & _
		"			<option value=2>未完成</option>" & _
		"			<option value=3>正常未完成</option>" & _
		"			<option value=4>过时未完成</option>" & _	
		"		</select>" & _
		"		<script language=""javascript"">document.all.task_status.selectedIndex=" & pTaskStatus & "</script>" & _
		"	</td>" & _
		"	<td width=""*""><span id=btnSearch style=""cursor:hand"" title=""设置查询条件，然后点击查询按钮进行查询""><img border=0 src=""../images/search.gif"" style=""vertical-align:middle"">查询</span></td></tr>" & _
		"<tr height=5><td colspan=4></td></tr>" & _
		"</form>" & _
		"</table>"
End Function

Function TableHeader()
	Response.Write TableTitle("您在" & pDay1 & "～" & pDay2 & "需要完成的任务", 600, "", "#0040a0")
	TableHeader = _
		"<table cellspacing=1 cellpadding=0 width=600 align=center style=""table-layout:fixed"" bgcolor=silver>" & _
		"<tr>" & _
		"<td class=tdHead width=80>&nbsp;" & TableHeaderField(sFileName, "urgency", "紧急程度", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead width=55>&nbsp;" & TableHeaderField(sFileName, "progress_percent", "进度", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead width=""*"">&nbsp;<img src=""../images/bg/ar-y.gif"" width=8 height=8>&nbsp;" & TableHeaderField(sFileName, "subject", "任务名称", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead width=110>&nbsp;" & TableHeaderField(sFileName, "dofrom", "开始时间", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead width=110>&nbsp;" & TableHeaderField(sFileName, "doend", "完成期限", sFormParams, iSort, iSorted) & "</td>" & _
		"</tr>"
End Function

Function TableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams)
	''response.write sSQL & "<br>"' : response.end
	dim sTemp	: sTemp = ""	' 临时字符串变量
	dim j					' 临时循环变量

	'------------------------------------
	' 分页所需的变量定义
	'------------------------------------
	Dim iCounter		: iCounter = 1
	Dim iPrevPage, iNextPage
	
	'------------------------------------
	' 获取数据库连接
	'------------------------------------
	dim crs	: set crs = New CRecordset
	dim rs	: set rs = crs.open(dbLocal,sSQL)
	dim iPTSerial, iTSerial, iUrgency, sUrgency, iProgressPercent, sSubject, sDoFrom, sDoEnd
	
	' 如果未到记录尾，将记录定位到你翻到的页面的第一个记录，否则显示空行
	if Not rs.EOF then	
		rs.Move (iCurrentPage - 1) * iRecordsPerPage
	end if

	'' 过了完成时间但任务尚未完成的任务信息用红色表示
	dim foreColor
	while not rs.EOF and iCounter <= iRecordsPerPage
		iPTSerial			= crs.GetValue("Personal_Task_Serial")
		iTSerial				= crs.GetValue("Task_Serial")
		iUrgency			= crs.GetValue("urgency")
		iProgressPercent	= crs.GetValue("Progress_Percent")
		sSubject			= crs.GetValue("subject")
		sUrgency			= DLookup(dbLocal,"T_Urgency", "Urgency_desc", " urgency_id=" & iUrgency)
		sDoFrom			= crs.GetValue("dofrom")
		sDoEnd				= crs.GetValue("doend")

		if iProgressPercent = 100 then			'' 任务已完成用灰色表示
			foreColor = "gray"
		elseif iProgressPercent < 100 and sDoEnd < now then	'' 过期未完成用红色表示
			foreColor = "red"
		else
			foreColor = "black"
		end if

		sDoFrom = FormatDT(sDoFrom, "yyyy-mm-dd hh:mm")
		sDoEnd = FormatDT(sDoEnd, "yyyy-mm-dd hh:mm")
		
		sTemp = sTemp & "<tr bgcolor=white style=""color:" & foreColor & """ height=20>" & _
				"<td>&nbsp;<img src=""../images/bg/news.gif"" width=9 height=9>&nbsp;" & sUrgency & "&nbsp;</td>" & _
				"<td align=right>&nbsp;" & iProgressPercent & "%&nbsp;&nbsp;</td>" & _
				"<td title='" & sSubject & "' style=""cursor:hand;"" onclick=""javascript:location.href='dotask.asp?PSerial=" & iPTSerial & "';"" nowrap>&nbsp;<img src=""../images/bg/ar-g.gif"" width=8 height=8>&nbsp;" & ToHtml(sSubject) & "&nbsp;</td>" & _
				"<td align=center nowrap>" & sDoFrom & "</td>" & _
				"<td align=center nowrap>" & sDoEnd & "</td>" & _
				"</tr>"
		iCounter = iCounter + 1
		rs.movenext
	wend
	crs.Close()

	' 填补空白行
	sTemp = sTemp & WhiteRows(iCols, iCounter, iRecordsPerPage)

	' 首页、前页、后页、尾页等分页信息
	sTemp = sTemp & "<tr bgcolor=white height=20><td colspan=" & iCols & " align=right>" & _
				Paginate(sFileName, sFormParams, sSortParams, iCurrentPage, iTotalPages) & _
				"&nbsp;</td></tr>"
	TableRecords = sTemp
End Function


Function TableLink()
	TableLink = _
		"<table width=600 cellspacing=0 cellpadding=0 border=0 align=center>" & _
		"<tr height=10>" & _ 
		"	<td width=600><img src=""../images/bg/line.gif"" width=600 height=3></td>" & _
		"</tr>" & _
		"<tr height=20>" & _
		"	<td width=600>&nbsp;" & _
		"		<img src=""../images/goto.gif"">&nbsp;<a href=""task_a.asp"">安排任务</a>" & _
		"		&nbsp;&nbsp;&nbsp;" & _
		"		<img src=""../images/goto.gif"">&nbsp;<a href=""tasks.asp"">我安排的任务</a></td>" & _
		"</tr>" & _
		"</table>"
End Function
%>