purchase_mgr.asp

物业管理和办公自动化系统

<%
'##############################################################################
'#
'#		文 件 名	 : purchase_mgr.asp
'#
'#
'#		创 建 人	 : yaoxiaohui
'# 　	日　  期	 : 2002-11-7
'#
'#		修改历史  : ****年**月**日 ******
'#      修改内容  : **************************************************
'#
'#		功能描述	 : 采购单管理
'# 　	版  　本	 : v1.0
'#	
'#	    Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司
'#
'##############################################################################
'------------------------------------------------------------------------------
'----   服务器端设置
'------------------------------------------------------------------------------
option explicit
Response.CacheControl = "no-cache"
Response.AddHeader "Pragma", "no-cache"
Response.Expires = -1
%>
<!-- include files begin -->

<!-- #include file="../include/common.inc" -->
<!-- #include file="../include/recordlist.inc" -->
<!-- #include file="../include/commonpage.inc" -->

<!-- #include file="purchase_mgr.inc" -->

<!-- include files end -->
<%
call CheckSecurity()

if hasright(ID_PURCHASE) < RIGHT_READ  then
	Response.Clear
	Response.Redirect "../include/error.asp?error=只有采购管理员才能进行采购提醒操作！"
	Response.end
end if
'##############################################################################
'----   服务器端代码
'##############################################################################
dim conn
set conn = DBConnection

'******************************************************************************
'----   分页相关的变量定义
'------------------------------------------------------------------------------
Dim sSQL, sWhere, sOrderby ,sWhere1
Dim sFileName			: sFileName			= "purchase_mgr.asp"
Dim iTotalRecords		: iTotalRecords		= 0			                ' 分页
Dim iRecordsPerPage		: iRecordsPerPage	= 10                         ' 一页8行
Dim iTotalPages			: iTotalPages		= 0
Dim iCols				: iCols				= 9                         ' 9列
Dim iCurrentPage		: iCurrentPage		= GetParam("Page")
Dim sSorting			: sSorting			= GetParam("Sorting")
Dim sSorted				: sSorted			= GetParam("Sorted")
Dim sSortParams			: sSortParams		= ""
Dim sFormParams			: sFormParams		= ""
Dim sDirection			: sDirection		= ""
'******************************************************************************
'----   查询参数
'------------------------------------------------------------------------------
''  采购单类别
dim pGoodsType		: pGoodsType = GetParam("goods_type")
if IsEmpty(pGoodsType)		then pGoodsType = -1

'' 申购部门
dim pDepartID    	: pDepartID = GetParam("department")
if IsEmpty(pDepartID)		then pDepartID = -1

'' 采购单类型
dim pIsTemp		  	: pIsTemp = GetParam("is_temporary")
if IsEmpty(pIsTemp)		then pIsTemp = -1

'' 供货商
dim pSupplier	  	: pSupplier = GetParam("supplier")
if IsEmpty(pSupplier)		then pSupplier = -1

'' 采购人
dim pBuyer		  	: pBuyer = GetParam("buyer")

''  申购人
dim pProposer		: pProposer = GetParam("proposer")

'' 采购单状态
dim pSheetStatus	: pSheetStatus = GetParam("sheet_status")
if IsEmpty(pSheetStatus) then 
pSheetStatus = 0
else
select case pSheetStatus
	case "1"
		pSheetStatus	= "新建"
	case "2"
		pSheetStatus	= "完成"
	case "3"
		pSheetStatus	= "入库"
end select
end if

dim pPayMode		: pPayMode = GetParam("pay_mode")
if IsEmpty(pPayMode) then 
pPayMode = 0
else
select case pPayMode
	case "1"
		pPayMode	= "现金"
	case "2"
		pPayMode	= "支票"
	case "3"
		pPayMode	= "转账"
end select
end if
dim pReqPrice		: pReqPrice = GetParam("request_price")

dim pCheque			: pCheque = GetParam("cheque")

dim pDay			: pDay = Getparam("purchase_time")

sFormParams = "goods_type=" & pGoodsType & "&department=" & pDepartID & "&is_temporary=" & pIsTemp & "&supplier=" & pSupplier & "&buyer=" & pBuyer & "&proposer=" & pProposer & "&sheet_status=" & pSheetStatus & "&purchase_time=" & pDay & "&" 
'******************************************************************************
'----   构造分页的SQL语句
'------------------------------------------------------------------------------
sSQL = "select sheet_id,goods_type,is_temporary,supplier,request_price,cheque,pay_mode,purpose" & _
	",department,buyer,proposer,administrator,mgr,purchase_time,sheet_status from t_purchase_master"
sWhere = " where sheet_id = sheet_id"
sOrderby = " order by sheet_id"
'******************************************************************************
'----   查询条件限制
'------------------------------------------------------------------------------
if pBuyer <> "" then sWhere = sWhere & " and buyer like " & ToSQL("%" & pBuyer & "%","Text")

if pProposer <> "" then sWhere = sWhere & " and proposer like " & ToSQL("%" & pProposer & "%","Text")

if pGoodsType > 0 then sWhere = sWhere & " and goods_type=" & ToSQL(pGoodsType,"number")

if pDepartID > 0 then sWhere = sWhere & " and department=" & ToSQL(pDepartID,"number")

if pIsTemp <> "-1" then sWhere = sWhere & " and is_temporary=" & ToSQL(pIsTemp,"number")

if pSupplier > 0 then sWhere = sWhere & " and supplier=" & ToSQL(pSupplier,"number")

if pSheetStatus <> "0" then sWhere = sWhere & " and sheet_status=" & ToSQL(pSheetStatus,"text")

if pPayMode <> "0" then sWhere = sWhere & " and pay_mode=" & ToSQL(pPayMode,"text")

if pReqPrice <> "" then sWhere = sWhere & " and request_price=" & ToSQL(pReqPrice,"text")

if pCheque <> "" then sWhere = sWhere & " and cheque like " & ToSQL("%" & pCheque & "%","Text")

if pDay <> "" then sWhere = sWhere & " and purchase_time =" & ToSQL(pDay,"text")
'******************************************************************************
'----   分页SQL语句构造完毕，调用PrepareListData进行分页前的准备
'------------------------------------------------------------------------------
dim arrayFields(8), sDelimiter
sDelimiter = "*"
arrayFields(0)	=	"sheet_id"
arrayFields(1)	=	"goods_type"
arrayFields(2)	=	"department"
arrayFields(3)	=	"is_temporary"
arrayFields(4)	=	"supplier"
arrayFields(5)	=	"buyer"
arrayFields(6)	=	"proposer"
arrayFields(7)	=	"sheet_status"
arrayFields(8)	=	"purchase_time"
'response.write sSQL & sWhere & sOrderby : response.end
call PrepareListData(conn,sSQL & sWhere & sOrderby, Join(arrayFields, sDelimiter), sDelimiter)
'******************************************************************************
%>

<html>
<head>
<title>上海信息大楼 Shanghai Information Tower</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link rel="stylesheet" href="../include/common.css" type="text/css">

<style type="text/css">
.tdlist		{border-width:0px}
.tdHead	    {border-width:0px}
</style>

<!-- 日历 -->
<IFRAME style="display:none;position:absolute;width:148;height:194;z-index=100" ID="CalFrame" MarginHeight=0 MarginWidth=0 noresize frameborder=0 scrolling=no src="../include/cal/calendar.htm"></IFRAME>
<script language="javascript" src="../include/cal/calendar.js"></script>
<script for=document event="onclick()">
<!--
document.all.CalFrame.style.display="none";
//-->
</script>
<!-- 日历 -->

<script language="javascript">
///////////////////////////////////////////////////////////////////////////////
function btnSearch_OnClick()
{
	frmSearch.submit()
}
///////////////////////////////////////////////////////////////////////////////
</script>

</head>

<body bgcolor="#FFFFFF" leftmargin="0" topmargin="0" marginwidth="0" marginheight="0" background="../images/bg/bg0.jpg">
<br>

<%
Response.Write OuterTableHeader
Response.Write HeaderWithMenu
Response.Write InnerTableHeader
'******************************************************************************
'----   主体从这里开始
'------------------------------------------------------------------------------
Response.Write SheetSearch
Response.Write TableHeader
Response.Write TableRecords(sSQL & sWhere & sOrderby, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams )
Response.Write TableLink
'------------------------------------------------------------------------------
'----   主体到这里结束
'******************************************************************************
Response.Write InnerTableTailer
Response.Write Footer
Response.Write OuterTableTailer
Disconnect(conn)
%>

</body>
</html>