飞鸟有关smtp server 的实验.txt

用纯ＡＳＰ代码实现图片上传并存入数据库中

飞鸟有关smtp server 的实验    


--------------------------------------------------------------------------------

 【飞鸟】 于 99-3-4 08:52:49 下午 加贴在 Joy ASP ↑：

实验目录
    了解asp程序发送电子邮件的过程，熟悉smtp server的设置和使用。

实验环境
    飞鸟自己的机器，中文nt server 4 + iis4 (安装有smtp server)，机器名：spf
    飞鸟公司的mail服务器 中文nt server 4 + exchange server 5.5 ，机器名保密 :),
    两个示例程序 readmail.asp & sendmail.asp
    
实验过程。
    1.给自己机器发送邮件
      ie4地址栏输入http://spf/test/sendmail.asp?from=spf@spf&to=spf@spf&subject=haha&body=xixi
      然后键入http://spf/test/readmail.asp?name=spf&email=spf@spf，嘿嘿看到了我的message
      检查\inetpub\mailroot\drop下，找到了一个eml后缀的文件。

    2.创建remote domain
      在Management console中，鼠标右键单击default smtp site ，选择菜单new,然后选定domain,
      域类型选择remote，域名输入飞鸟公司mail服务器所在的局网域域名。
      然后用sendmail向飞鸟的公司邮件账号发message:
      http://spf/test/sendmail.asp?from=spf@spf&to=[e-mail]&subject=haha&body=xixi
      (哈哈，后来用outlook 98从mail server上取下了邮件。)

     再让我试试向[e-mail]发送邮件。可惜失败了。检查inetpub\mailroot\badmail\下
     找到了这一封可怜的邮件。

    3.设置智能主机 smart host
     在Management console中，鼠标右键单击default smtp site,弹出Default SMTP Site属性窗口
     察看delivery属性页。
     设置正式域名 fully qualified domain name ,如果有的话。 我就写上spf就可以了。
     smart host，我输入我们mail server的局网ip
    
     再向[e-mail]发送邮件：
     http://spf/test/sendmail.asp?from=spf@spf&to=[e-mail]&subject=haha&body=xixi
     
     (后来用outlook 98从263.net取下了我的邮件)

   4.从公司mail服务器发邮件到spf@spf，我收到了
     但向[e-mail](我机器的局网ip)发邮件却失败了，可能mail服务器看到ip就到internet上找了。

   飞鸟在网上搬了好几次家，但是从来没有成功的找到一台可以发送mail的服务
器。不是没有安装就是没有设置好。web服务器如果不能发mail,功能不免就逊色很
多。

    在asp中，可以使许多别的组件发送mail,有的组件在asp中使用也很容易。我
在iis3上用过一个组件叫jmail，就觉得不错。比smtp server好用多了



附件：sendmail.asp    


--------------------------------------------------------------------------------

 【飞鸟】 于 99-3-4 08:54:28 下午 加贴在 Joy ASP ↑：

<!-- 
    This sample script uses the CDO for NTS Library to
    send email to a specific user.
    Leon Braginski & Matt Powell (c)
    Note: "To" is a reserved word, so we added an underscore to it.
-->

<%@ LANGUAGE = "VBScript" %>

<% 
If (Request.ServerVariables ("REQUEST_METHOD") = "POST") then
    From = Request.Form("from")
    To_ = Request.Form("to")
    Subject = Request.Form("subject")
    Body = Request.Form("body")
else
    ' Assume it is GET
    From = Request.QueryString("from") 
    To_ = Request.QueryString("to") 
    Subject = Request.QueryString("subject") 
    Body = Request.QueryString("body") 
end if

Set objNewMail = Server.CreateObject ("CDONTS.NewMail") 
objNewMail.Send From, To_, Subject, Body
Set objNewMail = Nothing
Response.Write "Message was sent"
%>



附件readmail.asp    


--------------------------------------------------------------------------------

 【飞鸟】 于 99-3-4 08:53:35 下午 加贴在 Joy ASP ↑：

<!-- 
    This sample script uses the CDO for NTS Library to 
    read e-mail for a specific user.
    Leon Braginski & Matt Powell (c)
-->
<%@ LANGUAGE = "VBScript" %>
<% 
If (Request.ServerVariables ("REQUEST_METHOD") = "POST") then
    Name = Request.Form("name")
    Email = Request.Form("ename")
else
    ' Assume it is GET
    Name = Request.QueryString("name") 
    Email = Request.QueryString("email") 
end if

If (Email = "") OR (Name = "") then
    Response.Write "You have to supply name and email <BR>"
    Response.End
End If

Set objSession = Server.CreateObject ("CDONTS.Session") 
objSession.LogonSMTP Name, Email
Set objInbox = objSession.GetDefaultFolder(1) 

If objInbox Is Nothing Then 
    Set collMessages = Nothing 
    Response.Write "Can't get folder. <br>"
    objSession.Logoff
    Response.End
End If

Set collMessages = objInbox.Messages 

If (collMessages.Count = 0) Then
    Response.Write  "<center> User <b>"  & Name & "</b>" & _
        " (email:  <b>" & Email & "</b>) does not have messages"
    Response.End
    objSession.Logoff
end if

Response.Write  "<center> User <b>"  & Name & "</b>" & _
    " (email:  <b>" & Email & "</b>) has <b>"& _
    collMessages.Count & "</b> message(s) </center> <p>"

Response.Write "<TABLE BORDER WIDTH=100% >"
Response.Write "<TR> <TD WIDTH=10% > <i>ID</i></TD>" & _
    "<TD WIDTH=15% > <i>From</i></TD>" & _
    "<TD WIDTH=15% > <i>Subject</i> </TD> " & _
    "<TD WIDTH=60% > <i>Message Text</i></TD> </TR>"

For Mes = 1 To collMessages.Count 
    Set objMessage = collMessages.Item(Mes) 
    Response.Write "<TR> <TD WIDTH=10% >" & Mes & "</TD>" & _
        "<TD WIDTH=15% >" & objMessage.Sender.Name & "</TD>" & _
        "<TD WIDTH=15% >" & objMessage.Subject & "</TD>" & _
        "<TD WIDTH=60% >" & objMessage.Text & "</TD> </TR>"
Next

Response.Write "</TABLE>"
%>