c5416dsk.cmd

TMS320C5416 DSP 主从机通信

/*************************************************************************
* $RCSFile: $
* $Revision: 1.1 $
* $Date: 2001/11/21 04:32:06 $
* Copyright (c) 2001 Texas Instruments Incorporated
*
* LINKER COMMAND FILE FOR TMS320VC5416 DSK Target
*
*   Usage:  lnk500 <obj files...>    -o <out file> -m <map file> c5416dsk.cmd
*           cl500  <src files...> -z -o <out file> -m <map file> c5416dsk.cmd
*
*   Description: This file is a sample command file that can be used
*                for linking programs built with the TMS54x C Compiler.
*                Use it as a guideline; you may want to change
*                the allocation scheme according to the size of your
*                program and the memory layout of your target system.
*************************************************************************/
-c /* copy constants in .cinit to global variables at boot time */
-stack 0x0400
-heap  0x0400

/* This symbol defines the interrupt mask to be applied to IMR inside
   RTDX Critical Code sections.

   This example masks the timer interrupt.
*/
_RTDX_interrupt_mask = ~0x0008; /* interrupts masked by RTDX */


/* Note: The default power-up state of board is PMST = 0xffa0, but we
    set it to 0x7fa8 in a GEL file.

PMST
______________________________________________________________________
IPTR                               |MP/|OV |AV |DR |CLK|SM |SST|Hex
                                   |MC |LY |IS |OM |OFF|UL |   |Value
15 |14 |13 |12 |11 |10 | 9 | 8 | 7 | 6 | 5 | 4 | 3 | 2 | 1 | 0 |
----------------------------------------------------------------------
 1 | 1 | 1 | 1 | 1 | 1 | 1 | 1 | 1 | 0 | 1 | 0 | 0 | 0 | 0 | 0 |0xffa0
---+---+---+---+---+---+---+---+---+---+---+---+---+---+---+---+------
 1 | 1 | 1 | 1 | 1 | 1 | 1 | 1 | 1 | 1 | 1 | 0 | 0 | 0 | 0 | 0 |0xffe0
---+---+---+---+---+---+---+---+---+---+---+---+---+---+---+---+------
 0 | 1 | 1 | 1 | 1 | 1 | 1 | 1 | 1 | 0 | 1 | 0 | 1 | 0 | 0 | 0 |0x7fa8
----------------------------------------------------------------------

Note: Memory between 0x0080-0x8000 is shared if OVLY = 1.

Note: PMEM0/DMEM0 will be flash memory if FLASHENB = 1.  
This memory may be recovered as SRAM by setting to 0.
*/


MEMORY  
{
    PAGE 0: /* Program Space when MP/MC = 0 */
        RSV0    (R  ) : o=000000h l=000080h /* Reserved                 */
        DARAM0  (RWX) : o=000080h l=003f80h /* On-Chip DARAM0 & DARAM1  */
        DARAM2  (RWX) : o=004000h l=003f80h /* On-Chip DARAM2 & DARAM3  */
        VECS0   (RWX) : o=007f80h l=000080h /* Interrupt Vector Table   */
        EXT     (RWX) : o=008000h l=004000h /* External                 */
        ROM     (R  ) : o=00c000h l=003f00h /* On-Chip ROM              */
        RSV1    (R  ) : o=00ff00h l=000080h /* Reserved                 */
        VECS1   (RWX) : o=00ff80h l=000080h /* Interrupt Vector Table   */


    PAGE 1: /* Data Space */
        MMRS    (RW ) : o=000000h l=000060h /* Memory-mapped registers  */
        SCRATCH (RW ) : o=000060h l=000020h /* scratch-pad DARAM        */
        DARAM0  (RWX) : o=000080h l=003f80h /* On-Chip DARAM0 & DARAM1  */
        DARAM2  (RWX) : o=004000h l=003f80h /* On-Chip DARAM2 & DARAM3  */
        /* External when DROM=0                                         */
        DARAM4  (RW)  : o=008000h l=002000h /* On-Chip DARAM4           */
        DARAM5  (RW)  : o=00a000h l=002000h /* On-Chip DARAM5           */
        DARAM6  (RW)  : o=00c000h l=002000h /* On-Chip DARAM6           */
        DARAM7  (RW)  : o=00e000h l=002000h /* On-Chip DARAM7           */
}

SECTIONS
{
    .intvecs    : > VECS0   PAGE 0 /* interrupt vector table            */

    .text       : > DARAM0  PAGE 0 /* User code                         */
    .rtdx_text  : > DARAM0  PAGE 0 /* RTDX code                         */
    .cinit      : > DARAM0  PAGE 0 /* initialization tables             */
    .pinit      : > DARAM0  PAGE 0 /* initialization functions          */
    .switch     : > DARAM0  PAGE 0 /* for C-switch tables               */
    .sysmem     : > DARAM2  PAGE 1 fill = 0DEADh /* dynamic heap        */
    .stack      : > DARAM2  PAGE 1 fill = 0BEEFh /* system stack        */
    .const      : > DARAM2  PAGE 1 /* C constant tables                 */
    .cio        : > DARAM2  PAGE 1 /* C-IO Buffer                       */
    .bss        : > DARAM2  PAGE 1 /* global & static vars              */
    .data       : > DARAM2  PAGE 1 /* asm data area                     */
    .rtdx_data  : > DARAM2  PAGE 1 /* RTDX data area                    */
}