📄 item_output.inc
字号:
<%
'###############################################################################
'#
'# 文件名 : item_output.inc
'#
'# 创建人 : yaoxiaohui
'# 日期 : 2002-11-06
'#
'# 修改历史 : ****年**月**日 ******
'# 修改内容 : *********************************
'#
'# 功能描述 : 领用函数文件
'# 版 本 : v1.0
'#
'# Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司
'#
'###############################################################################
'*******************************************************************************
Function SheetDetail()
pOpDate = date
SheetDetail = _
"<form name=""frmSheetDetail"" method=post action=""" & sFileName & """>" & vbLF & _
"<input type=""hidden"" name=""FormAction"">" & vbLF & _
"<table cellspacing=0 cellpadding=3 width=""100%"" align=center border=0>" & vbLF & _
"<tr height=20>" & _
"<td colspan=6 bgcolor=""black"" align=center style=""color:white;font-weight:600"">领料单细节</td></tr>" & _
" <tr height=30 bgcolor=white>" & vbLF & _
" <td align=right colspan=1>部 门：</td>" & vbLF & _
" <td>" & vbLF & _
" <select name=""node_id"" style=""width:100"">" & vbLF & _
" <option value=-1>全部</option>" & vbLF & _
SelectOptions(conn, "select *from t_node", "node_id", "node_desp", pNodeID) & vbLF & _
" </select></td>" & vbLF & _
" <td align=right>日 期：</td>" & vbLF & _
" <td>"& DrawCal("", pOpDate, "opdate", "dateimg") &"</td>" & vbLF & _
" </tr>" & vbLF & _
" <tr height=30 bgcolor=white>" & vbLF & _
" <td align=right>工作单号：</td>" & vbLF & _
" <td><input type=""text"" name=""worksheet_id"" value=""" & pWorksheetID & """ size=15 maxlength=20>" & vbLF & _
" <td align=right colspan=1>项目名称：</td>" & vbLF & _
" <td><input type=""text"" name=""item_name"" value=""" & pItemName & """ size=15 maxlength=20>" & vbLF & _
" </tr>" & vbLF & _
" <tr height=10 bgcolor=white><td colspan=8></td></tr>" & vbLF & _
"</table>" & vbLF
End Function
'*******************************************************************************
Function TableHeader()
TableHeader = _
"<table cellspacing=1 cellpadding=0 width=""100%"" align=center bgcolor=silver style=""table-layout:fixed"">" & vbLF & _
"<tr style=""display:none"">" & vbLF & _
" <td width=40>这一行仅用于控制表格的宽度</td>" & vbLF & _
" <td width=80></td>" & vbLF & _
" <td width=80></td>" & vbLF & _
" <td width=40></td>" & vbLF & _
" <td width=60></td>" & vbLF & _
" <td width=60></td>" & vbLF & _
" <td width=60></td>" & vbLF & _
" <td width=60></td>" & vbLF & _
" <td width=""*""></td></tr>" & vbLF & _
"<tr height=20>" & _
"<td colspan=" & iCols & " bgcolor=""#0040a0"" align=center style=""color:white;font-weight:600"">被领用物品和设备一览</td></tr>" & _
"<tr bgcolor=white>" & _
"<td class=tdHead align=center> 序号</td>" & _
"<td class=tdHead align=center> <img src=""../images/bg/ar-y.gif"" width=8 height=8> " & TableHeaderField(sFileName, "goods_name", "物品名称", sFormParams, sSorting, sSorted) & "</td>" & _
"<td class=tdHead align=center> " & TableHeaderField(sFileName, "model", "型号规格", sFormParams, sSorting, sSorted) & "</td>" & _
"<td class=tdHead align=center> " & TableHeaderField(sFileName, "unit", "单位", sFormParams, sSorting, sSorted) & "</td>" & _
"<td class=tdHead align=center> " & TableHeaderField(sFileName, "quantity", "库存数", sFormParams, sSorting, sSorted) & "</td>" & _
"<td class=tdHead align=center> " & TableHeaderField(sFileName, "input_method", "入库方式", sFormParams, sSorting, sSorted) & "</td>" & _
"<td class=tdHead align=center> " & TableHeaderField(sFileName, "unit_price", "单价", sFormParams, sSorting, sSorted) & "</td>" & _
"<td class=tdHead align=center> 数量</td>" & _
"<td class=tdHead align=center> 备注</td>" & _
"</tr>"
End Function
'*******************************************************************************
Function TableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams)
dim sTemp : sTemp = "" ' 临时字符串变量
dim j ' 临时循环变量
'------------------------------------
' 分页所需的变量定义
'------------------------------------
Dim iCounter : iCounter = 1
Dim iPrevPage, iNextPage
Dim rowCount : rowCount = 0
'------------------------------------
' 获取数据库连接
'------------------------------------
dim rs : set rs = Openrs(conn,sSQL)
dim GoodsID, sGoodsName, sModel, sUnit, sQuantity, sGoodsType, sInputMethod, sUnitPrice
''response.write sSQL : response.end
' 如果未到记录尾，将记录定位到你翻到的页面的第一个记录，否则显示空行
if Not rs.EOF then
rs.move (iCurrentPage - 1) * iRecordsPerPage
end if
while not rs.EOF and iCounter <= iRecordsPerPage
rowCount = rowCount + 1
GoodsID = rs("id")
sGoodsName = rs("goods_name")
sModel = rs("model")
sUnit = rs("unit")
sQuantity = rs("quantity")
sGoodsType = rs("type_desc")
sInputMethod = rs("input_method")
sUnitPrice = rs("unit_price")
select case sInputMethod
case "1"
sInputMethod = "采购入库"
case "2"
sInputMethod = "移交入库"
case "3"
sInputMethod = "归还入库"
end select
sTemp = sTemp & "<tr bgcolor=white height=20>" & _
"<td align=center nowrap> " & rowCount & " </td>" & _
"<input type=""hidden"" name=""goods_id_" & rowCount & """ value=""" & GoodsID &""">" & _
"<td align=center title=""" & sGoodsName & """ nowrap> " & sGoodsName & " </td>" & _
"<td align=center title=""" & sModel & """ nowrap> " & sModel & " </td>" & _
"<td align=center title=""" & sUnit & """ nowrap> " & sUnit & " </td>" & _
"<td align=center title=""" & sQuantity & """ nowrap> " & sQuantity & " </td>" & _
"<td align=center title=""" & sInputMethod & """ nowrap> " & sInputMethod & " </td>" & _
"<td align=center title=""" & sUnitPrice & """ nowrap> " & sUnitPrice & " </td>" & _
"<td align=center nowrap><input type=""text"" name=""quantity_" & rowCount & """ value=""" & pQuantity & """>" & _
"<input type=""hidden"" name=""quantity_in_" & rowCount & """ value=""" & sQuantity & """></td>" & _
"<td align=center nowrap><input type=""text"" name=""remark_" & rowCount & """ value=""" & pRemark & """ size=26 maxlength=50></td>" & _
"</tr>"
iCounter = iCounter + 1
rs.movenext
wend
rs.Close()
set rs = nothing
' 填补空白行
sTemp = sTemp & WhiteRows(iCols, iCounter, iRecordsPerPage)
' 首页、前页、后页、尾页等分页信息
sTemp = sTemp & "<tr bgcolor=white height=20><td colspan=" & iCols & " align=right>" & _
Paginate(sFileName, sFormParams, sSortParams, iCurrentPage, iTotalPages) & _
" </td></tr>"
TableRecords = _
sTemp & _
"<input type=""hidden"" name=""row_count"" value=""" & rowCount &""">" & _
" <tr height=30 bgcolor=white>" & vbLF & _
" <td colspan = 9 align=center>" & _
" <span title=""填写领用单各项细节，然后点击按钮进行出库"" style=""cursor:hand"" onmouseover=""mover();"" onmouseout=""mout();"" onclick=""btnItemadd_OnClick();"">" & _
" <img border=0 src=""../images/arrowr.gif"" style=""vertical-align:middle"">生成领用单</span>" & _
" " & vbLF & _
" <span title=""放弃出库"" style=""cursor:hand"" onmouseover=""mover();"" onmouseout=""mout();"" onclick=""btnCancel_OnClick();"">" & _
" <img border=0 src=""../images/delete.gif"" style=""vertical-align:middle"">放弃领用</span>" & _
" </td>" & vbLF & _
" </tr>" & _
"</form>"
End Function
'*******************************************************************************
Function ItemOutput()
dim sGoodsName, sModel, sUnit, sQuantity, sUnitPrices, sGoodsType, sDepotID, sLocation, sMinQ
dim pRemindID : pRemindID = ""
dim sSheetID
dim rowCount : rowCount = GetParam("row_count") ''记录数
dim iCount : iCount = 1
pOpdate = GetParam("opdate")
dim sql, sql2, sql3, rs
sql = "insert into t_stock_master(node_id,optype,department_manager,handover,receiver,worksheet_id,item_name,sheet_status)" & _
" values(" & ToSQL(pNodeID,"Text") & _
",4," & ToSQL(pDepMgr,"text") & "," & ToSQL(pHandover,"text") & _
"," & ToSQL(pReceiver,"text") & "," & ToSQL(pWorksheetID,"text") & _
"," & ToSQL(pItemName,"text") & ",0)"
'response.write sql & "<br>"
'response.end
call Openrs(conn,sql)
sql = "select Max(sheet_id) from t_stock_master"
sSheetID = DLookUp(conn,sql)
'response.write Cint(rowCount) & "<br>"
'response.end
while iCount <= Cint(rowCount)
pGoodsID = GetParam("goods_id_" & iCount)
pQuantity = GetParam("quantity_" & iCount)
pRemark = GetParam("remark_" & iCount)
sql = "select goods_name,model,quantity,unit,unit_price,goods_type,depot_id,location,min_quantity from t_goods" & _
" where goods_id = " & ToSQL(pGoodsID,"number")
'response.write sql & "<br>"
'response.end
set rs = Openrs(conn,sql)
if Not rs.EOF then
sGoodsName = rs("goods_name")
sModel = rs("model")
sUnit = rs("unit")
sQuantity = GetValue(rs, "quantity")
sUnitPrices = rs("unit_price")
sGoodsType = rs("goods_type")
sDepotID = rs("depot_id")
sLocation = GetValue(rs, "location")
sMinQ = GetValue(rs, "min_quantity")
end if
rs.Close()
set rs = nothing
sql2 = "insert into t_stock_detail(goods_id,sheet_id,goods_name,model,unit,quantity,unit_price,goods_type,depot,location,opdate,remark)" & _
" values(" & ToSQL(pGoodsID,"text") & "," & ToSQL(sSheetID,"number") & _
"," & ToSQL(sGoodsName,"text") & "," & ToSQL(sModel,"text") & _
"," & ToSQL(sUnit,"text") & "," & ToSQL(pQuantity,"number") & _
"," & ToSQL(sUnitPrices,"number") & "," & ToSQL(sGoodsType,"number") & _
"," & ToSQL(sDepotID,"number") & "," & ToSQL(sLocation,"text") & _
"," & ToSQL(pOpdate,"text") & "," & ToSQL(pRemark,"text") & ")"
call Openrs(conn,sql2)
'response.write sMinQ :response.end
iCount = iCount + 1
wend
sql = "update t_goods set current_status = 1 where current_status = 7"
call Openrs(conn,sql)
'response.write pRemindID : response.end
response.redirect "sheet_goto.asp?sheet_id=" & sSheetID
End Function
'*******************************************************************************
sub Cancel()
dim sql
sql = "update t_goods set current_status = 1 where current_status = 7"
call Openrs(conn,sql)
response.redirect "output.asp"
response.end
end sub
'*******************************************************************************
%>⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -