goods_detail.inc

物业管理和办公自动化系统

<%
'###############################################################################
'#
'#	文件名	 : goods_detail.inc
'#	
'#      创建人	 : yaoxiaohui
'#      日期	 : 2002-11-06
'#
'#	修改历史  : ****年**月**日 ****** 
'#      修改内容  : *********************************
'#
'#	功能描述	 : 库存物品和设备详细信息函数文件
'#      版  　本	 : v1.0
'#
'#      Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司
'#
'################################################################################

'********************************************************************************
Function TableDetail()
	'' 是否设备，0否，1是
	'' 进货方式分类，0全部，1为采购入库，2为移交入库，3为归还入库
	'' 库存状态分类，0全部，1在库中，2已借出，3已报废，4已退货，5已领用，6已移出
	'' 提醒状态分类，1正常中，2提醒中，3采购中

	dim GoodsID, sGoodsName, sModel, sUnit, sQuantity, sGoodsDesp, sIsEquip
	dim sGoodsType, sMinQuantity, sUnitPrice, sBestBefore, sRemark, sRemindStatus
	dim sDepotID, sLocation, sKeeper, sInputMethod, sCurrentStatus
	
	dim sSQL

	sSQL = "select t1.goods_id,t1.goods_name,t1.model,t1.unit,t1.quantity,t1.goods_desp,t1.is_equip" & _
	      " ,t2.type_desc,t1.min_quantity,t1.unit_price,t1.best_before,t1.remark,t1.remind_status" & _
		  " ,t3.depot_name,t1.location,t1.keeper,t1.input_method,t1.current_status" & _
		  " from t_goods t1" & _
	      " left join t_goods_type  t2 on t1.goods_type=t2.type_id" & _
	      " left join t_depot  t3 on t1.depot_id=t3.depot_id" & _
          " where  t1.goods_id =" & pGoodsID 
	
	'response.write sSQL
	'response.end
	
	dim rs	: set rs = Openrs(conn,sSQL)

	'' 若找不到相应的记录，则跳转到出错页面
	if rs.EOF then
			Response.Clear
			Server.Transfer("../common/error.asp")
			Response.end
	end if

	    GoodsID			        = rs("goods_id")              ''物品ID
	    sGoodsName			    = rs("goods_name")            ''物品名称
	    sModel			        = rs("model")                 ''型号规格
		sUnit		        	= rs("unit")                  ''单位
		sQuantity			    = rs("quantity")              ''库存数
		sGoodsDesp              = rs("goods_desp")            ''描述
		sIsEquip                = rs("is_equip")              ''是否设备
		sGoodsType		    	= rs("type_desc")             ''物品类别
		sMinQuantity            = rs("min_quantity")          ''最小库存数
		sUnitPrice              = rs("unit_price")            ''单价
		sBestBefore             = rs("best_before")           ''保质期
		sRemark                 = rs("remark")                ''备注
		sRemindStatus           = rs("remind_status")         ''提醒状态
		sLocation               = rs("location")              ''存货位置
		sKeeper                 = rs("keeper")                ''保管员
		sInputMethod	        = rs("input_method")		  ''入库方式
		sCurrentStatus			= rs("current_status")        ''当前状态
		sDepotID		    	= rs("depot_name")	          ''仓库名称
	
	rs.Close()
	set rs = nothing
	
		select case sIsEquip
		    case "0"
			sIsEquip = "否"
			case "1"
			sIsEquip = "是"
		end select

		select case sRemindStatus
		    case "1"
			sRemindStatus = "正常"
			case "2"
			sRemindStatus = "提醒中"
			case "3"
			sRemindStatus = "采购中"
		end select
		
		select case sInputMethod
		    case "1"
			sInputMethod = "采购入库"
			case "2"
			sInputMethod = "移交入库"
			case "3"
			sInputMethod = "归还入库"
		end select

        select case sCurrentStatus
		    case "1"
			sCurrentStatus = "在库中"
			case "2"
			sCurrentStatus = "已借出"
			case "3"
			sCurrentStatus = "已报废"
			case "4"
			sCurrentStatus = "已退货"
			case "5"
			sCurrentStatus = "已领用"
			case "6"
			sCurrentStatus = "已移出"
		end select

	TableDetail = _
		"<table cellspacing=1 cellpadding=3 bgcolor=""silver"" width=""100%"" border=0 style=""table-layout:fixed"">" & vbLF & _
		"	<tr style=""display:none"">" & vbLF & _
		"		<td width=75>这一行仅用于控制每一栏的宽度</td><td width=75>这一行仅用于控制每一栏的宽度</td>" & vbLF & _
		"		<td width=75>这一行仅用于控制每一栏的宽度</td><td width=75>这一行仅用于控制每一栏的宽度</td>" & vbLF & _
		"		<td width=75>这一行仅用于控制每一栏的宽度</td><td width=75>这一行仅用于控制每一栏的宽度</td>" & vbLF & _
		"		<td width=75>这一行仅用于控制每一栏的宽度</td><td width=75>这一行仅用于控制每一栏的宽度</td>" & vbLF & _
		"	</tr>" & vbLF & _
		
		"	<tr bgcolor=""#0040a0"" style=""color:white;font-weight:600"">" & vbLF & _
		"		<td colspan=8 align=center>物品或设备详细情况一览</td>" & vbLF & _
		"	</tr>" & vbLF & _
		
		"	<tr bgcolor=white height=25>" & vbLF & _
		"		<td align=center>物品名称</td><td class=tdValue nowrap colspan=3>" & sGoodsName & "</td>" & vbLF & _
		"		<td align=center>型号规格</td><td class=tdValue nowrap>" & sModel & "</td>" & vbLF & _
		"		<td align=center>单位</td><td class=tdValue nowrap>" & sUnit & "</td>" & vbLF & _
		"	</tr>" & vbLF & _
		
		"	<tr bgcolor=white height=25>" & vbLF & _
		"       <td align=center>是否设备</td><td class=tdValue nowrap>" & sIsEquip & "</td>" & vbLF & _
		"       <td align=center>类别</td><td class=tdValue nowrap>" & sGoodsType & "</td>" & vbLF & _
		"       <td align=center>单价</td><td class=tdValue nowrap>" & sUnitPrice & "</td>" & vbLF & _
		"       <td align=center>库存数</td><td class=tdValue nowrap>" & sQuantity & "</td>" & vbLF & _
		"	</tr>" & vbLF & _

		"	<tr bgcolor=white height=50>" & vbLF & _
		"       <td align=center>描述</td><td valign=top colspan=7 style=""word-wrap:break-word;""><pre>" & sGoodsDesp & "</pre></td>" & vbLF & _
		"	</tr>" & vbLF & _

		"	<tr bgcolor=white height=25>" & vbLF & _
		"		<td align=center>保值期至</td><td class=tdValue nowrap colspan=3>" & sBestBefore & "</td>" & vbLF & _
		"		<td align=center>当前状态</td><td class=tdValue nowrap>" & sCurrentStatus & "</td>" & vbLF & _
		"		<td align=center>最小库存</td><td class=tdValue nowrap>" & sMinQuantity & "</td>" & vbLF & _
		"	</tr>" & vbLF & _
		
		"	<tr bgcolor=white height=25>" & vbLF & _
		"       <td align=center>存放仓库</td><td class=tdValue nowrap>" & sDepotID & "</td>" & vbLF & _
		"       <td align=center>存货位置</td><td class=tdValue nowrap>" & sLocation & "</td>" & vbLF & _
		"       <td align=center>保管员</td><td class=tdValue nowrap>" & sKeeper & "</td>" & vbLF & _
		"       <td align=center>入库方式</td><td class=tdValue nowrap>" & sInputMethod & "</td>" & vbLF & _
		"	</tr>" & vbLF & _
		
		"	<tr bgcolor=white height=50>" & vbLF & _
		"		<td align=center>备注</td>" & vbLF & _
		"		<td valign=top colspan=7 style=""word-wrap:break-word;""><pre rows=3 cols=87>" & sRemark & "</pre></td>" & vbLF & _
		"</table>"
End Function
'********************************************************************************
function TableAction()
dim sTemp	: sTemp	= ""
if hasright(ID_STOCK) < RIGHT_WRITE  then
else
	sTemp = _
		"		<a style=""color:blue;cursor:hand"" target=_blank href=""goods_update.asp?id=" & pGoodsID & """><img border=0 src=""../images/edit.gif"">&nbsp;修改物品信息</a>" & vbLF & _
		"		&nbsp;&nbsp;&nbsp;" & vbLF
end if
	
	TableAction = _
		"<table width=600 cellspacing=0 cellpadding=5 height=30 align=center>" & vbLF & _
		"	<tr>" & vbLF & _
		"	<td align=center>" & _
		sTemp & _
		"		<a style=""color:blue;cursor:hand"" href=""goods_query.asp""><img border=0 src=""../images/delete.gif"">&nbsp;返回查询界面</a>" & vbLF & _
		"   </td>" & vbLF & _
		"	</tr>" & vbLF & _
		"</table>"
end function

'*******************************************************************************
Function TableLink()
	TableLink = _
		"<table width=""100%"" cellspacing=0 cellpadding=0 border=0 align=center>" & vbLF & _
		"<tr height=10>" & vbLF & _ 
		"	<td width=600><img src=""../images/bg/line.gif"" width=600 height=3></td>" & vbLF & _
		"</tr>" & vbLF & _
		"<tr>" & vbLF & _
		"	<td width=600>&nbsp;" & vbLF & _
		"		<img src=""../images/goto.gif"">&nbsp;<a href=""../stock/goods_input.asp"">物品入库</a>" & vbLF & _
		"		&nbsp;&nbsp;&nbsp;" & vbLF & _
		"		<img src=""../images/goto.gif"">&nbsp;<a href=""../stock/output.asp"">物品出库</a>" & vbLF & _
		"		&nbsp;&nbsp;&nbsp;" & vbLF & _
		"		<img src=""../images/goto.gif"">&nbsp;<a href=""../stock/goods_move.asp"">物品移动</a>" & vbLF & _
		"		&nbsp;&nbsp;&nbsp;" & vbLF & _
		"		<img src=""../images/goto.gif"">&nbsp;<a href=""../stock/depot_mgr.asp"">仓库管理</a>" & vbLF & _
		"		&nbsp;&nbsp;&nbsp;" & vbLF & _
		"		<img src=""../images/goto.gif"">&nbsp;<a href=""../stock/sheet_mgr.asp"">出入库单管理</a></td>" & vbLF & _
		"</tr>" & vbLF & _
		"</table>" & vbLF
End Function
%>