list_complaint.inc

物业管理和办公自动化系统

<%
Function ifSelected(i1,i2)
	if CStr(i1)=CStr(i2) then
		ifSelected="selected"
	else
	        ifSelected=""
	end if
End Function

Function TableSearch()
	dim sTemp			

	TableSearch = _
		TableTitle("设 置 客 户 意 见 查 询 条 件", 600, "", "") & vbLF & _
		"<table cellspacing=0 cellpadding=3 width=600 align=center border=0>" & vbLF & _
		"<form name=""frmSearch"" method=post action=""list_complaint.asp"">" & vbLF  & _
		"<tr height=30 bgcolor=white>" & vbLF & _
		"	<td>&nbsp;客户名称：<input type=""text"" name=""customername"" value=""" & pCustomername & """ size=10 maxlength=10>" & vbLF & _
 		"	<td>&nbsp;投诉人：<input type=""text"" name=""complaint"" value=""" & pComplaint & """ size=10 maxlength=12>" & vbLF & _
		"	<td>&nbsp;负责人：<input type=""text"" name=""chief"" value=""" & pChief & """ size=10 maxlength=12>" & vbLF & _
		"	<td>&nbsp;已生成工作单：" & vbLF & _
		"			<select name=""ifworksheet"">" & vbLF & _
		"					<option value=0 "&ifSelected(0,pIfworksheet)&"></option>" & vbLF & _
		"					<option value=2 "&ifSelected(2,pIfworksheet)&">是</option>" & vbLF & _
		"					<option value=1 "&ifSelected(1,pIfworksheet)&">否</option>" & vbLF & _					
		"			</select></td>"& vbLF & _						
		"	<td><span id=btnSearch style=""cursor:hand"" title=""设置查询条件，然后点击查询按钮进行查询""><img border=0 src=""../images/search.gif"" style=""vertical-align:middle"">查询</span></td></tr>" & vbLF & _
		"<tr height=10 bgcolor=white><td colspan=5></td></tr>" & vbLF & _
		"</form>" & vbLF & _
		"</table>" & vbLF
End Function

Function TableHeader()
	TableHeader = _
		"<table cellspacing=1 cellpadding=3 width=600 align=center bgcolor=silver style=""table-layout:fixed"">" & vbLF & _
		"<tr style=""display:none"">" & vbLF & _
		"	<td width=220>这一行仅用于控制表格的宽度</td>" & vbLF & _
		"	<td width=80></td>" & vbLF & _
		"	<td width=100></td>" & vbLF & _
		"	<td width=100></td>" & vbLF & _		
		"	<td width=""*""></td></tr>" & vbLF & _
		"<tr height=20>" & _
		"<td colspan=" & iCols & " bgcolor=""#0040a0"" align=center style=""color:white;font-weight:600"">客 户 意 见 查 询 结 果</td></tr>" & _
		"<tr bgcolor=white>" & _
		"<td class=tdHead align=center>&nbsp;<img src=""../images/bg/ar-y.gif"" width=15 height=8>&nbsp;" & TableHeaderField(sFileName, "customer_name", "客户名称", sFormParams, sSorting, sSorted) & "</td>" & _
		"<td class=tdHead align=center>&nbsp;客户意见号</td>" & _				
		"<td class=tdHead align=center>&nbsp;" & TableHeaderField(sFileName, "complaint", "投诉人", sFormParams, sSorting, sSorted) & "</td>" & _
		"<td class=tdHead align=center>&nbsp;" & TableHeaderField(sFileName, "chief", "负责人", sFormParams, sSorting, sSorted) & "</td>" & _
		"<td class=tdHead align=center>&nbsp;已生成工作单</td>" & _
		"</tr>"
End Function

Function TableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams)
	dim sTemp	: sTemp = ""	' 临时字符串变量
	dim j					' 临时循环变量

	'------------------------------------
	' 分页所需的变量定义
	'------------------------------------
	Dim iCounter		: iCounter = 1
	Dim iPrevPage, iNextPage
	
	'------------------------------------
	' 获取数据库连接
	'------------------------------------	
	dim rs	: set rs = openRS(conn,sSQL)
	dim iComplaintId, sCustomername,sComplaint,sChief,iWorksheetid,sIfworksheet
	''response.write sSQL : response.end
	' 如果未到记录尾，将记录定位到你翻到的页面的第一个记录，否则显示空行
	if Not rs.EOF then	
		rs.Move (iCurrentPage - 1) * iRecordsPerPage
	end if
	while not rs.EOF and iCounter <= iRecordsPerPage
		iComplaintId			= GetValue(rs,"complaint_id")
		sCustomername				= GetValue(rs,"customer_name")
		sComplaint			= GetValue(rs,"complaint")
		sChief		= GetValue(rs,"chief")		
		iWorksheetid				= GetValue(rs,"worksheet_id")
		
		if iWorksheetid="" then
                    sIfworksheet="否"
                else
                    sIfworksheet="是"
		end if
		
		sTemp = sTemp & "<tr bgcolor=white height=20>" & _
				"<td title=""点击可以察看“" & sCustomername & "”客户的客户意见的信息"" style=""cursor:hand;color:blue;"" onclick=""javascript:location.href='newcomplaint.asp?complaintid=" & iComplaintId & "';"" nowrap>&nbsp;<img src=""../images/bg/ar-g.gif"" width=8 height=8>&nbsp;" & sCustomername & "&nbsp;</td>" & _				
				"<td align=center title=""" & iComplaintId & """ nowrap>&nbsp;" & iComplaintId & "&nbsp;</td>" & _
				"<td align=center title=""" & sComplaint & """ nowrap>&nbsp;" & sComplaint & "&nbsp;</td>" & _
				"<td align=center title=""" & sChief & """ nowrap>&nbsp;" & sChief & "&nbsp;</td>" & _
				"<td align=center title=""" & sIfworksheet & """ nowrap>&nbsp;" & sIfworksheet & "&nbsp;</td>" & _
				"</tr>"
		iCounter = iCounter + 1
		rs.movenext
	wend
	CloseRS(rs)

	' 填补空白行
	sTemp = sTemp & WhiteRows(iCols, iCounter, iRecordsPerPage)

	' 首页、前页、后页、尾页等分页信息
	sTemp = sTemp & "<tr bgcolor=white height=20><td colspan=" & iCols & " align=right>" & _
				Paginate(sFileName, sFormParams, sSortParams, iCurrentPage, iTotalPages) & _
				"&nbsp;</td></tr>"
	TableRecords = sTemp
End Function


Function TableLink()
	dim sTemp : sTemp = ""
	
	if iRight=2 then
		sTemp = _
		"		<img src=""../images/goto.gif"">&nbsp;<a href=""newcomplaint.asp"">新增客户意见</a>" & vbLF & _
		"		&nbsp;&nbsp;&nbsp;" 
	end if
		
	TableLink = _
		"<table width=600 cellspacing=0 cellpadding=0 border=0 align=center>" & vbLF & _
		"<tr height=10>" & vbLF & _ 
		"	<td width=600><img src=""../images/bg/line.gif"" width=600 height=3></td>" & vbLF & _
		"</tr>" & vbLF & _
		"<tr>" & vbLF & _
		"	<td width=600>&nbsp;" & vbLF & _
		sTemp & vbLF & _
		"</tr>" & vbLF & _
		"</table>" & vbLF
End Function
%>