newsletter.asp

一个虚拟主机代理系统

<%'=========================================
'ScriptMate User Manager Version 2.1
'Copyright 2001 (C) ScriptMate.Com
'Admin Module
'This module helps in sending newsletters to maillist members, registered members,
'members of a particular level or a group
'For any help with modification to
'this file contact [e-mail]
'=========================================%>

<script language="JAVASCRIPT">


	var errfound = false;

		function ValidLength(item, len) {
		   return (item.length >= len);
		}

		function error(elem, text) {
		   if (errfound) return;
		   window.alert(text);
		   elem.select();
		   elem.focus();
		   elem.style.backgroundColor=errorcolor;
		   errfound = true;
		}
		
		function Validatenewsletter() {
		   errfound = false;
		   d=document.newsletter
		   if (!ValidLength(d.subject.value,2))error(d.subject,"Subject should not be blank.");
		   if (!ValidLength(d.content.value,2))error(d.content,"Content of the Newsletter should not be blank.");
		   return !errfound;
		}

		function Validatenewsletterg() {
		   errfound = false;
		   d=document.newsletterg
		   if (!ValidLength(d.subject.value,2))error(d.subject,"Subject should not be blank.");
		   if (!ValidLength(d.content.value,2))error(d.content,"Content of the Newsletter should not be blank.");
		   return !errfound;
		}

</script>

<%Sub Newsletter()

	dim todo, action, accesslevel, content, subject, nummembers, message, messagestatus, smumquery1, records, tempar, email,_
	toname, subjectfinal, messagebody, i, result


	session("smbulkmail") = true

	smumadminheader("Newsletter")
	
	if not Application("smumdebugmode") then on error resume next

	action = request("action")
	todo = Request("todo")
	
	if todo = "" then
	
		smumFormAction "<form action="""&smumadminpage&"?action=newsletter"" method=post name=newsletter language=""JAVASCRIPT"" onsubmit=""return Validatenewsletter();"">"
		smumFormHiddenField "todo","check"
		smumFormOpenTable
		smumFormHeader "Send a Newsletter to the Registered Members or Mailing List"
		smumFormFields "User Access Level",getaccesslevelnews(accesslevel)
		smumFormFields "Subject","<input class=fieldbox type=text name=subject size=45>"
		smumFormFields "Content","<textarea class=fieldbox cols=45 rows=10 name=content></textarea>"
		smumFormButtons "<input class=fieldbox type=submit value=""Nex Step >>"" name=submit>"
		smumFormCloseTable
		smumFormClose		

		smumFormAction "<form action="""&smumadminpage&"?action=newsletterg"" method=post name=newsletterg language=""JAVASCRIPT"" onsubmit=""return Validatenewsletterg();"">"
		smumFormHiddenField "todo","check"
		smumFormOpenTable
		smumFormHeader "Send a Newsletter to an Individual Group"
		smumFormFields "Choose a Group",getgroupssingle(0)
		smumFormFields "Subject","<input class=fieldbox type=text name=subject size=45>"
		smumFormFields "Content","<textarea class=fieldbox cols=45 rows=10 name=content></textarea>"
		smumFormButtons "<input class=fieldbox type=submit value=""Nex Step >>"" name=submit>"
		smumFormCloseTable
		smumFormClose
	
	elseif todo = "check" then

		accesslevel = request.form("accesslevel")
		content = Request.Form ("content")		
		subject = Request.Form ("subject")		

		if accesslevel = 0 then
			smumquery = "select count(*) as nummembers from smum_memberstbl"
		elseif accesslevel < 0 then
			smumquery = "select count(*) as nummembers from smum_maillisttbl"
		else
			smumquery = "select count(*) as nummembers from smum_memberstbl where members_accesslevel = " & accesslevel
		end if

		smumOpenrs smumquery,"smumrs",action
		
			if smumrs.eof or smumrs("nummembers") = 0 then
				messagestatus = false
			else
				nummembers = smumrs("nummembers")
				message = "There are currently "&nummembers&" members, please click ""Send the Newsletter""  to send the following newsletter."
				messagestatus = true
			end if

		smumClosers(smumrs)

		if messagestatus then
			
			content = replace(content, vbcrlf, "<br>")

			smumFormAction "<form action="""&smumadminpage&"?action=newsletter"" method=post>"
			smumFormHiddenField "todo","send"
			smumFormHiddenField "accesslevel",accesslevel
			smumFormHiddenField "content",replace(Request.form("content"),"""","")
			smumFormHiddenField "subject",replace(Request.form("subject"),"""","")
			smumFormOpenTable
			smumFormHeader "Send a Newsletter to the Registered Members or Mailing List"
			smumFormFields "Result",message
			smumFormFields "Subject",subject
			smumFormFields "Content",content
			smumFormButtons "<input class=fieldbox type=submit value=""Send the Newsletter"" name=submit>"
			smumFormCloseTable
			smumFormClose		
		
		else

			smumFormOpenTable
			smumFormHeader "Send a Newsletter to the Registered Members or Mailing List"
			smumFormResponse "There are currently no members so you cannot send any newsletter."
			smumFormCloseTable
		
		end if

	elseif todo = "send" then

		accesslevel = request.form("accesslevel")
		content = Request.Form ("content")		
		subject = Request.Form ("subject")		

		if accesslevel = 0 then
			smumquery1 = "select members_id,members_email,members_firstname from smum_memberstbl"
		elseif accesslevel < 0 then
			smumquery1 = "select maillist_email,maillist_name from smum_maillisttbl"
		else
			smumquery1 = "select members_id,members_email,members_firstname from smum_memberstbl where members_accesslevel = " & accesslevel
		end if

		smumOpenrs smumquery1,"smumrs1",action
		
			if smumrs1.eof then
			
				records =false
				smumFormOpenTable
				smumFormHeader "Send a Newsletter to the Registered Members or Mailing List"
				smumFormResponse "There are currently no members so you cannot send any newsletter."
				smumFormCloseTable

			else

				i = 0

				do until smumrs1.eof
				
					if accesslevel < 0 then
						email = smumrs1("maillist_email")
						toname = smumrs1("maillist_name")
						subjectfinal = replace(subject, "#$name$#", toname) 
						subjectfinal = replace(subjectfinal, "#$email$#", email) 
						messagebody = replace(content, "#$name$#", toname) 
						messagebody = replace(messagebody, "#$email$#", email) 
					else
						email = smumrs1("members_email")
						toname = smumrs1("members_firstname")
						subjectfinal = convertmes(subject, smumrs1("members_id")) 
						messagebody = convertmes(content, smumrs1("members_id")) 
					end if				
			
					result = sendmail(Application("smumadminemail"), email, Application("smumadminname"), toname, Application("smummailserver"), subjectfinal, messagebody, Application("smummailcomponent"))		
					i = i + 1
					smumrs1.movenext	
					
				loop
			
			end if

		smumClosers(smumrs1)
		
		if result = "sent" then
		
			smumFormOpenTable
			smumFormHeader "Send a Newsletter to the Registered Members or Mailing List"
			if application("smummessagequeuing") and session("smbulkmail") then
				smumFormResponse "Newsletter queued to "&i&" user(s) successfully. Please <a href=""/smusermanager/utilities/bulksend.asp?todomail=send"" target=_blank>click here</a> to send the queue."
			else
				smumFormResponse "Newsletter sent to "&i&" user(s) successfully."
			end if
			smumFormCloseTable
		
		else
		
			smumFormOpenTable
			smumFormHeader "Send a Newsletter to the Registered Members or Mailing List"
			smumFormResponse result
			smumFormCloseTable

		end if
	
	end if

End Sub%>