common.inc

物业管理和办公自动化系统

' 函数名　: GetRoleId
' 输　入　: (无)
' 输　出　: 用户角色标识，整型
' 功能描述: 获取当前用户的角色标识
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-05-29
' 版　本　: 
'************************************************************************************************
Function GetRoleId()
	dim sTemp
	sTemp = Session("RoleID")
	
	
	'call DealEmptySessionValue(sTemp)
	GetRoleId = sTemp
End Function


'************************************************************************************************
' 函数名　: SetOnline
' 输　入　: (无)
' 输　出　: (无)
' 功能描述: 用Cookie来保存用户在岗状态为“on”
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-05-29
' 版　本　: 
'************************************************************************************************
Sub SetOnline()
	Session("online") = "on"
	
End Sub

'************************************************************************************************
' 函数名　: SetOffline
' 输　入　: (无)
' 输　出　: (无)
' 功能描述: 用Cookie来保存用户在岗状态为“off”
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-05-29
' 版　本　: 
'************************************************************************************************
Sub SetOffline()
	Session("online") = "off"
	
End Sub

'************************************************************************************************
' 函数名　: GetOnlineStatus
' 输　入　: (无)
' 输　出　: 用户在岗状态“on” 或“off”，字符串类型
' 功能描述: 获取当前用户的在岗状态，“on” 或 “off”
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-05-29
' 版　本　: 
'************************************************************************************************
Function GetOnlineStatus()
	dim sTemp
	sTemp = Session("online")	

	call DealEmptySessionValue(sTemp)
	GetOnlineStatus = sTemp
End Function

'************************************************************************************************
' 函数名　: IsOnline
' 输　入　: (无)
' 输　出　: 用户在岗状态true 或false，布尔类型
' 功能描述: 获取当前用户的在岗状态，在岗返回true，离岗返回false
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-05-29
' 版　本　: 
'************************************************************************************************
Function IsOnline()
	if GetOnlineStatus = "on" then
	
		IsOnline = true
	else
		IsOnline = false
	end if
End Function

'************************************************************************************************
' 函数名　: IsLogin
' 输　入　: (无)
' 输　出　: 用户登录状态true 或false，布尔类型
' 功能描述: 获取当前用户的登录状态，已登录返回true，未登录返回false
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-05-30
' 版　本　: 
'************************************************************************************************
Function IsLogin()
	dim sLoginname
	sLoginname = Session("UserID")
	if sLoginname = "" then
		IsLogin = false
	else
		IsLogin = true
	end if
End Function

'************************************************************************************************
' 函数名　: IsAdministrator
' 输　入　: (无)
' 输　出　: 布尔型 true 或 false
' 功能描述: 当前用户是否是系统管理员，是返回true，否返回false
' 调用模块: 
' 作　者　: 蔡晓燕
' 日　期　: 2002-06-14
' 版　本　: 
'************************************************************************************************
function IsAdministrator()
	if GetUserId = "admin" then
		IsAdministrator = true
	else
		IsAdministrator = false
	end if
end function


'************************************************************************************************
' 函数名　: HasRight(sItem)
' 输　入　: (无)
' 输　出　: 整型，0/1/2：无权/仅读/读写
' 功能描述: 员工相对应的角色对相应的项目的操作权限，分为三种情况
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-08-14
' 版　本　: 
'************************************************************************************************
function HasRight(sItem)
	dim iRight
	dim sSQL,conn1
	
	select case sItem
		case ID_CUSTOMER
			sSQL="select customer_right from t_role where role_id="&ToSQL(GetRoleId, "number")
		case ID_STOCK
			sSQL="select stock_right from t_role where role_id="&ToSQL(GetRoleId, "number")
		case ID_PURCHASE
			sSQL="select purchase_right from t_role where role_id="&ToSQL(GetRoleId, "number")
		case ID_HR
			sSQL="select hr_right from t_role where role_id="&ToSQL(GetRoleId, "number")
		case ID_WORKSHEET
			sSQL="select worksheet_right from t_role where role_id="&ToSQL(GetRoleId, "number")
		case ID_EQUIPMENT
			sSQL="select equipment_right from t_role where role_id="&ToSQL(GetRoleId, "number")	
	case else
	end select    
	
	'response.write sSQL
	'response.end
	
	set conn1=DBConnection
	iRight=DLookUp(conn1, sSQL)
	Disconnect(conn1)
		
	HasRight = iRight
end function

'*******************************************************************
' 函数名　: DBConnection
' 输　入　: (无)
' 输　出　: DBConnection，函数名作为返回值，类型为ADODB.Connection的数据库连接对象
' 功能描述: 获取数据库链接
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-09-15
' 版　本　: 
'*******************************************************************
function DBConnection()
	dim conn : set conn=createobject("adodb.connection")
	conn.open "wuye", "infor", "tower"
	Set DBConnection = conn
end function

'*******************************************************************
' 函数名　: DBConnectionOA
' 输　入　: (无)
' 输　出　: DBConnectionOA，函数名作为返回值，类型为ADODB.Connection的数据库连接对象
' 功能描述: 获取OA数据库链接,用于建立删除t_email记录
' 调用模块: 
' 作　者　: weilin
' 日　期　: 2002-12-23
' 版　本　: 
'*******************************************************************
function DBConnectionOA()
	dim conn : set conn=createobject("adodb.connection")
	conn.open "infortower", "infor", "tower"
	Set DBConnectionOA = conn
end function

'*******************************************************************
' 函数名　: Disconnect
' 输　入　: conn	: 数据库连接对象
' 输　出　: (无)
' 功能描述: 关闭数据库链接
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-06-07
' 版　本　: 
'*******************************************************************
sub Disconnect(conn)
	conn.close
	set conn = nothing
end sub


'*******************************************************************
' 函数名　: ProcessError
' 输　入　: conn	: 数据库连接对象
' 输　出　: 跟数据库有关的出错信息
' 功能描述: 
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-09-15
' 版　本　: 
'*******************************************************************
function ProcessError(conn)
	if conn.Errors.Count > 0 then
		ProcessError = conn.Errors(0).Description & " (" & conn.Errors(0).Source & ")"
	elseif not (Err.Description = "") then
		ProcessError = Err.Description
	else
		ProcessError = ""
	end if
end function

'*******************************************************************
' 函数名　: openrs
' 输　入　: conn	: 数据库连接对象
'		sql	: sql语句
' 输　出　: SQL查询语句返回的数据库记录集Recordset
' 功能描述: 创建forward only recordset
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-06-07
' 版　本　: 
'*******************************************************************
function OpenRs(conn, sql)
	dim r
	set r = Server.CreateObject("ADODB.Recordset")
	r.CursorLocation = adUseServer
	
'	response.write sql
'	response.end
	r.open sql, conn, adOpenForwardOnly, adLockReadOnly, adCmdText
	Set OpenRs = r
end function

'*******************************************************************
' 函数名　: OpenStaticRS
' 输　入　: conn	: 数据库连接对象
'		sql	: sql 语句
' 输　出　: SQL查询语句返回的数据库记录集Recordset
' 功能描述: 创建static only recordset
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-06-07
' 版　本　: 
'*******************************************************************
function OpenStaticRS(conn, sql)
	dim rs
	set rs = Server.CreateObject("ADODB.Recordset")
	rs.CursorLocation = adUseServer
	rs.open sql, conn, adOpenStatic, adLockReadOnly, adCmdText
	set OpenStaticRS = rs
end function

'*******************************************************************
' 函数名　: Close
' 输　入　: rs	: Recordset对象
' 输　出　: (无)
' 功能描述: 关闭数据库记录集
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-06-07
' 版　本　: 
'*******************************************************************
sub CloseRs(rs)
	rs.Close()
	set rs = nothing
end sub


'*******************************************************************
' 函数名　: GetValue
' 输　入　: rs					: Recordset对象
'				sFieldName	: 数据库字段名
' 输　出　: GetValue函数名作为返回值，类型为字符串
' 功能描述: 从Recordset的当前行中获取相应字段的值
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-09-15
' 版　本　: 
'*******************************************************************
function GetValue(rs, sFieldName)
'	on error resume next
	Dim res
	if rs is nothing then
		GetValue = ""
	elseif (not rs.EOF) and (sFieldName <> "") then
		res = rs(sFieldName)
		if isnull(res) then 
			res = ""
		end if
		if VarType(res) = vbBoolean then
			if res then res = "1" else res = "0"
		end if
		GetValue = res
	else
		GetValue = ""
	end if

	'' 出错信息，如果出错，则显示出错信息，并不继续往下作了
	dim sError	: sError = ProcessError(conn)
	if sError <> "" then 
			'Response.Clear
			Response.Write("调用GetValue函数出错，参考信息如下：<br>" & vbLF & _
					"SQL语句：<span style=""color:blue;font-size:9pt"">" & m_sql & "</span><br>" & _
					"出错信息：<span style=""color:red;font-size:9pt"">" & sError & "</span><br>" & _
					"解决办法：<span style=""color:blue;font-size:9pt"">请仔细检查字段名是否正确，是否与查询语句中的一致！</span><br>")
			Response.end
	end if

'	on error goto 0
end function

'*******************************************************************
' 函数名　: GetValueHTML
' 输　入　: rs			: Recordset对象
'		sFieldName	: 数据库字段名
' 输　出　: GetValueHTML函数名作为返回值，类型为字符串
' 功能描述: 从Recordset的当前行中获取相应字段的值，以HTML编码形式返回
' 调用模块: 
' 作　者　: 周秋舫
' 日　期　: 2002-09-15
' 版　本　: 
'*******************************************************************
function GetValueHTML(rs, sFieldName)
	GetValueHTML = ToHTML(GetValue(rs, sFieldName))
end function