📄 emp_odl.asp
字号:
<%
'************************************************************************************************
' 文件名: emp_odl.asp
' Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司
'
' 创建人 :魏霖
' 日 期 : 2002-10-29
' 修改历史 :
' ****年**月**日 ****** 修改内容:**************************************************
' 功能描述 : 离职员工信息查询
' 版 本 :
'************************************************************************************************
option explicit
Response.CacheControl = "no-cache"
Response.AddHeader "Pragma", "no-cache"
Response.Expires = -1
%>
<!-- #include file="../include/common.inc" -->
<!-- #include file="../include/recordlist.inc" -->
<!-- #include file="../include/commonpage.inc" -->
<!-- #include file="emp_odl.inc" -->
<%
call CheckSecurity()
'' 如果既不是人事管理员,则进入error页面
dim iRight:iRight=HasRight(ID_HR)
if iRight=1 or iRight=2 then
else
Response.Clear
Response.Redirect "../include/error.asp?error=只有人事管理员或具有人事信息查询权限的人员才能访问人事信息页面&"
Response.End
end if
dim conn :set conn=DBConnection
'********************************************************************************************************
' 服务器端代码
'-------------------------------------------------------------------------------------------------------------------------------------------------
' 分页相关的变量定义
'-------------------------------------------------------------------------------------------------------------------------------------------------
Dim sSQL, sWhere, sOrderby
Dim sFileName : sFileName = "emp_odl.asp"
Dim iTotalRecords : iTotalRecords = 0 ' 分页
Dim iRecordsPerPage : iRecordsPerPage = 12
Dim iTotalPages : iTotalPages = 0
Dim iCols : iCols = 7
Dim iCurrentPage : iCurrentPage = GetParam("Page")
Dim sSorting : sSorting = GetParam("Sorting")
Dim sSorted : sSorted = GetParam("Sorted")
Dim sSortParams : sSortParams = ""
Dim sFormParams : sFormParams = ""
Dim sDirection : sDirection = ""
'-----------------------------------------------------------------------------------------------------'
' 查询参数
'-----------------------------------------------------------------------------------------------------
'' 部门
dim pNode : pNode = GetParam("node")
'' 姓名
dim pName: pName = GetParam("name")
sFormParams = "name=" & pName & "&node=" & pNode & "&"
''********************************************************************************************************
'' 构造分页的SQL语句
''********************************************************************************************************
sSQL = "select t1.emp_id,t1.name,t2.gender_desc as gender,t1.birthday,t1.engage_date,t1.dismiss_date,t3.node_desp as node,t1.pos"&_
" from t_employee t1"&_
" left join t_gender t2 on t1.gender=t2.gender_id"&_
" left join t_node t3 on t1.node_id=t3.node_id"
sWhere=" where t1.dismissed=1"
sOrderby = " order by t1.name"
''********************************************************************************************************
'' 查询条件限制
''********************************************************************************************************
if Not IsEmpty(pNode) then sWhere = sWhere & " and t3.node_desp like " & ToSQL("%" & pNode & "%", "Text")
if Not IsEmpty(pName) then sWhere = sWhere & " and t1.name like " & ToSQL("%" & pName & "%", "Text")
''response.write sSQL & sWhere & sOrderby & "<br>" : response.end
'********************************************************************************************************
' 分页SQL语句构造完毕，调用PrepareListData进行分页前的准备
'-------------------------------------------------------------------------------------------------------------------------------------------------
dim arrayFields(6), sDelimiter
sDelimiter = "*"
arrayFields(0) = "name"
arrayFields(1) = "gender"
arrayFields(2) = "birthday"
arrayFields(3) = "engage_date"
arrayFields(4) = "dismiss_date"
''arrayFields(5) = "node"
arrayFields(5) = "pos"
call PrepareListData(conn,sSQL & sWhere & sOrderby, Join(arrayFields, sDelimiter), sDelimiter)
'********************************************************************************************************
%>
<html>
<head>
<title>上海信息大楼 Shanghai Information Tower</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link rel="stylesheet" href="../include/common.css" type="text/css">
<style type="text/css">
.tdlist {border-width:0px}
.tdHead {border-width:0px}
</style>
<script language="VBScript">
Sub btnSearch_OnClick()
document.all.frmSearch.submit()
End Sub
</script>
</head>
<body bgcolor="#FFFFFF" leftmargin="0" topmargin="0" marginwidth="0" marginheight="0" background="../images/bg/bg0.jpg">
<br>
<%
Response.Write OuterTableHeader
Response.Write HeaderWithMenu
Response.Write InnerTableHeader
'********************************************************************************************************
' 主体从这里开始
'-------------------------------------------------------------------------------------------------------------------------------------------------
Response.Write TableSearch
Response.Write TableHeader
Response.Write TableRecords(sSQL & sWhere & sOrderby, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams )
Response.Write TableLink
'-------------------------------------------------------------------------------------------------------------------------------------------------
' 主体到这里结束
'********************************************************************************************************
Response.Write InnerTableTailer
Response.Write Footer
Response.Write OuterTableTailer
Disconnect(conn)
%>
</body>
</html>
⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -