bios32.asm

来自「高速同步串口芯片PEB20534的驱动程序」· 汇编 代码 · 共 71 行

;---------------------------------------------------------------
; Assembler code to perform 32bit BIOS access in 16bit mode
;---------------------------------------------------------------

		.MODEL		MEDIUM, C
.CODE
.386
;---------------------------------------------------------------
;
;   Does PCI bios interrupt 0x1a. Can return 32 bit values
;
;   Entry:
;       DWordRegs *inregs, DWordRegs *outregs
;       (pointers to reg. structures)
;
;   Exit:
;       None.
;
;---------------------------------------------------------------
PUBLIC  Bios32
Bios32	PROC	FAR

	push	bp
	mov	bp, sp
	push	si
	push	di
	push	es
	push	ds

	pushf					; Disable interrupts
	cli

	mov	di, WORD PTR [bp+06h]		; Address of inregs
	mov	eax, DWORD PTR ds:[di]
	mov	ebx, DWORD PTR ds:[di+04h]
	mov	ecx, DWORD PTR ds:[di+08h]
	mov	edx, DWORD PTR ds:[di+0ch]
	mov	si, WORD PTR ds:[di+010h]
	mov	di, WORD PTR ds:[di+012h]

	int	1ah				; BIOS call

	push	di	
	mov	di, WORD PTR [bp+08h]		; Address of outregs
	mov	DWORD PTR ds:[di], eax
	mov	DWORD PTR ds:[di+04h], ebx
	mov	DWORD PTR ds:[di+08h], ecx
	mov	DWORD PTR ds:[di+0ch], edx
	mov	WORD PTR ds:[di+010h], si
	pop	WORD PTR ds:[di+012h]		; Pop DI back off the stack
	
	mov	si, 0				; Save carry flag state
	jnc	cfok
	mov	si, 1
cfok:
	mov	WORD PTR ds:[di+14h], si
	
	popf					; Re-enable interrupts

	pop	ds				; Restore registers
	pop	es
	pop	di
	pop	si
	pop	bp
	
	retf

Bios32	ENDP

	END