discard_output_over.asp

物业管理和办公自动化系统

<%
'##############################################################################
'#
'#		文 件 名	 : discard_output_over.asp
'#
'#
'#		创 建 人	 : yaoxiaohui
'# 　	日　  期	 : 2002-11-4
'#
'#		修改历史  : ****年**月**日 ******
'#      修改内容  : **************************************************
'#
'#		功能描述	 : 物品报废
'# 　	版  　本	 : v1.0
'#	
'#	    Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司
'#
'##############################################################################
'------------------------------------------------------------------------------
'----   服务器端设置
'------------------------------------------------------------------------------
option explicit
Response.CacheControl = "no-cache"
Response.AddHeader "Pragma", "no-cache"
Response.Expires = -1
%>
<!-- include files begin -->

<!-- #include file="../include/common.inc" -->
<!-- #include file="../include/recordlist.inc" -->
<!-- #include file="../include/commonpage.inc" -->

<!-- #include file="discard_output_over.inc" -->

<!-- include files end -->
<%

'##############################################################################
'----   服务器端代码
'##############################################################################
call CheckSecurity()
'------------------------------------------------------------------------------
'----   用户权限检查
'------------------------------------------------------------------------------
if hasright(ID_STOCK) < RIGHT_WRITE  then
	Response.Clear
	Response.Redirect "../include/error.asp?error=只有仓库管理员才能进行报废操作！"
	Response.end
end if
'******************************************************************************
'----   建立数据库连接
'------------------------------------------------------------------------------
dim conn
set conn = DBConnection

dim pSheetID	: pSheetID	= GetParam("sheet_id")

if IsEmpty(pSheetID) then
	Response.Clear
	Response.Redirect "../include/error.asp"
	Response.end
end if

dim pGoodsID, pQuantity, pRemark, pDiscardReason
dim pNodeID             : pNodeID      = GetParam("node_id")             ''部门
dim pDepMgr             : pDepMgr      = GetParam("department_manager")  ''主管
dim pHandover           : pHandover    = GetParam("handover")            ''制表
dim pOpdate             : pOpdate      = GetParam("opdate")		         ''日期

if UCase(Request.ServerVariables("REQUEST_METHOD") = "POST") then
dim sFormAction
sFormAction = GetParam("FormAction")
select case sFormAction
  case "next" :
    call ReturnOutput()
  case "cancel" :
    call Cancel()
  case "delete" :
	call Delete()
end select 
end if

'******************************************************************************
'----   分页相关的变量定义
'------------------------------------------------------------------------------
Dim sSQL, sWhere, sOrderby
Dim sFileName			: sFileName			= "discard_output_over.asp"
Dim iTotalRecords		: iTotalRecords		= 0			                ' 分页
Dim iRecordsPerPage		: iRecordsPerPage	= 8                        ' 一页10行
Dim iTotalPages			: iTotalPages		= 0
Dim iCols				: iCols				= 8                         ' 8列
Dim iCurrentPage		: iCurrentPage		= GetParam("Page")
Dim sSorting			: sSorting			= GetParam("Sorting")
Dim sSorted				: sSorted			= GetParam("Sorted")
Dim sSortParams			: sSortParams		= ""
Dim sFormParams			: sFormParams		= ""
Dim sDirection			: sDirection		= ""

'******************************************************************************
'----   构造分页的SQL语句
'------------------------------------------------------------------------------
sSQL = " select t1.goods_id,t1.sheet_id,t1.goods_name,t1.model,t1.unit,t1.quantity,t2.type_desc ,t1.unit_price,t3.depot_name,t1.location,t1.opdate,t1.remark" & _
       " from t_stock_detail t1" & _
	   " left join t_goods_type  t2 on t1.goods_type=t2.type_id" & _
	   " left join t_depot t3 on t1.depot = t3.depot_id"
sWhere = " where t1.sheet_id =" & pSheetID
sOrderby = " order by t1.goods_id"

'******************************************************************************
'----   分页SQL语句构造完毕，调用PrepareListData进行分页前的准备
'------------------------------------------------------------------------------
dim arrayFields(8), sDelimiter
sDelimiter = "*"
arrayFields(0)	=	"goods_name"
arrayFields(1)	=	"model"
arrayFields(2)	=	"unit"
arrayFields(3)	=	"quantity"
arrayFields(4)	=	"type_desc"
arrayFields(5)	=	"unit_price"
arrayFields(6)	=	"depot_name"
arrayFields(7)	=	"location"
arrayFields(8)	=	"remark"

call PrepareListData(conn,sSQL & sWhere & sOrderby, Join(arrayFields, sDelimiter), sDelimiter)
'******************************************************************************
%>

<html>
<head>
<title>上海信息大楼 Shanghai Information Tower</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link rel="stylesheet" href="../include/common.css" type="text/css">

<style type="text/css">
.tdlist		{border-width:0px}
.tdHead	    {border-width:0px}
</style>

<!-- 日历 -->
<IFRAME style="display:none;position:absolute;width:148;height:194;z-index=100" ID="CalFrame" MarginHeight=0 MarginWidth=0 noresize frameborder=0 scrolling=no src="../include/cal/calendar.htm"></IFRAME>
<script language="javascript" src="../include/cal/calendar.js"></script>
<script for=document event="onclick()">
<!--
document.all.CalFrame.style.display="none";
//-->
</script>
<!-- 日历 -->

<script language="javascript">

function mover()
{
	var obj = window.event.srcElement;
	obj.style.color = 'blue';
}

function mout()
{
	var obj = window.event.srcElement;
	obj.style.color = 'black';
}

function btnItemadd_OnClick()
{
	if (frmSheetDetail.department_manager.value == 0)
	{
		alert("请输入部门主管!");
		frmSheetDetail.department_manager.focus();
		return;
	}
	if (frmSheetDetail.handover.value == 0)
	{
		alert("请输入制表人!");
		frmSheetDetail.handover.focus();
		return;
	}
	if ( window.confirm("你确定要完成报废单吗？\n\n确认请按“确定”，取消请按“取消”。") == true )
	{
		frmSheetDetail.FormAction.value = "next";
		frmSheetDetail.submit();
	}
}
function btnCancel_OnClick()
{
	frmSheetDetail.FormAction.value = "cancel";
	frmSheetDetail.submit();
}
function btnDelete_OnClick()
{
	if ( window.confirm("你要删除该报废单吗？\n\n一旦删除无法恢复！\n\n确认请按“确定”，取消请按“取消”。") == true )
	{
		frmSheetDetail.FormAction.value = "delete";
		frmSheetDetail.submit();
	}
}
</script>


</head>

<body bgcolor="#FFFFFF" leftmargin="0" topmargin="0" marginwidth="0" marginheight="0" background="../images/bg/bg0.jpg">
<br>

<%
'response.write sSQL & sWhere & sOrderby & "<br>" : response.end
Response.Write OuterTableHeader
Response.Write HeaderWithMenu
Response.Write InnerTableHeader
'******************************************************************************
'----   主体从这里开始
'------------------------------------------------------------------------------
Response.Write TableHeader
Response.Write TableRecords(sSQL & sWhere & sOrderby, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams )
Response.Write SheetDetail
Response.Write ActionLink
'------------------------------------------------------------------------------
'----   主体到这里结束
'******************************************************************************
Response.Write InnerTableTailer
Response.Write Footer
Response.Write OuterTableTailer
Disconnect(conn)
%>

</body>
</html>