e_powf.s

Glibc 2.3.2源代码(解压后有100多M)

}
{ .mfb
          nop.m 999
(p13)     fma.s f8                           = f8,f1,f0
(p13)     br.ret.spnt  b0    // Exit if x nan, y anything but zero
}
;;
          
// p10 = TRUE ==> X is zero  AND Y is positive
//  p8  = TRUE ==> X is zero  AND Y is outside integer range (treat as even int)
//                   return +0
//  p9  = TRUE ==> X is zero  AND Y is within integer range (may not be integer) 
{ .mfi
(p10)     cmp.gt.unc p8,p9                  =  pow_GR_exp_Y, pow_GR_10033
(p6)      fmerge.s POW_delta                 = f0,f0
          nop.i 999
}
{ .mfi
          nop.m 999
(p6)      fma.s1 POW_G                       = f0,f0,f0
          nop.i 999
}
;;

{ .mfi
          getf.sig pow_GR_sig_int_Y         = POW_int_Y
          fnma.s1 POW_twoV                   = POW_NORM_Y, POW_rsq,f0
          nop.i 999
}
{ .mfi
          nop.m 999
          fma.s1 POW_U                      = POW_NORM_Y,POW_r,f0
          nop.i 999
}
;;

{ .mfi
          ldfe      POW_log2_by_128_lo      = [pow_AD_P], 16
(p6)      fma.s1 POW_v2                     = POW_P1, POW_r1, POW_P0 
          nop.i 999
}
{ .mfi
          ldfe          POW_log2_by_128_hi  = [pow_AD_Q], 16
(p7)      fma.s1 POW_v2                     = POW_P1, POW_r,  POW_P0 
          nop.i 999
}
;;


{ .mfi
          nop.m 999
          fcvt.xf   POW_float_int_Y               = POW_int_Y
          nop.i 999
}
{ .mfi
          nop.m 999
          fma.s1 POW_v3                     = POW_v6, POW_rsq,  POW_v4 
          adds          pow_AD_tbl1       = pow_tbl1 - pow_Tt,  pow_AD_Q
}
;;

{ .mfi
          nop.m 999
(p7)      fma.s1 POW_delta                  = POW_K, POW_log2_lo, POW_Tt
          nop.i 999
}
{ .mfi
          nop.m 999
(p7)      fma.s1 POW_G                      = POW_K, POW_log2_hi, POW_T 
          adds pow_AD_tbl2                  = pow_tbl2 - pow_tbl1,  pow_AD_tbl1
}
;;


{ .mfi
          nop.m 999
          fms.s1 POW_e2                     = POW_NORM_Y, POW_r, POW_U
          nop.i 999
}
{ .mfi
          nop.m 999
          fma.s1 POW_Z2                     = POW_twoV, POW_Q0_half, POW_U
          nop.i 999
}
;;

// p11 = TRUE ==> X is NEGATIVE 
// p8  = TRUE ==> X is zero  AND Y is outside intger range (treat as even int)
//                return +0
{ .mfi
          nop.m 999
          fclass.m.unc  p11,p0              = f8, 0x1a
          nop.i 999
}
{ .mfb
          nop.m 999
(p8)      fma.s f8                          = f0,f0,f0
(p8)      br.ret.spnt b0
}
;;

{ .mfi 
          nop.m 999
          fma.s1 POW_Yrcub                 = POW_rsq, POW_U, f0
          nop.i 999
}
{ .mfi 
          nop.m 999
          fma.s1 POW_p                      = POW_rsq, POW_v3, POW_v2
          nop.i 999
}
;;


// p11 = TRUE ==> X is NEGATIVE
//    p12 = TRUE ==> X is NEGATIVE  AND  Y  already int
//    p13 = TRUE ==> X is NEGATIVE  AND  Y possible int
{ .mfi
          nop.m 999
          fma.s1 POW_Z1                     = POW_NORM_Y, POW_G, f0
(p11)     cmp.ge.unc  p12,p13                = pow_GR_exp_Y, pow_GR_10033
}
{ .mfi
          nop.m 999
          fma.s1 POW_e3                     = POW_NORM_Y, POW_delta, f0
          nop.i 999
}
;;

// p9  = TRUE ==> X is zero  AND Y is within integer range (may not be integer)
//    p6 = TRUE ==>  X is zero  AND  Y is an integer (may be even or odd)
//    p7 = TRUE ==>  X is zero  AND  Y is NOT an integer, return +0
{ .mfi
          nop.m 999
(p9)      fcmp.eq.unc.s1 p6,p7             = POW_float_int_Y,  POW_NORM_Y
          nop.i 999
}
{ .mfi 
          nop.m 999
          fma.s1 POW_Gpr                    = POW_G, f1, POW_r
          nop.i 999
}
;;

// By adding RSHF (1.1000...*2^63) we put integer part in rightmost significand
{ .mfi
          nop.m 999
          fma.s1 POW_W2  = POW_Z2, POW_inv_log2_by_128, POW_RSHF
          nop.i 999
}
{ .mfi
          nop.m 999
          fms.s1 POW_UmZ2                   = POW_U, f1, POW_Z2
          nop.i 999
}
;;


// If x=0 and y>0, test y and flag denormal
// p6  = TRUE ==>  X is zero  AND  Y is an integer (may be even or odd)
//    p8 = TRUE ==>  X is zero  AND  Y is an odd  integer
//    p9 = TRUE ==>  X is zero  AND  Y is an even integer
{ .mfi
          nop.m 999
(p10)     fcmp.eq.s0 p15,p0 = f9,f0
(p6)      tbit.nz.unc  p8,p9                = pow_GR_sig_int_Y,0
}
{ .mfi
          nop.m 999
          fma.s1 POW_Z3                      = POW_p, POW_Yrcub, f0
          nop.i 999
}
;;

// By adding RSHF (1.1000...*2^63) we put integer part in rightmost significand
{ .mfi
          nop.m 999
          fms.s1 POW_e1                     = POW_NORM_Y, POW_G, POW_Z1
          nop.i 999
}
{ .mfi
          nop.m 999
          fma.s1 POW_W1  = POW_Z1, POW_inv_log2_by_128, POW_RSHF
          nop.i 999
}
;;

{ .mfi
          nop.m 999
(p7)      fma.s f8  = f0,f0,f0  // Result +0 if x zero and y not integer
          nop.i 999
}
{ .mfb
          nop.m 999
          fma.s1 POW_Y_Gpr                  = POW_NORM_Y, POW_Gpr, f0
(p8)      br.ret.spnt b0        // Exit if x zero and y odd integer
}
;;

// By subtracting RSHF we get rounded integer POW_N2float
// p15 = TRUE ==> X_0_Y_NEG
{ .mfi
          nop.m 999
          fms.s1 POW_N2float  = POW_W2, f1, POW_RSHF
          nop.i 999
}
{ .mfb
          nop.m 999
          fma.s1 POW_UmZ2pV                 = POW_twoV,POW_Q0_half,POW_UmZ2
(p15)     br.cond.spnt L(POW_X_0_Y_NEG)
}
;;



{ .mfi
          nop.m 999
          fma.s1 POW_Z3sq                   = POW_Z3, POW_Z3, f0
          nop.i 999
}
{ .mfb
          nop.m 999
          fma.s1 POW_v4                     = POW_Z3, POW_Q3, POW_Q2
(p7)      br.ret.spnt b0     // Exit if x zero and y not an integer
}
;;



// Extract rounded integer from rightmost significand of POW_W2
// By subtracting RSHF we get rounded integer POW_N1float
{ .mfi
          getf.sig pow_GR_int_W2             = POW_W2
          fms.s1 POW_N1float  = POW_W1, f1, POW_RSHF
          nop.i 999
}
{ .mfi
          nop.m 999
          fma.s1 POW_v2                     = POW_Z3, POW_Q1, POW_Q0_half
          nop.i 999
}
;;




// p13 = TRUE ==> X is NEGATIVE  AND  Y possible int
//     p10 = TRUE ==> X is NEG and Y is an int
//     p12 = TRUE ==> X is NEG and Y is not an int
{ .mfi
          nop.m 999
(p13)     fcmp.eq.unc.s1 p10,p12             = POW_float_int_Y,  POW_NORM_Y
          nop.i 999
}
{ .mfb
          nop.m 999
(p9)      fma.s f8  = f0,f0,f0   // Result +0 if x zero and y even integer
(p9)      br.ret.spnt b0    // Exit if x zero and y even integer
}
;;


{ .mfi
          nop.m 999
          fnma.s1 POW_s2 = POW_N2float, POW_log2_by_128_hi, POW_Z2
          nop.i 999
}
{ .mfi
          nop.m 999
          fma.s1 POW_e2                     = POW_e2,f1,POW_UmZ2pV
          nop.i 999
}
;;

// Extract rounded integer from rightmost significand of POW_W1
// Test if x inf
{ .mfi
          getf.sig pow_GR_int_W1             = POW_W1
          fclass.m.unc p15,p0 = POW_NORM_X,  0x23
          nop.i 999
}
{ .mfb
          nop.m 999
          fnma.s1 POW_f2  = POW_N2float, POW_log2_by_128_lo, f1
(p12)     br.cond.spnt L(POW_X_NEG_Y_NONINT)  // Branch if x neg, y not integer
}
;;

// p12 = TRUE ==> X is NEGATIVE  AND Y is an odd integer
{ .mfi
          getf.exp pow_GR_signexp_Y_Gpr       = POW_Y_Gpr
          fma.s1 POW_v3                     = POW_Z3sq, POW_Q4, POW_v4
(p10)     tbit.nz.unc  p12,p0                = pow_GR_sig_int_Y,0
}
;;


{ .mfi
          add pow_GR_int_N                   = pow_GR_int_W1, pow_GR_int_W2
          fnma.s1 POW_f1  = POW_N1float, POW_log2_by_128_lo, f1
          nop.i 999
}
{ .mfb
          nop.m 999
          fnma.s1 POW_s1  = POW_N1float, POW_log2_by_128_hi, POW_Z1
(p15)     br.cond.spnt L(POW_X_INF)
}
;;


// Test x and y and flag denormal
{ .mfi
          and pow_GR_index1                  = 0x0f, pow_GR_int_N
          fcmp.eq.s0 p15,p0 = f8,f9
          shr r2                             = pow_GR_int_N, 7
}
{ .mfi
          and pow_GR_exp_Y_Gpr               = pow_GR_signexp_Y_Gpr, pow_GR_17ones
          nop.f 999
          and pow_GR_index2                  = 0x70, pow_GR_int_N
}
;;



{ .mfi
          shladd pow_AD_T1                   = pow_GR_index1, 4, pow_AD_tbl1
          fcmp.eq.s1 p7,p0 = POW_NORM_Y, f1  // Test for y=1.0
          sub pow_GR_true_exp_Y_Gpr          = pow_GR_exp_Y_Gpr, pow_GR_16ones
}
{ .mfi
          addl pow_int_GR_M                  = 0xFFFF, r2
          fma.s1  POW_e12                     = POW_e1,f1,POW_e2
          add pow_AD_T2                      = pow_AD_tbl2, pow_GR_index2
}
;;


{ .mmi
          ldfe POW_T1                        = [pow_AD_T1],16
          setf.exp POW_2M                    = pow_int_GR_M
          andcm pow_GR_sign_Y_Gpr            = pow_GR_signexp_Y_Gpr, pow_GR_17ones
}
;;


{ .mfb
          ldfe POW_T2                        = [pow_AD_T2],16
          fma.s1 POW_q                       = POW_Z3sq, POW_v3, POW_v2
(p7)      br.ret.spnt b0        // Early exit if y=1.0, result is x
}
;;


// double: p8 TRUE ==> |Y(G + r)| >= 10
// single: p8 TRUE ==> |Y(G + r)| >= 7

// double
//     -2^10  -2^9             2^9   2^10
// -----+-----+----+ ... +-----+-----+-----
//  p8  |             p9             |  p8
//      |     |       p10      |     |  
// single
//     -2^7   -2^6             2^6   2^7
// -----+-----+----+ ... +-----+-----+-----
//  p8  |             p9             |  p8
//      |     |       p10      |     |


{ .mfi
(p0)      cmp.le.unc p8,p9                   = 7, pow_GR_true_exp_Y_Gpr
          fma.s1 POW_s                       = POW_s1, f1, POW_s2