ezsim.bat

GAL开发工具

: ABEL(tm) Version-3.00a  Copyright 1983-1987 FutureNet Div, Data I/O Corp.
echo off
if X%1 == X goto help
if NOT X%1 == X-help goto begin
:help
echo :  NAME:  ezsim = batch script to execute resimulate abel source
echo :  USAGE: ezsim  name [args]...              
echo :      name = design file name -- without suffix [.abl]
echo :      args = command line options
echo :  FILES:   name.abl -- source file
echo :      name.lst, name.sim  -- results
echo :      name.tm1, name.tm2  -- intermediate files
echo :  Expects device files to be in the directory specified by ABEL3DEV
goto exit

:begin
echo + ezsim %1
PARSE  -i%1.abl -o%1.tm1 -l%1.lst  %2 %3 %4 %5 %6 %7 %8 %9
if errorlevel 1 goto parserr
TRANSFOR -i%1.tm1 -o%1.tm2
if errorlevel 1 goto tranerr
if exist %1.tm1 del %1.tm1
SIMULATE -i%1.tm2 -o%1.sim %2 %3 %4 %5 %6 %7 %8 %9
if errorlevel 1 goto simerr
if exist %1.tm2 del %1.tm2
goto exit
:parserr
    echo ? ezsim: Error in parsing source	(see PARSE)
    goto exit
:tranerr
    echo ? ezsim: Error in transforming terms	(see TRANSFOR)
    goto exit
:simerr
    echo ? ezsim: Error in simulating logic/vectors	(see SIMULATE)
:exit