check.asp

来自「网上学生心里调查系统」· ASP 代码 · 共 59 行

<script language="VBScript">
<!--
''=======================================================''
''函数名称：getStrLen(str)
''参数列表：str          需要返回长度的字符串。
''函数作用：返回字符串的长度，一个中文字符算两个长度单位。
''返回数据：整数
''=======================================================''
Function getStrLen(ByVal str)
If IsNull(str) Or str = "" Then
 getStrLen = 0
Else
 Dim i, n, k, chrA
 k = 0
 n = Len(str)
 For i = 1 To n
  chrA = Mid(str, i, 1)
  If Asc(chrA) >= 0 And Asc(chrA) <= 255 Then
   k = k + 1
  Else
   k = k + 2
  End If
 Next
 getStrLen = k
End If
End Function


''=======================================================''
''函数名称：getStrValue(str, i, str_2)
''参数列表：str          返回之前的字符串；
''　　　　　i            需要的长度；
''　　　　　str_2        省略字符标志。
''函数作用：按照需要的长度，截取字符串。区分中英文字符。
''返回数据：字符串
''=======================================================''
Function getStrValue(ByVal str, ByVal i, ByVal str_2)
   If getStrLen(str) <= i Then
       getStrValue = str
   Else
       Dim j, n, k, chrA
 j = i - getStrLen(str_2)
       n = 0
       k = 0
       Do While n < j
           k = k + 1
  chrA = Mid(str, k, 1)
           If Asc(chrA) < 0 Or Asc(chrA) > 255 Then
               n = n + 2
   If n > j Then k = k - 1
           Else
               n = n + 1
           End If
       Loop
       getStrValue = Left(Trim(str), k) & str_2
   End If
End Function
-->
</script>