📄 room_mgr.asp
字号:
<%
'***********************************************************************
' 文件名: typemgr.asp
' Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司
'
' 创建人 : 蔡晓燕
' 日 期 : 2002-11-06
'
' 修改历史 :
' ****年**月**日 ****** 修改内容:*******************************************
' 功能描述 : 设备类型管理，即对表T_equipment_type进行增删改
' 版 本 :
'***********************************************************************
option explicit
Response.CacheControl = "no-cache"
Response.AddHeader "Pragma", "no-cache"
Response.Expires = -1
%>
<!-- #include file="../include/common.inc" -->
<!-- #include file="../include/commonpage.inc" -->
<!-- #include file="../include/recordlist.inc" -->
<!-- #include file="room_mgr.inc" -->
<%
call CheckSecurity()
'' 如果不是设备管理员，则无权进入本页
if hasright(ID_EQUIPMENT) < RIGHT_READ then
Response.Clear
Response.Redirect "../include/error.asp?error=只有设备管理员才能进行机房管理！"
Response.end
end if
'***********************************************************************
' 服务器端代码
'***********************************************************************
dim sInfo
sInfo = ""
' 建立数据库连接
dim conn
Set conn = DBConnection
' 定义全局变量:
' pRoomId 传递到本页面的参数，根据该参数到t_room表获取相应的机房信息
Dim pRoomId : pRoomId = GetParam("room_id")
Dim sRoomName, sRoomNo, sKeyNo, sLocation, sFloor
if Not IsEmpty(pRoomId) then
dim rs : set rs = conn.execute("select * from t_room where room_id = " & ToSQL(pRoomId, "Number"))
if rs.eof then
rs.Close()
set rs = nothing
Disconnect(conn)
Response.Redirect "../include/error.asp"
Response.end
end if
sRoomName = GetValue(rs, "room_name")
sRoomNo = GetValue(rs, "room_no")
sKeyNo = GetValue(rs, "key_no")
sLocation = GetValue(rs, "location")
sFloor = GetValue(rs, "floor")
rs.Close()
set rs = nothing
end if
'***********************************************************************
' 如果是提交，则调用函数InsertType或UpdateType或DeleteType更新数据库
Dim sFormAction
if UCase(Request.ServerVariables("REQUEST_METHOD") = "POST") then
sFormAction = GetParam("FormAction")
select case sFormAction
case "insert":
call AddRoom()
case "update":
call UpdateRoom()
case "delete":
call DeleteRoom()
end select
end if
'-----------------------------------------------------------------------------------------------------------------
' 分页相关的变量定义
'-----------------------------------------------------------------------------------------------------------------
Dim sSQL, sOrderby
Dim sFileName : sFileName = "room_mgr.asp"
Dim iTotalRecords : iTotalRecords = 0 ' 分页
Dim iRecordsPerPage : iRecordsPerPage = 15
Dim iTotalPages : iTotalPages = 0
Dim iCols : iCols = 5
Dim iCurrentPage : iCurrentPage = GetParam("Page")
Dim sSorting : sSorting = GetParam("Sorting")
Dim sSorted : sSorted = GetParam("Sorted")
Dim sSortParams : sSortParams = ""
Dim sFormParams : sFormParams = ""
Dim sDirection : sDirection = ""
'***********************************************************************
'' 构造分页的SQL语句
'***********************************************************************
sSQL = "select room_id, room_name, room_no, key_no, location, floor from t_room"
sOrderby = " order by room_no asc"
'***********************************************************************
' 分页SQL语句构造完毕，调用PrepareListData进行分页前的准备
'-----------------------------------------------------------------------------------------------------------------
dim arrayFields(4), sDelimiter
sDelimiter = "*"
arrayFields(0) = "room_name"
arrayFields(1) = "room_no"
arrayFields(2) = "key_no"
arrayFields(3) = "location"
arrayFields(4) = "floor"
call PrepareListData(conn, sSQL, Join(arrayFields, sDelimiter), sDelimiter)
'***********************************************************************
%>
<html>
<head>
<title>上海信息大楼 Shanghai Information Tower</title>
<meta http-equiv="Content-Type" content="text/html;charset=gb2312">
<link rel="stylesheet" href="../include/common.css" type="text/css">
<script language="javascript" src="../include/common.js"></script>
<script language="javascript" src="room_mgr.js"></script>
</head>
<body bgcolor="#FFFFFF" leftmargin="0" topmargin="0" marginwidth="0" marginheight="0" background="../images/bg/bg0.jpg">
<br>
<%
Response.Write OuterTableHeader
Response.Write HeaderWithMenu
Response.Write InnerTableHeader
'***********************************************************************
' 主体从这里开始
%>
<%
Response.Write _
"<table cellspacing=1 width=""100%"" cellpadding=0 border=0 bgcolor=navy>" & _
"<tr>" & _
"<td width=400 valign=top bgcolor=white>" & _
ListTableHeader & _
ListTableRecords(sSQL&sOrderby, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams ) & _
ListTableTailer() & _
"</td>" & _
"<td width=280 valign=top bgcolor=white>" & _
FormTable & _
"</td></tr></table>"
'-----------------------------------------------------------------------------------------------------------------
' 主体到这里结束
'***********************************************************************
Response.Write InnerTableTailer
Response.Write Footer
Response.Write OuterTableTailer
Disconnect(conn)
%>
</body>
</html>
⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -