list_worksheet.asp

物业管理和办公自动化系统

<%
'************************************************************************************************
' 文件名: list_worksheet.asp
' Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司
'
' 　创建人 : 魏霖
' 　日　期 : 2002-11-19
' 修改历史 :
'   ****年**月**日 ****** 修改内容:**************************************************
' 功能描述 : 
' 　版　本 :
'************************************************************************************************
option explicit
Response.CacheControl = "no-cache"
Response.AddHeader "Pragma", "no-cache"
Response.Expires = -1

%>
<!-- #include file="../include/common.inc" -->
<!-- #include file="../include/recordlist.inc" -->
<!-- #include file="../include/commonpage.inc" -->
<!-- #include file="list_worksheet.inc" -->

<%
call CheckSecurity()

dim iRight:iRight=HasRight(ID_WORKSHEET)


if iRight=1 or iRight=2 then
else
	Response.Clear
	Response.Redirect "../include/error.asp?error=只有工单管理员或具有工单信息查询权限的人员才能访问该页面&"
	Response.End
end if

dim conn :set conn=DBConnection

'********************************************************************************************************
' 服务器端代码

'-------------------------------------------------------------------------------------------------------------------------------------------------
' 分页相关的变量定义
'-------------------------------------------------------------------------------------------------------------------------------------------------
Dim sSQL, sWhere, sOrderby
Dim sFileName			: sFileName = "list_worksheet.asp"
Dim iTotalRecords		: iTotalRecords = 0			' 分页
Dim iRecordsPerPage	: iRecordsPerPage = 12
Dim iTotalPages			: iTotalPages = 0
Dim iCols					: iCols = 8
Dim iCurrentPage		: iCurrentPage = GetParam("Page")
Dim sSorting					: sSorting = GetParam("Sorting")
Dim sSorted				: sSorted = GetParam("Sorted")
Dim sSortParams		: sSortParams = ""
Dim sFormParams		: sFormParams = ""
Dim sDirection			: sDirection = ""

'-----------------------------------------------------------------------------------------------------'
' 查询参数
'-----------------------------------------------------------------------------------------------------

dim pDay1		: pDay1 = GetParam("pDay1")
dim pDay2		: pDay2 = GetParam("pDay2")
dim pObjecttype		: pObjecttype = GetParam("pobjecttype")
dim pObjectname         :pObjectname=GetParam("pObjectname")
dim pFinished 		:pFinished=GetParam("pfinished")
dim pFormtype           :pFormtype=GetParam("pformtype")
dim pUrgency            :pUrgency=GetParam("purgency")
dim pDepartment         :pDepartment=GetParam("pdepartment")




if IsEmpty(pDay1) or IsEmpty(pDay2) then 
	pDay1=year(date)&"-"&month(date)&"-1"
        pDay2=date
end if

if IsEmpty(pObjecttype) then 
	pObjecttype=-1
	pObjectname=""
end if

if IsEmpty(pFinished) then pFinished=0

if IsEmpty(pFormtype) then pFormtype=-1

if IsEmpty(pUrgency) then pUrgency=-1

if IsEmpty(pDepartment) then pDepartment=-1
 
''response.write pDay1&","&pDay2&","&pObjecttype&","&pObjectname&","&pFinished&","&pFormtype&","&pUrgency&","&pDepartment
''response.end

''sFormParams = "name=" & pName & "person="&pPerson&"&"
''********************************************************************************************************
'' 构造分页的SQL语句
''********************************************************************************************************

sSQL = "select * from t_worksheet"
		
''sOrderby = " order by name"

''********************************************************************************************************
'' 查询条件限制
''********************************************************************************************************

   sWhere=" where starttime>='"&pDay1&"' and starttime<'"&DateAdd("d", 1, pDay2)&"'"
  
  if pFinished>=0 then  sWhere=sWhere&" and finished="&ToSQL(pFinished,"number")
  
  if pFormtype>=0 then sWhere=sWhere&" and form_type="&ToSQL(pFormtype,"number")
  
  if pUrgency>=0 then sWhere=sWhere&" and urgency="&ToSQL(pUrgency,"number")
  
  if pDepartment>=0 then sWhere=sWhere&" and department="&ToSQL(pDepartment,"number")
  
  if pObjecttype=0 then
      sWhere=sWhere&" and equi_sys_id in (select sys_id from t_sys where sys_desc like "& ToSQL("%" & pObjectname & "%","Text")&") and object_type=0"
  end if
  if pObjecttype=1 then
      sWhere=sWhere&" and equi_sys_id in (select equi_id from t_equipment where name like "& ToSQL("%" & pObjectname & "%","Text")&") and object_type=1"
  end if     

''response.write sSQL & sWhere & sOrderby & "<br>" : response.end
'********************************************************************************************************
' 分页SQL语句构造完毕，调用PrepareListData进行分页前的准备
'-------------------------------------------------------------------------------------------------------------------------------------------------
dim arrayFields(8), sDelimiter
sDelimiter = "*"
arrayFields(0) = "object_type,equi_sys_id"
arrayFields(1) = "department"
arrayFields(2) = "starttime"
arrayFields(3) = "limit_days"

call PrepareListData(conn,sSQL & sWhere & sOrderby, Join(arrayFields, sDelimiter), sDelimiter)
'********************************************************************************************************
%>

<html>
<head>
<title>上海信息大楼 Shanghai Information Tower</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link rel="stylesheet" href="../include/common.css" type="text/css">
<style type="text/css">
.tdlist		{border-width:0px}
.tdHead	{border-width:0px}
</style>
<IFRAME style="display:none;position:absolute;width:148;height:194;z-index=100" ID="CalFrame" MarginHeight=0 MarginWidth=0 noresize frameborder=0 scrolling=no src="../include/cal/calendar.htm"></IFRAME>
<script language="javascript" src="../include/cal/calendar.js"></script>
<script for=document event="onclick()">
<!--
document.all.CalFrame.style.display="none";
//-->
</script>
<script language="VBScript">
Sub btnSearch_OnClick()

	document.all.frmSearch.submit()
End Sub


</script>
</head>

<body bgcolor="#FFFFFF" leftmargin="0" topmargin="0" marginwidth="0" marginheight="0" background="../images/bg/bg0.jpg">
<br>

<%
Response.Write OuterTableHeader
Response.Write HeaderWithMenu
Response.Write InnerTableHeader
'********************************************************************************************************
' 主体从这里开始
'-------------------------------------------------------------------------------------------------------------------------------------------------

Response.Write TableSearch

Response.Write TableHeader


Response.Write TableRecords(sSQL & sWhere & sOrderby, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams )

Response.Write TableLink
'-------------------------------------------------------------------------------------------------------------------------------------------------
' 主体到这里结束
'********************************************************************************************************
Response.Write InnerTableTailer
Response.Write Footer
Response.Write OuterTableTailer

Disconnect(conn)
%>

</body>
</html>