inbox.asp

一个虚拟主机代理系统

<%'=========================================
'ScriptMate User Manager Version 2.1
'Copyright 2001 (C) ScriptMate.Com
'User Module
'This displays all the incoming messages of a member
'For any help with modification to
'this file contact [e-mail]
'=========================================

Sub Inbox()

	dim action,records,smumquery,smumarray,iscolor
	
	if not Application("smumdebugmode") then on error resume next

	if session("id") = "" then Response.Redirect smumpage&"?action=login&url="&Request.ServerVariables("url")&"?action=inbox"
	
	action = request("action")
	
	smumquery = "select * from smum_messagingtbl where messaging_toid = "&session("id") &" and messaging_approvalstatus = "&smumtrue&" and messaging_deletestatusto = "&smumfalse&" order by messaging_date desc"
	smumOpenrs smumquery,"smumrs",action
	
		if smumrs.eof then

			smumFormOpenTable
			smumFormHeader "Inbox"
			smumFormResponse "There are currently no messages in your Inbox."
			smumFormCloseTable

		else

			records = true	
			smumarray = smumrs.getrows
				
		end if

	smumClosers(smumrs)
	
	if records then
	
		smumFormOpenTable%>
		
			<tr class=colorformheader>
				<td colspan=5 align=left width=75><font class=textsize9><b>Inbox</b></font></td>
			</tr>
			<tr class=colorformfields>
				<td align=center width=5% nowrap></td>
				<td align=center width=5% nowrap></td>
				<td align=center width=10% nowrap><font class=textsize9><b>From</b></font></td>
				<td align=left><font class=textsize9><b>Subject</b></font></td>
				<td width=10% nowrap align=center><font class=textsize9><b>Date</b></font></td>
			</tr>

			<%dim i
			For i = 0 to ubound(smumarray,2)

				if iscolor = false then
					response.write"<tr class=colorwhite><td align=center width=5% nowrap>"
					iscolor = true
				else
					response.write"<tr class=colorformfields><td align=center width=5% nowrap>"
					iscolor = false
				end if

				if not smumarray(7,i) then response.write "<img src=/smusermanager/images/newmail.gif border=0 align=absmiddle alt=New>"

				response.write "</td><td align=center width=5% nowrap><a href="""&request.servervariables("url")&"?action=deletemessage&messaging_id="&smumarray(0,i)&"""><img src=/smusermanager/images/delete.gif border=0 align=absmiddle alt=Delete></a>"

				response.write "</td><td align=center width=10% nowrap><font class=textsize9><a href="""&request.servervariables("url")&"?action=displaymember&messaging_id="&smumarray(2,i)&""">"&smumgetusername(smumarray(2,i))&"</a></font></td><td align=left><font class=textsize9><a href="""&request.servervariables("url")&"?action=displaymessage&messaging_id="&smumarray(0,i)&""">"

				if not smumarray(7,i) then
					response.write "<b>"&smumarray(4,i)&"</b>"
				else
					response.write smumarray(4,i)
				end if

				response.write "</a></font></td><td nowrap width=10% align=center><font class=textsize9>"&monthname(month(smumarray(1,i)),true) & " " & day(smumarray(1,i))  &"</font></td></tr>"

			next
		
		smumFormCloseTable
	
	end if

End Sub%>