purchase_input.inc

物业管理和办公自动化系统

<%
'#############################################################################################
'#
'#	文件名	 : purchase_input.inc
'#	
'#      创建人	 : yaoxiaohui
'#      日期	 : 2002-11-06
'#
'#	修改历史  : ****年**月**日 ****** 
'#      修改内容  : *********************************
'#
'#	功能描述	 : 选择物品和设备入库函数文件
'#      版  　本	 : v1.0
'#
'#      Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司
'#
'#############################################################################################
'************************************************************************************************
Function TableHeader()
      TableHeader = _
        "<table cellspacing=1 cellpadding=0 width=""100%"" align=center bgcolor=silver style=""table-layout:fixed"">" & vbLF & _
		"<tr style=""display:none"">" & vbLF & _
		"	<td width=100>这一行仅用于控制表格的宽度</td>" & vbLF & _
		"	<td width=40></td>" & vbLF & _
		"	<td width=80></td>" & vbLF & _
		"	<td width=80></td>" & vbLF & _
		"	<td width=100></td>" & vbLF & _
		"	<td width=80></td>" & vbLF & _
		"	<td width=80></td>" & vbLF & _
		"	<td width=100></td></tr>" & vbLF & _
		"<tr height=25>" & _
		"<td colspan=" & iCols & " bgcolor=""#0040a0"" align=center style=""color:white;font-weight:600"">请选择需要入库的采购单</td></tr>" & _
		"<tr height=25 bgcolor=white>" & _
		"<td class=tdHead align=center>&nbsp;<img src=""../images/bg/ar-y.gif"" width=8 height=8>&nbsp;" & TableHeaderField(sFileName, "sheet_id", "采购单编号", sFormParams, sSorting, sSorted) & "</td>" & _
		"<td class=tdHead align=center>选择</td>" & _
		"<td class=tdHead align=center>&nbsp;" & TableHeaderField(sFileName, "goods_type", "类别", sFormParams, sSorting, sSorted) & 	"</td>" & _
		"<td class=tdHead align=center>&nbsp;" & TableHeaderField(sFileName, "department", "申购部门", sFormParams, sSorting, sSorted) & "</td>" & _
		"<td class=tdHead align=center>&nbsp;" & TableHeaderField(sFileName, "is_temporary", "采购单类型", sFormParams, sSorting, sSorted) & "</td>" & _
		"<td class=tdHead align=center>&nbsp;" & TableHeaderField(sFileName, "buyer", "采购人", sFormParams, sSorting, sSorted) & "</td>" & _
		"<td class=tdHead align=center>&nbsp;" & TableHeaderField(sFileName, "purchase_time", "采购日期", sFormParams, sSorting, sSorted) & "</td>" & _
		"<td class=tdHead align=center>&nbsp;" & TableHeaderField(sFileName, "sheet_status", "采购单状态", sFormParams, sSorting, sSorted) & "</td>" & _
		"</tr>"
End Function
'************************************************************************************************
Function TableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams)
    dim sTemp	: sTemp = ""	' 临时字符串变量
	dim j					' 临时循环变量

	'------------------------------------
	' 分页所需的变量定义
	'------------------------------------
	Dim iCounter		: iCounter = 1
	Dim iPrevPage, iNextPage
	Dim rowCount        : rowCount = 0
	
	dim sSheetID, sGoodType, sDepartment, sIsTemporary, sBuyer, sPurchase_time, sSheetStatus
	'------------------------------------
	' 获取数据库连接
	'------------------------------------
	dim rs	: set rs = Openrs(conn,sSQL)
	
	''response.write sSQL : response.end
	
	' 如果未到记录尾，将记录定位到你翻到的页面的第一个记录，否则显示空行
	if Not rs.EOF then		
		rs.move (iCurrentPage - 1) * iRecordsPerPage
	end if
	
	while not rs.EOF and iCounter <= iRecordsPerPage
		rowCount = rowCount + 1
		sSheetID			        = rs("sheet_id")
		sGoodType		    	    = rs("goods_type")
		sDepartment			        = rs("department")
		sIsTemporary	         	= rs("is_temporary")
		sBuyer	     	        	= rs("buyer")			
		sPurchase_time	    		= rs("purchase_time")
        sSheetStatus	            = rs("sheet_status")
     
		select case sIsTemporary
		    case "0"
			sIsTemporary = "常规"
			case "1"
			sIsTemporary = "临时"
		end select

		sTemp = sTemp & "<tr bgcolor=white height=20>" & _
				"<td title=""点击可以察看“" & sSheetID & "”的信息"" style=""cursor:hand;color:blue;"" onclick=""javascript:location.href='../purchase/purchase_sheet.asp?sheet_id=" & sSheetID & "';"" nowrap>&nbsp;<img src=""../images/bg/ar-g.gif"" width=8 height=8>&nbsp;" & sSheetID & "&nbsp;</td>" & _
				"<td align=center><input type=""checkbox"" id=choose_" & rowCount & " name=""choose"" value=""" & rowCount & """ style=""border-width:0""></td>" & vbLF & _
				"<input type=""hidden"" name=""Sheet_id_" & rowCount & """ value=""" & sSheetID & """>" & vbLF & _
				"<input type=""hidden"" name=""type_id_" & rowCount & """ value=""" & sGoodType & """>" & vbLF & _
				"<td align=center title=""" & sGoodType & """ nowrap>&nbsp;" & sGoodType & "&nbsp;</td>" & _
				"<td align=center title=""" & sDepartment & """ nowrap>&nbsp;" & sDepartment & "&nbsp;</td>" & _
				"<td align=center title=""" & sIsTemporary & """ nowrap>&nbsp;" & sIsTemporary & "&nbsp;</td>" & _
				"<td align=center title=""" & sBuyer & """ nowrap>&nbsp;" & sBuyer & "&nbsp;</td>" & _
				"<td align=center title=""" & sPurchase_time & """ nowrap>&nbsp;" & sPurchase_time & "&nbsp;</td>" & _
				"<td align=center title=""" & sSheetStatus & """ nowrap>&nbsp;" & sSheetStatus & "&nbsp;</td>" & _
				"</tr>"
		iCounter = iCounter + 1
		rs.movenext
	wend
	rs.Close()
	set rs = nothing

	' 填补空白行
	sTemp = sTemp & WhiteRows(iCols, iCounter, iRecordsPerPage)

	' 首页、前页、后页、尾页等分页信息
	sTemp = sTemp & "<tr bgcolor=white height=20><td colspan=" & iCols & " align=right>" & _
				Paginate(sFileName, sFormParams, sSortParams, iCurrentPage, iTotalPages) & _
				"&nbsp;</td></tr>"
    TableRecords = _
	           "<form method=post name=""frmInput"" action=""" & sFileName & """>" & vbLF & _
			   "<input type=""hidden"" name=""FormAction"" value=""input_next"">" & vbLF & _
	           sTemp & _
			   ActionLink & _
			   "</form>" 

End Function
'************************************************************************************************
'*********************************************************************************************
Function ActionLink
		ActionLink = _
			"<img height=2>" & _
			"<table cellspacing=0 cellpadding=1 width=""100%"" align=center bgcolor=""#0099cc"" style=""color:white"">" & vbLF & _
			"<tr height=20>" & vbLF & _
			"		<td align=right" & _
						" style=""cursor:hand"" onmouseover=""mover();"" onmouseout=""mout();"" onclick=""CheckAllRows();"">全部选中</td>" & vbLF & _
			"		<td align=center" & _
						" style=""cursor:hand"" onmouseover=""mover();"" onmouseout=""mout();"" onclick=""btnInputNext_OnClick();"">继续</td>" & vbLF & _
			"</tr>" & vbLF & _
			"</table>" & vbLF
End Function
'*********************************************************************************************
sub InputNext(choose)
	dim arrayInput, sSheetID, j, pSheetID, sql, pTypeID, sTypeID
'	response.write choose & "<br>"
'	response.end
	arrayInput = split(choose, ",")
'	response.Write arrayInput(0) & "<br>"
'	response.Write arrayInput(1) & "<br>"
'	response.end
'	sSheetID = GetParam("sheet_id_" & Trim(arrayInput(0))) 
'	sql = "select goods_type from t_purchase_master where sheet_id =" & sSheetID
'	pTypeID = DLookUp(conn,sql)
	for j = 0 to UBound(arrayInput) step 1
			sSheetID = GetParam("sheet_id_" & Trim(arrayInput(j))) 
'			response.write sSheetID & "<br>"
'			sql = "select goods_type from t_purchase_master where sheet_id =" & sSheetID
'			sTypeID = DLookUp(conn,sql)
'			if pTypeID <> sTypeID then
'				response.write "alert("选择采购单的类别不一致!");"
'				End Sub
'			end if
			pSheetID = sSheetID & "," & pSheetID
	next
'	response.write pSheetID & "<br>"
'	response.end
    dim Num        :  Num = Len(pSheetID)
    pSheetID = left(pSheetID,Num - 1)
	Response.Redirect "purchase_input_detail.asp?id=" & pSheetID
end sub
'*******************************************************************************
Function TableLink()
	TableLink = _
		"<table width=""100%"" cellspacing=0 cellpadding=0 border=0 align=center>" & vbLF & _
		"<tr height=10>" & vbLF & _ 
		"	<td width=600><img src=""../images/bg/line.gif"" width=600 height=3></td>" & vbLF & _
		"</tr>" & vbLF & _
		"<tr>" & vbLF & _
		"	<td width=600>&nbsp;" & vbLF & _
		"		<img src=""../images/goto.gif"">&nbsp;<a href=""../stock/goods_query.asp"">库存查询</a>" & vbLF & _
		"		&nbsp;&nbsp;&nbsp;" & vbLF & _
		"		<img src=""../images/goto.gif"">&nbsp;<a href=""../stock/output.asp"">物品出库</a>" & vbLF & _
		"		&nbsp;&nbsp;&nbsp;" & vbLF & _
		"		<img src=""../images/goto.gif"">&nbsp;<a href=""../stock/goods_move.asp"">物品移动</a></td>" & vbLF &_
		"</tr>" & vbLF & _
		"</table>" & vbLF
End Function
%>