co-exist.cmd

TMS320C2000Flash操作

/*--------------------------------------------------------------------------------------------------
 * Filename         : MAIN.CMD	  
 * Last Modified    : 26 Dec 2001.
 * Version          : 1.3
 * Originator       : Texas Instruments, DSP Digital Control Systems Group.
 *--------------------------------------------------------------------------------------------------
 * Revision history : 
 * Version 1.3 (26 Dec 2001):
 *                    Changed start of the 'PROG' memory block to 0x44 to maintain compatibility
 *                    with the LF240x-A parts.
 *                    Added version header
 *                    
 *
 */

MEMORY
{
  PAGE 0 : VECS: 	origin = 0x0000, length = 0x0040
  PAGE 0 : PROG: 	origin = 0x0044, length = 0x7fbc
  PAGE 0 : ABSRAM:  origin = 0x8000, length = 0x0040
  PAGE 0 : SARAM: 	origin = 0x8040, length = 0x07c0
  PAGE 1 : BLKB2: 	origin = 0x0060, length = 0x0020
  PAGE 1 : BLKB0B1:	origin = 0x0200, length = 0x0200

}
SECTIONS
{                       
	VECTORS : {} > VECS PAGE 0	

    .text   : {} > PROG PAGE 0
    .cinit  : {} > PROG PAGE 0

/* Allocate the relocation sensitive portions in SARAM 
   at proper addresses. The relocation sensitive section
   should always be sent to a RAM block starting on XXX0
   for the relocation mechanism to properly locate the
   code with relocation sensitivities.
 */
    SPL_text: load = PROG PAGE 0, run= ABSRAM PAGE 0
    {
    . += 7 ;
    ClearAlgoRunSpl   = . ;
    *(CSPL_text)
    . += 6 ;
    ProgramAlgoRunSpl = . ;
    *(PSPL_text)
    . += 6 ;
    EraseAlgoRunSpl   = . ;
    *(ESPL_text)
    }

    ALG_text : load = PROG PAGE 0, run = SARAM PAGE 0
    {
    ClearAlgoRunMain = .   ;
    *(CLR_text)
    EraseAlgoRunMain = .   ;
    *(ERA_text)
    ProgramAlgoRunMain = . ;
    *(PGM_text)
	KernelRun = .;
	*(KER_strt)
	*(KER_text)
	*(KER_end)
    }
    .flshvar  : {} > BLKB2  PAGE 1

}