sheet_stock0120.asp

物业管理和办公自动化系统

<%
'##############################################################################
'#
'#		文 件 名	 : sheet_stock.asp
'#
'#
'#		创 建 人	 : yaoxiaohui
'# 　	日　  期	 : 2002-11-28
'#
'#		修改历史  : ****年**月**日 ******
'#      修改内容  : **************************************************
'#
'#		功能描述	 : 进出库物料明细选择时间和仓库
'# 　	版  　本	 : v1.0
'#	
'#	    Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司
'#
'##############################################################################
'------------------------------------------------------------------------------
'----   服务器端设置
'------------------------------------------------------------------------------
option explicit
Response.CacheControl = "no-cache"
Response.AddHeader "Pragma", "no-cache"
Response.Expires = -1
%>
<!-- include files begin -->

<!-- #include file="../include/common.inc" -->
<!-- #include file="../include/recordlist.inc" -->
<!-- #include file="../include/commonpage.inc" -->

<!-- #include file="sheet_stock.inc" -->

<!-- include files end -->
<%

'##############################################################################
'----   服务器端代码
'##############################################################################
call CheckSecurity()

if hasright(ID_STOCK) < RIGHT_READ  then
	Response.Clear
	Response.Redirect "../include/error.asp?error=你没有查询权限！"
	Response.end
end if

dim conn
set conn = DBConnection


'******************************************************************************
'----   分页相关的变量定义
'------------------------------------------------------------------------------
Dim sSQL, sWhere, sOrderby ,sWhere1
Dim sFileName			: sFileName			= "sheet_stock.asp"
Dim iTotalRecords		: iTotalRecords		= 0			                ' 分页
Dim iRecordsPerPage		: iRecordsPerPage	= 25                        ' 一页8行
Dim iTotalPages			: iTotalPages		= 0
Dim iCols				: iCols				= 9                         ' 9列
Dim iCurrentPage		: iCurrentPage		= GetParam("Page")
Dim sSorting			: sSorting			= GetParam("Sorting")
Dim sSorted				: sSorted			= GetParam("Sorted")
Dim sSortParams			: sSortParams		= ""
Dim sFormParams			: sFormParams		= ""
Dim sDirection			: sDirection		= ""
'******************************************************************************
'----   查询参数
'------------------------------------------------------------------------------
dim pOpdate1		: pOpdate1	= GetParam("opdate1")
dim pOpdate2		: pOpdate2	= GetParam("opdate2")
dim pDepotID		: pDepotID	= GetParam("depot_id")
if IsEmpty(pDepotID)       then pDepotID = -1
if IsEmpty(pOpdate1) then pOpdate1 = dateSerial(year(date), month(date), 1)
if IsEmpty(pOpdate2) then pOpdate2 = date

sFormParams = "opdate1=" & pOpdate1 & "&opdate2=" & pOpdate2 & "&depot_id=" & pDepotID & "&"
'******************************************************************************
'----   构造分页的SQL语句
'------------------------------------------------------------------------------
sSQL = "select t1.goods_id,t1.goods_name,t1.sheet_id,t1.model,t1.quantity,t1.unit,t1.goods_type,t1.opdate,t2.depot_name,t1.remark" & _
" from t_stock_detail t1" & _
" left join t_depot t2 on t1.depot = t2.depot_id" & _
" left join t_stock_master t3 on t1.sheet_id = t3.sheet_id"
sOrderby = " order by t1.opdate desc"
'******************************************************************************
'----   查询条件限制
'------------------------------------------------------------------------------
sWhere = " where t3.sheet_status <> 0 and t1.opdate >= " & ToSQL(pOpdate1, "Text") & " and t1.opdate < " & ToSQL(DateAdd("d", 1, pOpdate2), "Text")

if pDepotID > 0 then sWhere = sWhere & " and t1.depot = " & ToSQL(pDepotID, "number")

'******************************************************************************
'----   分页SQL语句构造完毕，调用PrepareListData进行分页前的准备
'------------------------------------------------------------------------------
dim arrayFields(8), sDelimiter
sDelimiter = "*"
arrayFields(0)	=	"goods_id"
arrayFields(1)	=	"goods_name"
arrayFields(2)	=	"model"
arrayFields(3)	=	"quantity"
arrayFields(4)	=	"unit"
arrayFields(5)	=	"unit_price"
arrayFields(6)	=	"opdate"
arrayFields(7)	=	"depot_name"
arrayFields(8)	=	"remark"

'response.write pSheetID  &"<BR>"
'response.write sSQL & sWhere & sOrderby  &"<BR>"
'response.end

call PrepareListData(conn,sSQL & sWhere & sOrderby, Join(arrayFields, sDelimiter), sDelimiter)

'******************************************************************************
%>

<html>
<head>
<title>上海信息大楼 Shanghai Information Tower</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link rel="stylesheet" href="../include/common.css" type="text/css">

<!-- 日历 -->
<IFRAME style="display:none;position:absolute;width:148;height:194;z-index=100" ID="CalFrame" MarginHeight=0 MarginWidth=0 noresize frameborder=0 scrolling=no src="../include/cal/calendar.htm"></IFRAME>
<script language="javascript" src="../include/cal/calendar.js"></script>
<script for=document event="onclick()">
<!--
document.all.CalFrame.style.display="none";
//-->
</script>
<!-- 日历 -->

<style type="text/css">
.tdlist		{border-width:0px}
.tdHead	    {border-width:0px}
</style>

<script language="VBScript">
Sub btnSearch_OnClick()
	document.all.frmSearch.submit()
End Sub
</script>

</head>

<body bgcolor="#FFFFFF" leftmargin="0" topmargin="0" marginwidth="0" marginheight="0" background="../images/bg/bg0.jpg">
<br>

<%
Response.Write OuterTableHeader
Response.Write HeaderWithMenu
Response.Write InnerTableHeader
'******************************************************************************
'----   主体从这里开始
'------------------------------------------------------------------------------
Response.Write TableSearch

Response.Write TableHeader
Response.Write TableRecords(sSQL & sWhere & sOrderby, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams )
Response.Write TableAction(sSQL & sWhere & sOrderby)
Response.Write TableLink
'------------------------------------------------------------------------------
'----   主体到这里结束
'******************************************************************************
Response.Write InnerTableTailer
Response.Write Footer
Response.Write OuterTableTailer
Disconnect(conn)
%>

</body>
</html>