installo.bat

CBASE v1.01 采用Borland公司TC++编写的数据库管理源程序库

@echo off
rem lseq installation batch file------------------------------------------------
rem install.bat	1.4 - 90/06/20
rem NOTE Set up for overlay mode -Yo option turned on
rem ----------------------------------------------------------------------------
rem NAME
rem      install.bat - lseq library installation batch file for MS-DOS
rem
rem SYNOPSIS
rem      install model [x]
rem
rem DESCRIPTION
rem     install.bat performs the installation of the lseq library for
rem     MS-DOS.  model specifies the memory model as one of the following.
rem
rem          s        small model
rem          m        medium model
rem          c        compact model
rem          l        large model
rem          h        huge model
rem
rem     The library file is named lseqm.lib, where m would correspond
rem     to the memory model of the library.
rem
rem     If specified, the second parameter causes the reference manual to
rem     be extracted from the source code.  The reference manual is placed
rem     in the file lseq.man.
rem
rem SEE ALSO
rem      makefile
rem
rem NOTES
rem      This modified batch file is written for use with
rem       Borland Turbo C++.  To convert it for use with another
rem       compiler, make the following  modifications:
rem
rem           1. Replace \tc\include with the include directory used by
rem              the new compiler.
rem           2. Replace \tc\lib with the library directory used by the
rem              new compiler.
rem           3. Replace tcc with the command to invoke the compiler being
rem              used, replacing the switches also, if necessary.  Below
rem              are listed the Turbo C switches used and their meanings.
rem                   -O        jump optimization
rem                   -G        speed optimization
rem                   -c        compile but don't link
rem                   -A        ANSI keywords only
rem                   -C-       no nested comments
rem                   -m        memory model
rem           4. The command to build the library archive from the object
rem              modules may vary more drastically.  Turbo C uses the tlib
rem              command with what is called a response file.  This
rem              response file, lseq.rsp, contains a list of all the
rem              object modules in the library.
rem
rem ----------------------------------------------------------------------------

rem verify arguments------------------------------------------------------------
if "%1" == "s" goto arg1
if "%1" == "m" goto arg1
if "%1" == "c" goto arg1
if "%1" == "l" goto arg1
if "%1" == "h" goto arg1
echo Usage:  install model [x]
echo Valid values for model are s (small), m (medium), c (compact),
echo   l (large), and h (huge).  Model must be lower case.
echo If x is specified, the reference manual will be extracted.
goto end
:arg1

if "%2" == "" goto arg2
if "%2" == "x" goto arg2
echo Usage:  install model [x]
echo Invalid second argument.  Valid value is lowercase x.
:arg2

if "%3" == "" goto arg3
echo Usage:  install model [x]
echo Too many arguments specified.
:arg3


rem extract the reference manual------------------------------------------------
if not "%2" == "x" goto skipman
echo Extracting reference manual into lseq.man.
if not exist lseq.man goto man
echo lseq.man exists.  ^C to exit, any other key to continue.
pause
:man
if not exist tmp goto tmp
echo tmp exists.  ^C to exit, any other key to continue.
pause
:tmp
echo on
type lseq.h | manx -c >lseq.man
copy
lsclose.cpp/a+lscreate.cpp+lscursor.cpp+lsdelcur.cpp+lsfirst.cpp+lsgetcur.cpp tmp
type tmp | manx -c >> lseq.man
copy lsgetlck.cpp/a+lsgetr.cpp+lsgetrf.cpp+lsinsert.cpp+lslast.cpp+lslock.cpp tmp
type tmp | manx -c >> lseq.man
copy lsnext.cpp/a+lsopen.cpp+lsprev.cpp+lsputr.cpp+lsputrf.cpp+lsreccnt.cpp tmp
type tmp | manx -c >> lseq.man
copy lsrecsiz.cpp/a+lssearch.cpp+lssetbuf.cpp+lssetcur.cpp+lssetvbu.cpp+lssync.cpp tmp
type tmp | manx -c >> lseq.man
del tmp
@echo off
:skipman

rem compile all lseq source files-----------------------------------------------
echo on
tcc -c -O -G -A -C- -P -Yo -m%1 lsclose.cpp  lscreate.cpp lsdelcur.cpp lsfirst.cpp  lsgetcur.cpp lsgetlck.cpp
tcc -c -O -G -A -C- -P -Yo -m%1 lsgetr.cpp  lsgetrf.cpp lsinsert.cpp lslast.cpp   lslock.cpp   lsnext.cpp
tcc -c -O -G -A -C- -P -Yo -m%1 lsopen.cpp   lsprev.cpp lsputr.cpp  lsputrf.cpp  lssearch.cpp lssetbuf.cpp
tcc -c -O -G -A -C- -P -Yo -m%1 lssetcur.cpp lssetvbu.cpp lssync.cpp
tcc -c -O -G -A -C- -P -Yo-m%1 lsops.cpp   rcops.cpp
@echo off

rem build the lseq library archive----------------------------------------------
if exist lseq%1.lib del lseq%1.lib
echo on
tlib lseq%1 @lseq.rsp
@echo off


rem end of lseq installation batch file-----------------------------------------
:end