main.cmd

TMS320C2000Flash操作

/*--------------------------------------------------------------------------------------------------
 * Filename         : MAIN.CMD	  
 * Last Modified    : 26 Dec 2001.
 * Version          : 1.3
 * Originator       : Texas Instruments, DSP Digital Control Systems Group.
 *--------------------------------------------------------------------------------------------------
 * Revision history : 
 *
 * Version 1.3 (2 Jan 2002):
 *                    * Added header which was missing.
 *                    * Added allocation for .bss and .stack sections.
 *                    * Modified memory block PROG to start at 0x44, so as to 
 *                      keep out of the password area on the rev-A parts
 *
 */

MEMORY
{
  PAGE 0 : VECS: 	origin = 0x0000, length = 0x0040
  PAGE 0 : PROG: 	origin = 0x0044, length = 0x7fbc
  PAGE 0 : ABSRAM:  origin = 0x8000, length = 0x0040
  PAGE 0 : SARAM: 	origin = 0x8040, length = 0x07c0
  PAGE 1 : BLKB2: 	origin = 0x0060, length = 0x0020
  PAGE 1 : BLKB0B1:	origin = 0x0200, length = 0x0200

}
SECTIONS
{                       
	VECTORS : {} > VECS PAGE 0	

    .text   : {} > PROG PAGE 0
    .cinit  : {} > PROG PAGE 0

/* Allocate the relocation sensitive portions in SARAM 
   at proper addresses. The relocation sensitive section
   should always be sent to a RAM block starting on XXX0
   for the relocation mechanism to properly locate the
   code with relocation sensitivities.
 */

	UNION 	  run = ABSRAM PAGE 0
	{   
    	CSPL_tex: load = PROG PAGE 0 
    	{
    	.+= 7;
    	ClearAlgoRunSpl = . ;
    	*(CSPL_text)
    	}
    	
    	  
	    PSPL_tex:  load = PROG PAGE 0
    	{
    	.+= 7;
    	ProgramAlgoRunSpl = . ;
    	*(PSPL_text)
    	}

	    ESPL_tex:  load = PROG PAGE 0
    	{
    	.+= 7;
    	EraseAlgoRunSpl = . ;
    	*(ESPL_text)
    	}
	}
	

    UNION   run = SARAM	PAGE 0
	{
    	CLR_text:	load = PROG PAGE 0
    	{
    	ClearAlgoRunMain = .   ; 
    	}
    		
        ERA_text:	load = PROG PAGE 0
        {
        EraseAlgoRunMain = .   ;
        }

        PGM_text	load = PROG PAGE 0
        {
        ProgramAlgoRunMain = . ;
        }
    }


  KER_comp : load = PROG PAGE 0, run = SARAM PAGE 0
    {
 	KernelRun = .;
	*(KER_strt)
	*(KER_text)
	*(KER_end)
    }



    .flshvar  : {} > BLKB2  PAGE 1
    .bss      : {} > BLKB0B1 PAGE 1
    .stack    : {} > BLKB0B1 PAGE 1


}