d9r7.bas

矩阵特征值的求解过程之一

Attribute VB_Name = "Module1"
Public NCOM, PCOM(50), XICOM(50)
Sub LINMIN(P(), XI(), N, FRET)
    TOL = 0.0001
    NCOM = N
    For J = 1 To N
        PCOM(J) = P(J)
        XICOM(J) = XI(J)
    Next J
    AX = 0#
    XX = 1#
    Call MNBRAK(AX, XX, BX, FA, FX, FB)
    FRET = BRENT(AX, XX, BX, TOL, XMIN)
    For J = 1 To N
        XI(J) = XMIN * XI(J)
        P(J) = P(J) + XI(J)
    Next J
End Sub
Function F1DIM(X)
    Dim XT(50)
    For J = 1 To NCOM
        XT(J) = PCOM(J) + X * XICOM(J)
    Next J
    F1DIM = FUNC2(XT(), NCOM)
    Erase XT
End Function
Sub MNBRAK(AX, BX, CX, FA, FB, FC)
    GOLD = 1.618034
    GLIMIT = 100#
    TINY = 1E-20
    FA = FUNC(AX)
    FB = FUNC(BX)
    If FB > FA Then
        DUM = AX
        AX = BX
        BX = DUM
        DUM = FB
        FB = FA
        FA = DUM
    End If
    CX = BX + GOLD * (BX - AX)
    FC = FUNC(CX)
    Do
        If FB < FC Then Exit Do
        DONE% = -1
        R = (BX - AX) * (FB - FC)
        Q = (BX - CX) * (FB - FA)
        DUM = Q - R
        If Abs(DUM) < TINY Then DUM = TINY
        U = BX - ((BX - CX) * Q - (BX - AX) * R) / (2 * DUM)
        ULIM = BX + GLIMIT * (CX - BX)
        If (BX - U) * (U - CX) > 0# Then
            FU = FUNC(U)
            If FU < FC Then
                AX = BX
                FA = FB
                BX = U
                FB = FU
                Exit Sub
            ElseIf FU > FB Then
                CX = U
                FC = FU
                Exit Sub
            End If
            U = CX + GOLD * (CX - BX)
            FU = FUNC(U)
        ElseIf (CX - U) * (U - ULIM) > 0# Then
            FU = FUNC(U)
            If FU < FC Then
                BX = CX
                CX = U
                U = CX + GOLD * (CX - BX)
                FB = FC
                FC = FU
                FU = FUNC(U)
            End If
        ElseIf (U - ULIM) * (ULIM - CX) >= 0# Then
            U = ULIM
            FU = FUNC(U)
        Else
            U = CX + GOLD * (CX - BX)
            FU = FUNC(U)
        End If
        If DONE% Then
            AX = BX
            BX = CX
            CX = U
            FA = FB
            FB = FC
            FC = FU
        Else
            DONE% = 0
        End If
    Loop While Not DONE%
End Sub
Function BRENT(AX, BX, CX, TOL, XMIN)
    ITMAX = 100
    CGOLD = 0.381966
    ZEPS = 0.0000000001
    A = AX
    If CX < AX Then A = CX
    B = AX
    If CX > AX Then B = CX
    V = BX
    W = V
    X = V
    E = 0#
    FX = FUNC(X)
    FV1 = FX
    FW = FX
    For ITER = 1 To ITMAX
        XM = 0.5 * (A + B)
        TOL1 = TOL * Abs(X) + ZEPS
        TOL2 = 2# * TOL1
        If Abs(X - XM) <= TOL2 - 0.5 * (B - A) Then Exit For
        DONE% = -1
        If Abs(E) > TOL1 Then
            R = (X - W) * (FX - FV1)
            Q = (X - V) * (FX - FW)
            P = (X - V) * Q - (X - W) * R
            Q = 2# * (Q - R)
            If Q > 0# Then P = -P
            Q = Abs(Q)
            ETEMP = E
            E = D
            DUM = Abs(0.5 * Q * ETEMP)
            If Abs(P) < DUM And P > Q * (A - X) And P < Q * (B - X) Then
                D = P / Q
                U = X + D
                If U - A < TOL2 Or B - U < TOL2 Then
                    D = Abs(TOL1) * Sgn(XM - X)
                End If
                DONE% = 0
            End If
        End If
        If DONE% Then
            If X >= XM Then
                E = A - X
            Else
                E = B - X
            End If
            D = CGOLD * E
        End If
        If Abs(D) >= TOL1 Then
            U = X + D
        Else
            U = X + Abs(TOL1) * Sgn(D)
        End If
        FU = FUNC(U)
        If FU <= FX Then
            If U >= X Then
                A = X
            Else
                B = X
            End If
            V = W
            FV1 = FW
            W = X
            FW = FX
            X = U
            FX = FU
        Else
            If U < X Then
                A = U
            Else
                B = U
            End If
            If FU <= FW Or W = X Then
                V = W
                FV1 = FW
                W = U
                FW = FU
            ElseIf FU <= FV1 Or V = X Or V = W Then
                V = U
                FV1 = FU
            End If
        End If
    Next ITER
    If ITER > ITMAX Then Form1.Print " Brent exceed maximum iterations."
    XMIN = X
    BRENT = FX
End Function
Function FUNC(X)
    FUNC = F1DIM(X)
End Function
Function FUNC2(X(), N)
    F = 0#
    F = F + (X(1) - 1) ^ 2
    F = F + (X(2) - 1) ^ 2
    F = F + (X(3) - 1) ^ 2
    FUNC2 = F
End Function