fet140_ta06.s43

TI低功耗MCU用例子

#include  "msp430x14x.h"
;******************************************************************************
;   MSP-FET430P140 Demo - Timer_A Toggle P1.0, CCR1 Contmode ISR, DCO SMCLK
;
;   Description; Toggle P1.0 using using software and TA_1 ISR. Toggle rate is 
;   set at 50000 DCO/SMCLK cycles. Default DCO frequency used for TACLK. 
;   Durring the TA_0 ISR P0.1 is toggled and 50000 clock cycles are added to 
;   CCR0.  TA_1 ISR is triggered exactly 50000 cycles. CPU is normally off and
;   used only durring TA_ISR. Proper use of TAIV interrupt vector generator
;   demonstrated.    
;   ACLK = n/a, MCLK = SMCLK = TACLK = DCO ~ 800k
;
;                MSP430F149
;             -----------------
;         /|\|              XIN|-  
;          | |                 |
;          --|RST          XOUT|-
;            |                 |
;            |             P1.0|-->LED
;
;   M.Buccini
;   Texas Instruments, Inc
;   January 2002
;******************************************************************************
;------------------------------------------------------------------------------ 
            ORG     01100h                  ; Program Start
;------------------------------------------------------------------------------ 
RESET       mov.w   #0A00h,SP               ; Initialize 'F149 stackpointer
StopWDT     mov.w   #WDTPW+WDTHOLD,&WDTCTL  ; Stop WDT
SetupTA     mov.w   #TASSEL1+TACLR,&TACTL   ; SMCLK, clear TAR
SetupC1     mov.w   #CCIE,&CCTL1            ; CCR1 interrupt enabled
            mov.w   #50000,&CCR1            ; 
SetupP1     bis.b   #001h,&P1DIR            ; P1.0 output 
            bis.w   #MC1,&TACTL             ; Start Timer_a in continous mode
            eint                            ; Enable interrupts
                                            ;						  
Mainloop    bis.w   #CPUOFF,SR              ; CPU off
            nop                             ; Required for C-spy
                                            ;
;------------------------------------------------------------------------------ 
TAX_ISR;    Common ISR for CCR1-4 and overflow
;------------------------------------------------------------------------------ 
            add.w   &TAIV,PC                ; Add Timer_A offset vector
            reti                            ; CCR0 - no source
            jmp     CCR1_ISR                ; CCR1
            reti                            ; CCR2
            reti                            ; CCR3
            reti                            ; CCR4
TA_over     reti                            ; Return from overflow ISR		 
                                            ;
CCR1_ISR    add.w   #50000,&CCR1            ; Offset until next interrupt
            xor.b   #001h,&P1OUT            ; Toggle P1.0
            reti                            ; Return from overflow ISR		 
                                            ;            
;----------------------------------------------------------------------------- 
;           Interrupt Vectors Used MSP430x13x/14x          
;----------------------------------------------------------------------------- 
            ORG     0FFFEh                  ; MSP430 RESET Vector
            DW      RESET                   ; 
            ORG     0FFEAh                  ; Timer_AX Vector
            DW      TAX_ISR                 ; 
            END