room_mgr.inc

物业管理和办公自动化系统

<%
Function ListTableHeader()
	ListTableHeader = _
		"<table cellspacing=1 cellpadding=3 width=""100%"" border=0 align=center bgcolor=silver style=""table-layout:fixed"">" & vbLF & _
		"<tr style=""display:none"">" & vbLF & _
		"	<td width=90></td>" & vbLF & _
		"	<td width=""*""></td>" & vbLF & _
		"	<td width=75></td>" & vbLF & _
		"	<td width=60></td>" & vbLF & _
		"	<td width=50></td>" & vbLF & _
		"</tr>" & vbLF & _
		"<tr><td colspan=" & iCols & " bgcolor=""#0040a0"" align=center style=""color:white;font-weight:600"" height=20 >机 房 列 表</td></tr>" & vbLF & _
		"<tr bgcolor=""#eeeeee"">" & vbLF & _
		"	<td class=tdHead><img src=""../images/bg/ar-y.gif"" width=8 height=8>&nbsp;" & _
			TableHeaderField(sFileName, "room_no", "机房编号", sFormParams, sSorting, sSorted) & "</td>" & vbLF & _
		"	<td class=tdHead align=center>" & _
			TableHeaderField(sFileName, "room_name", "机房名称", sFormParams, sSorting, sSorted) & "</td>" & vbLF & _
		"	<td class=tdHead align=center>" & _
			TableHeaderField(sFileName, "key_no", "钥匙编号", sFormParams, sSorting, sSorted) & "</td>" & vbLF & _
		"	<td class=tdHead align=center>" & _
			TableHeaderField(sFileName, "location", "方位", sFormParams, sSorting, sSorted) & "</td>" & vbLF & _
		"	<td class=tdHead align=center>" & _
			TableHeaderField(sFileName, "floor", "楼层", sFormParams, sSorting, sSorted) & "</td>" & vbLF & _
		"</tr>" & vbLF
End Function

Function ListTableTailer()
	ListTableTailer = "</table>" & vbLF
End Function

Function ListTableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams)
	dim sTemp	: sTemp = ""	' 临时字符串变量
	dim j					' 临时循环变量

	'------------------------------------
	' 分页所需的变量定义
	'------------------------------------
	Dim iCounter		: iCounter = 1
	Dim iPrevPage, iNextPage
	
	'------------------------------------
	' 获取数据库连接
	'------------------------------------
'	response.write sSQL
'	response.end
	dim rs	: set rs = Openrs(conn,sSQL)
	dim iRoomId, sRoomName, sRoomNo, sKeyNo, sLocation, sFloor
	dim sColor	

	' 如果未到记录尾，将记录定位到你翻到的页面的第一个记录，否则显示空行
	if Not rs.EOF then	
		rs.Move (iCurrentPage - 1) * iRecordsPerPage
	end if
	while not rs.EOF and iCounter <= iRecordsPerPage
		iRoomId		= GetValue(rs, "room_id")
		sRoomName	= GetValue(rs, "room_name")
		sRoomNo		= GetValue(rs, "room_no")
		sKeyNo			= GetValue(rs, "key_no")
		sLocation		= GetValue(rs, "location")
		sFloor			= GetValue(rs, "floor")
		if CStr(iRoomId) = CStr(pRoomId) then		'' 如果是选中的纪录，显示不同的颜色，这里指定红色
				sColor = "red"
		else
				sColor = "black"
		end if
		sTemp = sTemp & "<tr bgcolor=white style=""cursor:hand;color:" & sColor & """" & _
			" onmouseover=""javascript:this.style.color='blue';""" & _
			" onmouseout=""javascript:this.style.color='" & sColor & "';""" & _
			" onclick=""javascript:location.href='room_mgr.asp?room_id=" & iRoomId & "&Page="&iCurrentPage&"';"">" & vbLF & _
				"<td title=""" & sRoomNo & """>&nbsp;<img src=""../images/bg/ar-g.gif"" width=8 height=8>&nbsp;" & sRoomNo & "&nbsp;</td>" & vbLF & _
				"<td align=center>" & sRoomName & "</td>" & vbLF & _
				"<td align=center>" & sKeyNo & "</td>" & vbLF & _
				"<td align=center>" & sLocation & "</td>" & vbLF & _
				"<td align=center>" & sFloor & "</td>" & vbLF & _
				"</tr>" & vbLF
		iCounter = iCounter + 1
		rs.movenext
	wend

	' 填补空白行
	sTemp = sTemp & WhiteRows(iCols, iCounter, iRecordsPerPage)

	' 首页、前页、后页、尾页等分页信息
	sTemp = sTemp & "<tr bgcolor=white><td colspan=" & iCols & " align=right>" & vbLF & _
				Paginate(sFileName, sFormParams, sSortParams, iCurrentPage, iTotalPages) & vbLF & _
				"&nbsp;</td></tr>" & vbLF

	ListTableRecords = sTemp
End Function


Function FormTable()
	dim sTitle, sActionLinks
	if IsEmpty(pRoomId) then
		sTitle = "新增机房信息"			'' 显示新增、取消的链接
		sActionLinks = _
				"<tr bgcolor=white height=50>" & vbLF & _
				"	<td colspan=2 align=center>" & vbLF & _
				"		<img border=0 src=""../images/button/add.gif"" onclick=""btnAdd_OnClick()"" style=""cursor:hand"">" & vbLF & _
				"		&nbsp;&nbsp;" & vbLF & _
				"		<img border=0 src=""../images/button/clear.gif"" onclick=""btnClear_OnClick()"" style=""cursor:hand"">" & vbLF & _
				"	</td>" & vbLF & _
				"</tr>" & vbLF
	else
		sTitle = "编辑机房信息"			'' 显示修改、删除、取消的链接
		sActionLinks = _
				"<tr bgcolor=white height=50>" & vbLF & _
				"	<td colspan=2 align=center>" & vbLF & _
				"		<img border=0 src=""../images/button/update.gif"" onclick=""btnUpdate_OnClick()"" style=""cursor:hand"">" & vbLF & _
				"		&nbsp;" & vbLF & _
				"		<img border=0 src=""../images/button/delete.gif"" onclick=""btnDelete_OnClick()"" style=""cursor:hand"">" & vbLF & _
				"		&nbsp;" & vbLF & _
				"		<img border=0 src=""../images/button/cancel.gif"" onclick=""btnCancel_OnClick()"" style=""cursor:hand"">" & vbLF & _
				"	</td>" & vbLF & _
				"</tr>" & vbLF
	end if

	FormTable = _
		"<table cellspacing=1 cellpadding=3 border=0 width=""100%"" height=""100%"">" & vbLF & _
		"<form method=post name=frmMgr action=""room_mgr.asp"">" & vbLF & _
		"<input type=""hidden"" name=""FormAction"">" & vbLF & _
		"<input type=""hidden"" name=""Page"" value=""" & iCurrentPage & """>" & vbLF & _
		"<input type=""hidden"" name=""room_id"" value=""" & pRoomId & """>" & vbLF & _
		"<tr height=20>" & vbLF & _
		"		<td colspan=2 background=""../images/bg/bnbg.gif"" style=""color:white;font-weight:600"" align=center>" & sTitle & "</td></tr>" & vbLF & _
		"<tr height=5><td colspan=2></td></tr>" & vbLF & _
		"<tr><td colspan=2 align=center style=""color:red"">" & sInfo & "</td></tr>" & vbLF & _
		"<tr height=5><td colspan=2></td></tr>" & vbLF & _
		"<tr height=30>" & vbLF & _
			"	<td align=right width=120>机房名称：</td>" & _
			"	<td><input type=""text"" name=""room_name"" value=""" & sRoomName & """ size=18 maxlength=20></td></tr>" & vbLF & _
		"<tr height=30>" & vbLF & _
			"	<td align=right>楼层代号：</td>" & _
			"	<td><input type=""text"" name=""floor"" value=""" & sFloor & """ size=18 maxlength=2></td></tr>" & vbLF & _
		"<tr height=30>" & vbLF & _
			"	<td align=right>所处方位：</td>" & _
			"	<td><input type=""text"" name=""location"" value=""" & sLocation & """ size=18 maxlength=20></td></tr>" & vbLF & _
		"<tr height=30>" & vbLF & _
			"	<td align=right>机房编号：</td>" & _
			"	<td><input type=""text"" name=""room_no"" value=""" & sRoomNo & """ size=18 maxlength=8></td></tr>" & vbLF & _
		"<tr height=30>" & vbLF & _
			"	<td align=right>钥匙编号：</td>" & _
			"	<td><input type=""text"" name=""key_no"" value=""" & sKeyNo & """ size=18 maxlength=10></td></tr>" & vbLF & _
		"<tr><td colspan=2 style=""color:green"">　　注:<br> 　　1.楼层代号由2位代码组成，如地下一层以“B1”表示，地下二层以“B2表示”，…，一楼以“01”表示，二楼以“02”表示，…，18楼以“18”表示，19楼以“19”表示，以此类推。<br>　　2.机房编号由8位代码组成，前两位与楼层代号相同。</td></tr>" & vbLF & _
		
		sActionLinks & vbLF & _

		"</form>" & _
		"</table>" & vbLF & _
		""
End Function

Function TableLink()
	TableLink = _
		"<table width=600 cellspacing=0 cellpadding=0 border=2 align=center>" & _
		"<tr height=10>" & _ 
		"	<td width=600><img src=""../images/bg/line.gif"" width=600 height=3></td>" & _
		"</tr>" & _
		"<tr height=20>" & _
		"	<td width=600>&nbsp;" & _
		"		<img src=""../images/goto.gif"">&nbsp;<a href=""position.asp"">职务管理</a>" & _
		"		&nbsp;" & _
		"		<img src=""../images/goto.gif"">&nbsp;<a href=""emp_ol.asp"">员工信息查询</a></td>" & _
		"</tr>" & _
		"</table>"
End Function


sub AddRoom()
	dim sSQL, iRows
	'dim sRoomName, sRoomNo, sKeyNo, sLocation, sFloor
	sRoomName = GetParam("room_name")
	sRoomNo = GetParam("room_no")
	sKeyNo	 = GetParam("key_no")
	sLocation = GetParam("location")
	sFloor = GetParam("floor")

	'' 检查是否存在重复的类别名称
	iRows = DLookUp(conn, "select count(*) from t_room where room_no =" & ToSQL(sRoomNo, "Text"))
	if iRows > 0 then
		sInfo = "对不起，机房编号“" & sRoomNo & "”<br>已经存在，请选择其它的编号！"
		'Response.Write _
		'		"<script language=""javascript"">" & vbLF & _
		'		"		alert(""对不起，机房编号“" & sRoomNo & "”已经存在，请选择其它的编号！"");" & vbLF & _
		'		"</script>" & vbLF
		exit sub
	end if
	sSQL = "insert into t_room(room_name, room_no, key_no, location, floor)" & _
			" values(" & ToSQL(sRoomName, "Text") & _
			", " & ToSQL(sRoomNo, "Text") & _
			", " & ToSQL(sKeyNo, "Text") & _
			", " & ToSQL(sLocation, "Text") & _
			", " & ToSQL(sFloor, "Text") & _
			")"
	conn.Execute(sSQL)
	
	sInfo = "<span style=""color:blue"">机房" & sRoomName & "“" & sRoomNo & "”新增成功！</span>"
	pRoomId = empty		'' 重新置成新增状态
	sRoomName  = ""
	sRoomNo = ""
	sKeyNo = ""
	sLocation = ""
	sFloor = ""
end sub

sub UpdateRoom()
	dim sSQL, iRows
	sRoomName = GetParam("room_name")
	sRoomNo = GetParam("room_no")
	sKeyNo	 = GetParam("key_no")
	sLocation = GetParam("location")
	sFloor = GetParam("floor")

	'' 检查是否存在重复的类别名称
	iRows = DLookUp(conn, "select count(*) from t_room where room_no=" & ToSQL(sRoomNo, "Text") & " and room_id<>" & ToSQL(pRoomId,"Number"))
	if iRows > 0 then
		sInfo = "对不起，机房编号“" & sRoomNo & "”<br>已经存在，请选择其它的编号！"
		'Response.Write _
		'		"<script language=""javascript"">" & vbLF & _
		'		"		alert(""对不起，机房编号“" & sRoomNo & "”已经存在，请选择其它的编号！"");" & vbLF & _
		'		"</script>" & vbLF
		exit sub
	end if
	sSQL = "update t_room" & _
				" set room_name = " & ToSQL(sRoomName, "Text") & _
				", room_no = " & ToSQL(sRoomNo, "Text") & _
				", key_no = " & ToSQL(sKeyNo, "Text") & _
				", location = " & ToSQL(sLocation, "Text") & _
				", floor = " & ToSQL(sFloor, "Text") & _
				" where room_id = " & ToSQL(pRoomId, "Number")
	conn.Execute(sSQL)

	pRoomId = empty		'' 重新置成新增状态
	sRoomName  = ""
	sRoomNo = ""
	sKeyNo = ""
	sLocation = ""
	sFloor = ""
end sub

sub DeleteRoom()
	dim sSQL, iRows

	'' 检查是否存在使用中的类别名称
	iRows = DLookUp(conn, "select count(*) from t_equipment where room_no =" & ToSQL(sRoomNo, "Text"))
	if iRows > 0 then
		sInfo = "对不起，系统中有" & iRows & "个设备存放在编号为<br>“" & sRoomNo & "”机房中，该机房不能删除！"
		'Response.Write _
		'		"<script language=""javascript"">" & vbLF & _
		'		"		alert(""对不起，系统中有" & iRows & "个设备存放在编号为“" & sRoomNo & "”机房中，该机房不能删除！"");" & vbLF & _
		'		"</script>" & vbLF
		exit sub
	end if
	sSQL = "delete from t_room where room_id = " & ToSQL(pRoomId, "Number")
	conn.Execute(sSQL)

	pRoomId = empty		'' 重新置成新增状态
	sRoomName  = ""
	sRoomNo = ""
	sKeyNo = ""
	sLocation = ""
	sFloor = ""
end sub
%>