tree_equi_list.inc

物业管理和办公自动化系统

<%
Function ListTableHeader()
	ListTableHeader = _
		"<table cellspacing=1 cellpadding=3 width=""100%"" border=0 align=center bgcolor=silver style=""table-layout:fixed"">" & vbLF & _
		"<tr style=""display:none"">" & vbLF & _
		"	<td width=100>这一行仅用于控制表格宽度</td>" & vbLF & _
		"	<td width=60></td>" & vbLF & _
		"	<td width=80></td>" & vbLF & _
		"	<td width=80></td>" & vbLF & _
		"	<td width=""*""></td></tr>" & vbLF & _
 
		"<tr><td colspan=" & iCols & " bgcolor=""#0040a0"" align=center style=""color:white;font-weight:600"" height=20 >"&sEquiSysDesc&"("&pEquiSysId&")设备查询列表</td></tr>" & vbLF & _
		"<tr bgcolor=""#eeeeee"">" &  vbLF & _
		"	<td class=tdHead>&nbsp;<img src=""../images/bg/ar-y.gif"" width=8 height=8>&nbsp;" & _
						TableHeaderField(sFileName, "name", "设备名称", sFormParams, sSorting, sSorted) & "</td>" & vbLF & _
		"	<td class=tdHead>&nbsp;" & _
						TableHeaderField(sFileName, "equi_id", "代码", sFormParams, sSorting, sSorted) & "</td>" & vbLF & _
		"	<td class=tdHead>&nbsp;" & _
						TableHeaderField(sFileName, "number", "设备编号", sFormParams, sSorting, sSorted) & "</td>" & vbLF & _
		"	<td class=tdHead>&nbsp;" & _
						TableHeaderField(sFileName, "discarded", "设备状态", sFormParams, sSorting, sSorted) & "</td>" & vbLF & _
		"	<td class=tdHead>&nbsp;" & _
						TableHeaderField(sFileName, "room_no", "机房编号", sFormParams, sSorting, sSorted) & "</td>" & vbLF & _
		"</tr>" & vbLF
End Function

Function ListTableTailer()
	ListTableTailer = "</table>" & vbLF
End Function

Function ListTableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams)
'	response.write sSQL
'	response.end
	dim sTemp	: sTemp = ""	' 临时字符串变量
	dim j					' 临时循环变量

	'------------------------------------
	' 分页所需的变量定义
	'------------------------------------
	Dim iCounter		: iCounter = 1
	Dim iPrevPage, iNextPage
	
	'------------------------------------
	' 获取数据库连接
	'------------------------------------
	dim rs	: set rs = Openrs(conn,sSQL)
	dim iEquiId, sName, sNumber, sModel, sTypeDesc, sRoomno

	' 如果未到记录尾，将记录定位到你翻到的页面的第一个记录，否则显示空行
	if Not rs.EOF then	
		rs.Move (iCurrentPage - 1) * iRecordsPerPage
	end if
	while not rs.EOF and iCounter <= iRecordsPerPage
		iEquiId				= GetValue(rs, "equi_id")
		sName				= GetValue(rs, "name")
		sNumber			= GetValue(rs, "number")
		sModel				= GetValue(rs, "discarded")
		if sModel=0 then
			sModel="在用"
		else 
			sModel="已报废"
		end if
		sRoomno			= GetValue(rs, "room_no")

		sTemp = sTemp & "<tr bgcolor=white>" & vbLF & _
				"	<td title=""" & sName & """ style=""color:blue"">&nbsp;<img src=""../images/bg/ar-g.gif"" width=8 height=8><a target=queryequip.asp href=""etabs.asp?eid=" & iEquiId & """>&nbsp;" & Bref(sName,16) & "&nbsp;</a></td>" & vbLF & _
				"	<td align=center>" & iEquiId & "</td>" & vbLF & _
				"	<td align=center>" & sNumber & "</td>" & vbLF & _
				"	<td align=center>" & sModel & "</td>" & vbLF & _
				"	<td align=center>" & sRoomno & "</td>" & vbLF & _
				"</tr>" & vbLF
		iCounter = iCounter + 1
		rs.movenext
	wend

	' 填补空白行
	sTemp = sTemp & WhiteRows(iCols, iCounter, iRecordsPerPage)

	' 首页、前页、后页、尾页等分页信息
	sTemp = sTemp & "<tr bgcolor=white><td colspan=" & iCols & " align=right>" & vbLF & _
				Paginate(sFileName, sFormParams, sSortParams, iCurrentPage, iTotalPages) & vbLF & _
				"&nbsp;</td></tr>" & vbLF

	ListTableRecords = sTemp
End Function



%>