markfile

一个朋友写的操作系统源码

00537   _copr_not_available:
00538           push 0                        ! padding for error code 
00539           push COPROC_NOT_VECTOR
00540           jmp trap
00541   
00542   _double_fault:
00543           push DOUBLE_FAULT_VECTOR
00544           jmp trap
00545   
00546   _copr_seg_overrun:
00547           push 0                        ! padding for error code 
00548           push COPROC_SEG_VECTOR
00549           jmp trap
00550   
00551   _inval_tss:
00552           push INVAL_TSS_VECTOR
00553           jmp trap
00554   
00555   _segment_not_present:
00556           push SEG_NOT_VECTOR
00557           jmp trap
00558   
00559   _stack_exception:
00560           push STACK_FAULT_VECTOR
00561           jmp trap
00562   
00563   _general_protection:
00564           push PROTECTION_VECTOR
00565           jmp trap
00566   
00567   _page_fault:
00568           push PAGE_FAULT_VECTOR
00569           jmp trap
00570   
00571   _copr_error:
00572           push 0                        ! padding for error code 
00573           push COPROC_ERR_VECTOR
00574           jmp trap
00575   
00576   !*===========================================================================*
00577   !*                        system call                                        *
00578   !*===========================================================================*
00579   ! It shares the same interface with exception
00580   
00581   _s_call:
00582          push 0
00583          push SYS386_VECTOR
00584          jmp trap
00585   
00586   !*===========================================================================*
00587   !*                           trap                                            *
00588   !*===========================================================================*
00589   ! Called from all exceptions, no matter it has pushed an error code or not.
00590   ! Remember to pop the error code from stack before execute iretd instruction
00591   ! because iretd won't pop it.
00592     
00593           .align 16
00594   trap:
00595           cld                     ! set direction flag to a know value     
00596           pushad                  ! save general registers                
00597           push ds                 ! save ds                              
00598           push es                 ! save es                             
00599           push fs                 ! save fs                            
00600           push gs                 ! save gs                           
00601      o16  mov ax, KERNEL_VDATA_SELECTOR                                       
00602           mov ds, ax              ! we don't touch ss, becasue it was
00603           mov es, ax              ! already setup by kernel TSS if the
00604           mov fs, ax              ! previous mode is user. If the previous
00605           mov gs, ax              ! mode is kernel, reload is trivial.
00606           mov eax,esp             ! use eax as a base pointer.
00607           push esp                ! esp points to common stack frame
00608           push 60(eax)            ! get cs pushed.
00609           sti                     ! allow interrupts
00610           test (esp), RING0
00611           je 1f                   ! if ring0
00612           call _trap              ! C verion trap routine
00613           add esp, 4*2            ! pop used C arguments
00614        2: cli                     ! disable interrupts
00615           cmpb (_runrun), 0
00616           je 2f
00617           sti                     ! unlock
00618           call _swtch
00619           jmp 2b
00620        2: pop gs                  ! return to user mode
00621           pop fs
00622           pop es
00623           pop ds
00624           popad
00625           add esp, 4*2            ! pop padding space
00626           iretd
00627        1: call _trap              ! C verion trap routine
00628           add esp, 4*2            ! pop used C arguemts
00629           cli                     ! disable interrupts
00630           pop gs                  ! return to kernel mode
00631           pop fs
00632           pop es
00633           pop ds
00634           popad
00635           add esp, 4*2            ! pop padding space
00636           iretd
00637   
00638   !*===========================================================================*
00639   !*                             savu                                          *
00640   !*===========================================================================*
00641   ! PUBLIC void savu(reg_t *kenv);
00642   ! Save the kernel mode environment into user PPDA, it is highly cooperated
00643   ! with retu to switch the kernel process. 
00644   
00645          .align 16
00646   _savu:
00647         cli                ! atomic operating, interrupt is not allowed
00648         pop eax            ! get return address
00649         mov edx, (esp)     ! fetch the retiring process u_kenv pointer
00650         mov (edx), esp     ! get esp saved
00651         add edx, 4
00652         mov (edx), ebp     ! get ebp saved
00653         add edx, 4
00654         mov (edx), ebx     ! get ebx saved
00655         add edx, 4
00656         mov (edx), esi     ! get esi saved
00657         add edx, 4
00658         mov (edx), edi     ! get edi saved
00659         add edx, 4
00660         pushf
00661         pop ecx
00662         mov (edx), ecx     ! get eflags saved
00663         sti                ! unlock
00664         jmp (eax)          ! go back
00665         
00666   !*===========================================================================*
00667   !*                             retu                                          *
00668   !*===========================================================================*
00669   ! PUBLIC void retu(phys_bytes usr_pagetab);
00670   ! Restore the kernel mode environment from user PPDA, it is highly cooperated
00671   ! with savu to switch the kernel process
00672   
00673          .align 16
00674   _retu:
00675         cli                ! atomic operating, interrupt is not allowed
00676         pop eax            ! get return address
00677         mov edx, (esp)     ! fetch the arising process page table pointer
00678         mov eax, (edx)
00679         mov cr3, eax       ! restore arising process page table
00680         mov edx, (_usr_ppda_ptr)
00681         add edx, 12        ! get the arising process u_kenv pointer
00682         mov esp, (edx)     ! restore esp
00683         add edx, 4
00684         mov ebp, (edx)     ! restore ebp
00685         add edx, 4
00686         mov ebx, (edx)     ! restore ebx
00687         add edx, 4
00688         mov esi, (edx)     ! restore esi
00689         add edx, 4
00690         mov edi, (edx)     ! restore edi
00691         add edx, 4
00692         mov ecx, (edx)     
00693         push ecx
00694         popf               ! restore eflags
00695         sti                ! unlock
00696         jmp (eax)          ! go back
00697   
00698   !*===========================================================================*
00699   !*                             aretu                                         *
00700   !*===========================================================================*
00701   ! PUBLIC void aretu();
00702   ! Used to performance the local goto. Mainly used to abort system call.
00703   
00704          .align 16
00705   _aretu:
00706         cli                ! atomic operating, interrupt is not allowed
00707         pop eax            ! get return address
00708         mov edx, (esp)     ! fetch the retiring process u_qenv pointer
00709         mov esp, (edx)     ! restore esp
00710         add edx, 4
00711         mov ebp, (edx)     ! restore ebp
00712         add edx, 4
00713         mov ebx, (edx)     ! restore ebx
00714         add edx, 4
00715         mov esi, (edx)     ! restore esi
00716         add edx, 4
00717         mov edi, (edx)     ! restore edi
00718         add edx, 4
00719         mov ecx, (edx)     
00720         push ecx
00721         popf               ! restore eflags
00722         sti                ! unlock
00723         jmp (eax)          ! go back
00724   
00725   !*===========================================================================*
00726   !*                             idle                                          *
00727   !*===========================================================================*
00728   ! PUBLIC void idle();
00729   ! Used to consume the processor idle time if there's no process runnable, only
00730   ! the hardware interrupt can make it back.
00731   
00732         .align 16
00733   _idle:
00734         sti         ! To allow peripheral interrupt
00735         hlt
00736         ret
00737   
00738   !*===========================================================================*
00739   !*                             gohome                                        *
00740   !*===========================================================================*
00741   ! PUBLIC void gohome();
00742   ! Called only by swtch() to return to arising process environment, it prevents
00743   ! the esi, edi registers from being restored again blindly. The ACK compiler
00744   ! use these registers as local register variables, it restore these registers
00745   ! before discarding the local stack variables. eax can be used to hold the 
00746   ! return value from subroutine, the value returned here has many subtle
00747   ! implications. See the newproc comments.
00748   
00749         .align 16
00750   _gohome:
00751         mov eax, 1
00752         leave
00753         ret
00754   
00755