userfunction.bas

教学资源管理系统

Attribute VB_Name = "mduUserFunction"
Public Function PlayMidiFile(ByVal FileName As String, Optional ByVal Alias As String = "MyMid") As Boolean
    Dim nRet As Long
    Dim S As String, ShortPathName As String
    
    S = String(LenB(FileName), Chr(0))
    GetShortPathName FileName, S, Len(S)
    ShortPathName = Left(S, InStr(S, Chr(0)) - 1)

    Call StopMidiFile(Alias)
    If mciSendString("open " & ShortPathName & " alias " & Alias, vbNullString, 0, 0) = 0 Then
        nRet = mciSendString("play " & Alias & " from 0", vbNullString, 0, 0)
        PlayMidiFile = (nRet = 0)
    End If
End Function

Public Sub StopMidiFile(Optional ByVal Alias As String = "MyMid")
    Call mciSendString("stop " & Alias, vbNullString, 0, 0)
    Call mciSendString("close " & Alias, vbNullString, 0, 0)
End Sub

Public Function IsFileExists(ByVal strFileFullName As String) As Boolean
    Dim Win_Find As WIN32_FIND_DATA
    Dim hFile As Long
    IsFileExists = False
    If Right(strFileFullName, 1) = "\" Then strFileFullName = Left(strFileFullName, Len(strFileFullName) - 1)
    hFile = FindFirstFile(strFileFullName, Win_Find)
    If hFile <> -1 Then
        FindClose hFile
        IsFileExists = True
    End If
End Function
Public Function FileDir(ByVal strFileFullName As String) As String
    Dim i As Integer
    i = 0
    While Mid(strFileFullName, Len(strFileFullName) - i, 1) <> "\"
        i = i + 1
    Wend
    FileDir = Left(strFileFullName, Len(strFileFullName) - i)
End Function