common.inc

物业管理和办公自动化系统

'*******************************************************************
' 函数名　: SelectOptions
' 输　入　: conn				---- 数据库连接对象
' 　　　　  sql					---- 查询语句
' 　　　　  ValueField		---- 值字段名
' 　　　　  DisplayField	---- 显示字段名
' 　　　　  DefaultValue  ---- 缺省选中的值
' 输　出　: SelectOptions函数名作为返回值，类型为字符串"<option value='id值'>desp值</option>...."
' 功能描述: 根据限定条件从相应表中选取相应字段值
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-05-09
' 版　本　: 
'*******************************************************************
Function SelectOptions(conn, sql, ValueField, DisplayField, DefaultValue)
	on error resume next

  	dim m_id, m_desp
	dim Res : Res = ""
	dim m_default	: m_default = DefaultValue

	' 循环取数据，放入<option>对
	dim rs				: set rs = conn.execute(sql)
	while not rs.EOF 
		m_id   = GetValue(rs, ValueField)
		m_desp = GetValue(rs, DisplayField)

		' 对取出的每一条记录的值与缺省值比较，相同则选中
		if UCase(CStr(m_id)) = UCase(CStr(m_default)) then
			Res = Res & "<option value=""" & m_id & """ selected>" & m_desp & "</option>"
		else
			Res = Res & "<option value=""" & m_id & """>" & m_desp & "</option>"
		end if

		rs.MoveNext
	wend

	if Res = "" then Res = "<option>(无记录)</option>"
	SelectOptions = Res

	on error goto 0
end function

'*******************************************************************
' 函数名　: DLookUp
' 输　入　: conn		: 数据库连接对象
' 　　　　  sql			: 查询语句
' 输　出　: DLookUp函数名作为返回值，类型为字符串
' 功能描述: 根据限定条件从相应表中选取相应字段值
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-06-07
' 版　本　: 
'*******************************************************************
Function DLookUp(conn, sql)
	'on error resume next
	dim rs, res
	set rs = openrs(conn, sql)
		
	if rs.eof then 
	 	Res=""
	else 
		res = rs.Fields(0).Value
	end if
	CloseRs(rs)
	if IsNull(Res) then Res = ""
	DLookUp = Res
	
	'if err.Description <> "" then DebugStr("Error in function DLookUp: " & err.Description)
	'on error goto 0
End Function

'*******************************************************************
' 函数名　: GetParam(ParamName)
' 输　入　: 参数名
' 输　出　: 参数值
' 功能描述: 获取参数值，先从QueryString中查，然后从Form中查
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-09-15
' 版　本　: 
'*******************************************************************
function GetParam(ParamName)
	dim Param
	if Request.QueryString(ParamName).Count > 0 then 
		Param = Request.QueryString(ParamName)
	elseif Request.Form(ParamName).Count > 0 then
		Param = Request.Form(ParamName)
	else 
		Param = ""
	end if
	if Param = "" then
		GetParam = Empty
	else
		GetParam = Param
	end if
end function

'*******************************************************************
' 函数名　: GetIntParam(ParamName)
' 输　入　: 参数名
' 输　出　: 参数值
' 功能描述: 获取参数值，先从QueryString中查，然后从Form中查，参数值必须为整数或可以转换为整数
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-09-15
' 版　本　: 
'*******************************************************************
function GetIntParam(ParamName)
	dim Param
	Param = GetParam(ParamName)
	if Not IsNumeric(Param) then
		'' 处理出错信息
		exit function
	end if
	if not IsEmpty(Param) then
		GetIntParam = CInt(Param)
	else
		GetIntParam = empty
	end if
end function



' Convert value for use with SQL statament
'-------------------------------
Function ToSQL(Value, sType)
  Dim Param : Param = Value
  
  if Param = "" then
    ToSQL = "Null"
  else
    if LCase(sType) = "number" then
      	ToSQL = replace(CDbl(Param), ",", ".")
    else
      ''response.write "value:"&Value&",type:"&sType
      ''response.end
      	ToSQL = "'" & Replace(Param, "'", "''") & "'"
    end if
  end if
end function


'*******************************************************************
' 函数名　: ToHTML
' 输　入　: sValue ---- 字符串类型的任意值
' 输　出　: ToHTML函数名作为返回值，类型为HTML编码后的字符串
' 功能描述: 将输入参数值转换为HTML编码后返回
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-09-15
' 版　本　: 
'*******************************************************************
Function ToHTML(sValue)
  if IsNull(sValue) then 
    ToHTML = ""
  else
    ToHTML = Server.HTMLEncode(sValue)
  end if
End Function

'*******************************************************************
' 函数名　: ToURL
' 输　入　: sValue ---- 字符串类型的任意值
' 输　出　: ToURL函数名作为返回值，类型为URL编码后的字符串
' 功能描述: 将输入参数值转换为URL编码后返回
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-09-15
' 版　本　: 
'*******************************************************************
Function ToURL(sValue)
  if IsNull(sValue) then sValue = ""
  ToURL = Server.URLEncode(sValue)
End Function


'*******************************************************************
' 函数名　: FormatDT
' 输　入　: dt		---- 日期时间，类型为日期或可转换成日期的字符串
' 　　　　  format	---- 转换格式，类型为字符串
' 输　出　: FormatDT函数名作为返回值，类型为字符串
' 功能描述: 将日期转换成格式字符串
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-09-15
' 版　本　: 
'*******************************************************************
Function FormatDT(dt, format)
	if Not IsDate(dt) then
		FormatDT = ""
		exit function
	end if
	dim y, m, mm, d, dd, h, mi, ss
	dt = CDate(dt)							' dt:    先将参数转换成日期
	y = Year(dt)								' y:     取出年份
	m = Month(dt)							' m:    取出月份
	if m < 10 then mm = "0" & m else mm = m		' mm: 双位月份
	d = Day(dt)								' d: 	  取出日期
	if d < 10 then dd = "0" & d else dd = d			' dd:   双位日期
	h = Hour(dt)								' h:     时
	if h < 10 then h = "0" & h
	mi = Minute(dt)							' mi:   分
	if mi < 10 then mi = "0" & mi
	ss = Second(dt)
	ss = right("00" & ss, 2)
	Select Case format
	case "mm-dd hh:mm"
		FormatDT = mm & "-" & dd & " " & h & ":" & mi
	case "mm-dd hh:mm:ss"
		FormatDT = mm & "-" & dd & " " & h & ":" & mi & ":" & ss
	case "yy-mm-dd hh:mm:ss"
		FormatDT = right(y,2) & "-" & mm & "-" & dd & " " & h & ":" & mi & ":" & ss
	case "yyyy-mm-dd hh:mm"
		FormatDT = y & "-" & mm & "-" & dd & " " & h & ":" & mi
	case "yyyy-mm-dd hh:mm:ss"
		FormatDT = y & "-" & mm & "-" & dd & " " & h & ":" & mi & ":" & ss
	case "yyyy-mm-dd"
		FormatDT = y & "-" & mm & "-" & dd
	case "yyyy年mm月dd日"
		FormatDT = y & "年" & mm & "月" & dd & "日"
	case "yyyy年mm月dd日 h时mi分"
		FormatDT = y & "年" & mm & "月" & dd & "日 " & h & "时" & mi & "分" 
	case else
		'' yyyy-mm-dd
		FormatDT = y & "-" & mm & "-" & dd
	End Select
End Function

'*******************************************************************
' 函数名　: StrLen
' 输　入　: str		---- 字符串
' 输　出　: 整型
' 功能描述: 给定字串，返回该字串的长度，可以区别中英文
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-09-15
' 版　本　: 
'*******************************************************************
function strlen(str)
	dim length, j
	str = trim(str)
	length = len(str)
	dim y : y = 0
	for j = 1 to length
		if asc(mid(str, j, 1)) < 0 or asc(mid(str, j, 1)) > 255 then	'' 如果是汉字
			y= y + 2
		else
			y = y + 1
		end if
	next
	strlen = y
end function

'*******************************************************************
' 函数名　: Bref
' 输　入　: s			---- 要转换的字符串
' 　　　　  lennum	---- 子串的长度
' 输　出　: Bref函数名作为返回值，类型为字符串
' 功能描述: 将给定子串转换成形如 “ ****.... ” 的字符串
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-09-15
' 版　本　: 
'*******************************************************************
function Bref(str, lennum)
	if strlen(str) <= lennum then
		Bref = str
		exit function
	end if
	
	dim p_num	: p_num = 0
	dim x			: x = 0

	do while not p_num > lennum - 2
		x=x+1
		if asc(mid(str,x,1))<0 then
			p_num=int(p_num) + 2
		else
			p_num=int(p_num) + 1
		end if
		Bref = left(trim(str),x) & "..."
	loop
end function


'*******************************************************************
' 函数名　: FormatStr
' 输　入　: str		---- 要格式化的字符串
' 输　出　: 字符串
' 功能描述: 将给定子串中的空格字符和回车字符分别用“&nbsp;”和“<br>”代替，这样可以在td中正确显示
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-10-31
' 版　本　: 
'*******************************************************************
function FormatStr(str)
	FormatStr = Replace(Replace(str,vbCRLF,"<br>"),chr(13),"&nbsp;")
end function

'************************************************************************************************
' 函数名　: ExecuteSP
' 输　入　: db  ----- 指明连接到哪个数据库，整数类型
' 　　　　  sql  ---- 要执行的Stored Procedure，字符串类型
' 输　出　: ExecuteSP函数名作为返回值，即存储过程执行结果，类型为整数
' 功能描述: 执行Stored Procedure，完成相应的功能
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-05-09
' 版　本　: 
'************************************************************************************************
Function ExecuteSP(conn, sql)
		on error resume next

		dim rs, iRtn

		set rs = Conn.Execute(sql)
		iRtn = rs("rtn_code")

		'' 出错信息，如果出错，则显示出错信息，并不继续往下作了
		dim sError	: sError = ProcessError(conn)
		if sError <> "" then 
				'Response.Clear
				Response.Write("调用ExecuteSP函数出错，参考信息如下：<br>" & vbLF & _
						"SQL语句：<span style=""color:blue;font-size:9pt"">" & sql & "</span><br>" & _
						"出错信息：<span style=""color:red;font-size:9pt"">" & sError & "</span><br>" & _
						"解决办法：<span style=""color:blue;font-size:9pt"">请仔细检查SQL语句，可以在SQL查询分析器中测试一下其正确性（确定存储过程返回rtn_code字段）！</span><br>")
				Response.end
		end if

		ExecuteSP = iRtn

		on error goto 0
End Function

'************************************************************************************************
' 函数名　: CheckSecurity
' 输　入　: (无)
' 输　出　: (无)
' 功能描述: 检查用户对所访问的页面的权限
'		首先检查用户是否已经登录，如果未登录，跳转到登录页面
'		*** （现在不检查了）检查该文件是否存在于T_WebFiles表
'		*** （现在不检查了）检查用户对该页是否有访问权限
'		检查用户是否在岗，如果离岗状态，则提示变成在岗状态
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-05-29
' 版　本　: 
'************************************************************************************************