fet140_tb04.s43

TI低功耗MCU用例子

#include  "msp430x14x.h"
;******************************************************************************
;   MSP-FET430P140 Demo - Timer_B Toggle P1.0, TBoverflow ISR, 32kHz ACLK
;
;   Description; Toggle P1.0 using using software and the timer_B overflow ISR. 
;   In this example an ISR will trigger when TB overflows.  Inside the ISR P1.0 
;   is toggled.  Toggle rate is exactly 0.25hz.
;   ACLK = TBCLK = 32768, MCLK = SMCLK = DCO ~ 800k 
;   //*An external watch crystal on XIN XOUT is required for ACLK*//	  
;
;                 MSP430F149
;             -----------------
;         /|\|              XIN|-  
;          | |                 | 32kHz 
;          --|RST          XOUT|-
;            |                 |
;            |             P1.0|-->LED
;
;   M.Buccini
;   Texas Instruments, Inc
;   January 2002
;******************************************************************************
;------------------------------------------------------------------------------ 
            ORG     01100h                  ; Progam Start 
;------------------------------------------------------------------------------ 
RESET       mov.w   #0A00h,SP               ; Initialize 'F149 stackpointer
StopWDT     mov.w   #WDTPW+WDTHOLD,&WDTCTL  ; Stop WDT
SetupTB     mov.w   #TBSSEL0+TBCLR+TBIE,&TBCTL  ; ACLK, Clr TAR, interrupt
SetupP1     bis.b   #001h,&P1DIR            ; P1.0 output 
            bis.w   #MC1,&TBCTL             ; Start timer_B continous mode
            eint                            ; Enable interrupts
                                            ;													  
Mainloop    bis.w   #LPM3,SR                ; Enter LPM3
            nop                             ; Required only for C-spy
                                            ;
;------------------------------------------------------------------------------ 
TBX_ISR;    Common ISR for TBCCR1-4 and overflow
;------------------------------------------------------------------------------ 
            add.w   &TBIV,PC                ; Add Timer_B offset vector
            reti                            ; CCR0 - no source
            reti                            ; CCR1
            reti                            ; CCR2
            reti                            ; CCR3
            reti                            ; CCR4
            reti                            ; CCR5
            reti                            ; CCR6
TB_over     xor.b   #001h,&P1OUT            ; Toggle P1.0
            reti                            ; Return from overflow ISR		 
                                            ;
;------------------------------------------------------------------------------ 
;           Interrupt Vectors Used MSP430x13x/14x          
;------------------------------------------------------------------------------ 
            ORG     0FFFEh                  ; MSP430 RESET Vector
            DW      RESET                   ; 
            ORG     0FFF8h                  ; Timer_BX Vector
            DW      TBX_ISR                 ; 
            END