abel.bat

GAL开发工具

: ABEL(tm) Version-3.00a  Copyright(C) 1983-1988 FutureNet Div, Data I/O Corp.
echo off
if X%1 == X goto help
if NOT X%1 == X-help goto begin
:help
echo :  NAME:  abel = batch script to execute all phases of ABEL (COMMAND.COM)
echo :  USAGE: abel  name [args]...
echo :      name = design file name -- without suffix [.abl]
echo :      args = command line options
echo :  FILES:   name.abl -- source file
echo :      name.lst, name.sim, name.doc, name.out, device.jed -- results
echo :      name.tm1, name.tm2, name.tm3 -- intermediate files
echo :  Expects device files to be in the directory specified by ABEL3DEV
goto exit

:begin
echo + abel %1
PARSE  -i%1.abl -o%1.tm1 -l%1.lst  %2 %3 %4 %5 %6 %7 %8 %9
if errorlevel 1 goto parserr
TRANSFOR -i%1.tm1 -o%1.tm2  %2 %3 %4 %5 %6 %7 %8 %9
if errorlevel 1 goto tranerr
if exist %1.tm1 del %1.tm1
REDUCE -i%1.tm2 -o%1.tm3 %2 %3 %4 %5 %6 %7 %8 %9
if errorlevel 2 goto fuse
if errorlevel 1 goto rederr
:fuse
if exist %1.tm2 del %1.tm2
FUSEMAP -i%1.tm3 -o%1.out %2 %3 %4 %5 %6 %7 %8 %9
if errorlevel 1 goto fuserr
if exist %1.tm3 del %1.tm3
SIMULATE -i%1.out -o%1.sim %2 %3 %4 %5 %6 %7 %8 %9
if errorlevel 1 goto simerr
DOCUMENT -i%1.out -o%1.doc -f0 -g %2 %3 %4 %5 %6 %7 %8 %9
if errorlevel 1 goto docerr
goto exit
:parserr
    echo ? abel: Error in parsing source        (see PARSE)
    goto exit
:tranerr
    DOCUMENT -i%1.tm1 -o%1.doc  -g -q0 %2 %3 %4 %5 %6 %7 %8 %9
    echo ? abel: Error in transforming terms    (see TRANSFOR)
    goto exit
:rederr
    DOCUMENT -i%1.tm2 -o%1.doc -g -q1 %2 %3 %4 %5 %6 %7 %8 %9
    echo ? abel: Error in reducing factors      (see REDUCE)
    goto exit
:fuserr
    DOCUMENT -i%1.tm3 -o%1.doc -g -v -q2 %2 %3 %4 %5 %6 %7 %8 %9
    echo ? abel: Error in generating fusemap    (see FUSEMAP)
    goto exit
:simerr
    DOCUMENT -i%1.out -o%1.doc -f -g -v -q2 %2 %3 %4 %5 %6 %7 %8 %9
    echo ? abel: Error in simulating logic/vectors      (see SIMULATE)
    goto exit
:docerr
    echo ? abel: Error producing documents      (see DOCUMENT)
:exit