储在sql7的image字段的文件下载到客户端的asp源代码.txt

用纯ＡＳＰ代码实现图片上传并存入数据库中

把存储在SQL7的image字段的文件下载到客户端的ASP源代码，继续和大家分享。    


--------------------------------------------------------------------------------

 【woozhj】 于 00-2-27 11:58:44 加贴在 Joy ASP ↑：

<%
'**************************************
'文 件 名：download.asp 
'使用方法：download.asp?fid=xxx
'说　　明：把SQL7的image字段存储的文件下载到客户端
'数据库结构：[表名]tabimage　{fid int not null;filename varchar(100) not null;filecontent image not null}
'            fid:文件id [PK]；filename:文件名；filecontent:文件二进制内容
'**************************************
Response.Buffer=True
varfileid = Request("fid")
If varfileid="" Then
   Response.write "没有指定下载文件ID。"
   Response.End
End If

OpenDB conn
SQL = "SELECT filename,filecontent FROM tabimage WHERE fid=" & varfileid
Set rs = conn.Execute(SQL)
If Not rs.Eof Then
   varfilename = rs("filename")
   varfilesize=rs("filecontent").ActualSize
   varcontent = rs("filecontent").GetChunk(varfilesize)
   Response.ContentType = "*/*"
   Response.AddHeader "Content-Length",varfilesize
   Response.AddHeader "Content-Disposition", "attachment;filename=""" & varfilename & """"
   Response.binarywrite varcontent
End If
rs.Close
Set rs = Nothing
conn.Close
Set conn = Nothing
Response.End

'连接数据库通用过程
Sub OpenDB (ByRef conn)
    Set conn = Server.CreateObject("ADODB.Connection")
        conn.provider="sqloledb"
        conn.ConnectionString = "driver={SQL Server};server=xxx.xxx.xxx.xxx;uid=myusername;pwd=mypassword;database=mydatabase"
        conn.Open
End Sub
%>