upload.inc

物业管理和办公自动化系统

<% 
Sub BuildUploadRequest(RequestBin) 
	'Get the boundary
	dim Pos, PosBeg, PosEnd, PosFile, PosBound
	dim Name, FileName, ContentType, Value
	dim boundary, boundaryPos
	dim UploadControl

	PosBeg = 1 
	PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(13))) 
	boundary = MidB(RequestBin,PosBeg,PosEnd-PosBeg) 
	boundaryPos = InstrB(1,RequestBin,boundary) 
	'Get all data inside the boundaries 
	Do until (boundaryPos=InstrB(RequestBin,boundary & getByteString("--"))) 
		'Members variable of objects are put in a dictionary object 
		
		Set UploadControl = CreateObject("Scripting.Dictionary") 
		'Get an object name 
		Pos = InstrB(BoundaryPos,RequestBin,getByteString("Content-Disposition")) 
		Pos = InstrB(Pos,RequestBin,getByteString("name=")) 
		PosBeg = Pos+6 
		PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(34))) 
		Name = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg)) 
		PosFile = InstrB(BoundaryPos,RequestBin,getByteString("filename=")) 
		PosBound = InstrB(PosEnd,RequestBin,boundary) 
		'Test if object is of file type 
		If PosFile<>0 AND (PosFile<PosBound) Then 
			'Get Filename, content-type and content of file 
			PosBeg = PosFile + 10 
			PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(34))) 
			FileName = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg)) 
			'response.BinaryWrite "filename in builduploadrequest function:" & getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg)) & "<br>"
			'Add filename to dictionary object 
			UploadControl.Add "FileName", FileName 
			Pos = InstrB(PosEnd,RequestBin,getByteString("Content-Type:")) 
			PosBeg = Pos+14 
			PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(13))) 
			'Add content-type to dictionary object 
			ContentType = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg)) 
			UploadControl.Add "ContentType",ContentType 
			'Get content of object 
			PosBeg = PosEnd+4 
			PosEnd = InstrB(PosBeg,RequestBin,boundary)-2 
			Value = MidB(RequestBin,PosBeg,PosEnd-PosBeg) 
		else 
			'Get content of object 
			Pos = InstrB(Pos,RequestBin,getByteString(chr(13))) 
			PosBeg = Pos+4 
			PosEnd = InstrB(PosBeg,RequestBin,boundary)-2 
			Value = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg)) 
		End If 
		'response.write name & ":" & Value & "<br>"
		'Add content to dictionary object 
		UploadControl.Add "Value" , Value
		'Add dictionary object to main dictionary 
		UploadRequest.Add name, UploadControl
		'Loop to next object 
		BoundaryPos=InstrB(BoundaryPos+LenB(boundary),RequestBin,boundary) 
	Loop 
	'Response.end
End Sub 
%>